core/words/words.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs definitions hashtables kernel
   4 kernel.private math math.order namespaces quotations sequences
   5 slots.private strings vocabs ;
   6 IN: words
   7
   8 BUILTIN: word
   9 { hashcode fixnum initial: 0 } name vocabulary
  10 { def quotation initial: [ ] } props pic-def pic-tail-def
  11 { sub-primitive read-only } ;
  12
  13 PRIMITIVE: word-code ( word -- start end )
  14 PRIMITIVE: word-optimized? ( word -- ? )
  15
  16 <PRIVATE
  17 PRIMITIVE: (word) ( name vocab hashcode -- word )
  18 PRIVATE>
  19
  20 ! Need a dummy word here because BUILTIN: word is not a real word
  21 ! and parse-datum looks for things that are actually words instead of
  22 ! also looking for classes
  23 : word ( -- * ) "dummy word" throw ;
  24
  25 : last-word ( -- word ) \ last-word get-global ;
  26
  27 : set-last-word ( word -- ) \ last-word set-global ;
  28
  29 M: word execute (execute) ;
  30
  31 M: word <=>
  32     [ [ name>> ] [ vocabulary>> ] bi 2array ] compare ;
  33
  34 M: word definer drop \ : \ ; ;
  35
  36 M: word definition def>> ;
  37
  38 : word-prop ( word name -- value ) swap props>> at ;
  39
  40 : remove-word-prop ( word name -- ) swap props>> delete-at ;
  41
  42 : remove-word-props ( word seq -- )
  43     swap props>> [ delete-at ] curry each ;
  44
  45 : set-word-prop ( word value name -- )
  46     over
  47     [ pick props>> ?set-at >>props drop ]
  48     [ nip remove-word-prop ] if ;
  49
  50 : change-word-prop ( ..a word prop quot: ( ..a value -- ..b newvalue ) -- ..b )
  51     [ swap props>> ] dip change-at ; inline
  52
  53 <PRIVATE
  54
  55 : caller ( callstack -- word ) callstack>array <reversed> third ;
  56
  57 PRIVATE>
  58
  59 TUPLE: undefined-word word ;
  60
  61 : undefined ( -- * ) get-callstack caller undefined-word boa throw ;
  62
  63 : undefined-def ( -- quot )
  64     ! 'f' inhibits tail call optimization in non-optimizing
  65     ! compiler, ensuring that we can pull out the caller word
  66     ! above.
  67     [ undefined f ] ;
  68
  69 PREDICATE: deferred < word def>> undefined-def = ;
  70 M: deferred definer drop \ DEFER: f ;
  71 M: deferred definition drop f ;
  72
  73 PREDICATE: primitive < word "primitive" word-prop ;
  74 M: primitive definer drop \ PRIMITIVE: f ;
  75 M: primitive definition drop f ;
  76
  77 ERROR: invalid-primitive vocabulary word effect ;
  78 : ensure-primitive ( vocabulary word effect -- )
  79     3dup
  80     [ drop vocabulary>> = ]
  81     [ drop nip primitive? ]
  82     [ [ nip "declared-effect" word-prop ] dip = ] 3tri and and
  83     [ 3drop ] [ invalid-primitive ] if ;
  84
  85 : lookup-word ( name vocab -- word ) vocab-words-assoc at ;
  86
  87 : target-word ( word -- target )
  88     [ name>> ] [ vocabulary>> ] bi lookup-word ;
  89
  90 SYMBOL: bootstrapping?
  91
  92 : if-bootstrapping ( true false -- )
  93     [ bootstrapping? get ] 2dip if ; inline
  94
  95 : bootstrap-word ( word -- target )
  96     [ target-word ] [ ] if-bootstrapping ;
  97
  98 GENERIC: crossref? ( word -- ? )
  99
 100 M: word crossref?
 101     dup "forgotten" word-prop [ drop f ] [ vocabulary>> >boolean ] if ;
 102
 103 GENERIC: subwords ( word -- seq )
 104
 105 M: word subwords drop f ;
 106
 107 GENERIC: parent-word ( word -- word/f )
 108
 109 M: word parent-word drop f ;
 110
 111 : define ( word def -- )
 112     over changed-definition [ ] like >>def drop ;
 113
 114 : changed-effect ( word -- )
 115     [ changed-effects get add-to-unit ]
 116     [ dup primitive? [ drop ] [ changed-definition ] if ] bi ;
 117
 118 : set-stack-effect ( effect word -- )
 119     2dup "declared-effect" word-prop = [ 2drop ] [
 120         [ nip changed-effect ]
 121         [ nip subwords [ changed-effect ] each ]
 122         [ swap "declared-effect" set-word-prop ]
 123         2tri
 124     ] if ;
 125
 126 : define-declared ( word def effect -- )
 127     [ nip swap set-stack-effect ] [ drop define ] 3bi ;
 128
 129 : make-deprecated ( word -- )
 130     t "deprecated" set-word-prop ;
 131
 132 : word-prop? ( obj string -- ? )
 133     over word? [ word-prop ] [ 2drop f ] if ; inline
 134
 135 : word-props? ( obj seq -- ? )
 136     over word? [ [ word-prop ] with all? ] [ 2drop f ] if ; inline
 137
 138 : inline? ( obj -- ? ) "inline" word-prop? ; inline
 139
 140 : recursive? ( obj -- ? ) "recursive" word-prop? ; inline
 141
 142 : inline-recursive? ( obj -- ? )
 143     { "inline" "recursive" } word-props? ; inline
 144
 145 ERROR: cannot-be-inline word ;
 146
 147 GENERIC: make-inline ( word -- )
 148
 149 M: word make-inline
 150     dup inline? [ drop ] [
 151         [ t "inline" set-word-prop ]
 152         [ changed-effect ]
 153         bi
 154     ] if ;
 155
 156 : define-inline ( word def effect -- )
 157     [ define-declared ] [ 2drop make-inline ] 3bi ;
 158
 159 : make-recursive ( word -- )
 160     t "recursive" set-word-prop ;
 161
 162 GENERIC: flushable? ( word -- ? )
 163
 164 M: word flushable?
 165     [ "flushable" word-prop ]
 166     [ parent-word dup [ flushable? ] when ] bi or ;
 167
 168 : make-flushable ( word -- )
 169     t "flushable" set-word-prop ;
 170
 171 GENERIC: foldable? ( word -- ? )
 172
 173 M: word foldable?
 174     [ "foldable" word-prop ]
 175     [ parent-word dup [ foldable? ] when ] bi or ;
 176
 177 : make-foldable ( word -- )
 178     [ make-flushable ]
 179     [ t "foldable" set-word-prop ] bi ;
 180
 181 GENERIC: reset-word ( word -- )
 182
 183 M: word reset-word
 184     dup flushable? [ dup changed-conditionally ] when
 185     {
 186         "unannotated-def" "parsing" "inline" "recursive"
 187         "foldable" "flushable" "reading" "writing" "reader"
 188         "writer" "delimiter" "deprecated"
 189     } remove-word-props ;
 190
 191 : reset-generic ( word -- )
 192     [ subwords forget-all ]
 193     [ reset-word ]
 194     [
 195         f >>pic-def
 196         f >>pic-tail-def
 197         {
 198             "methods"
 199             "combination"
 200             "default-method"
 201             "engines"
 202             "decision-tree"
 203         } remove-word-props
 204     ] tri ;
 205
 206 : <word> ( name vocab -- word )
 207     2dup [ hashcode ] bi@ hash-combine >fixnum (word) dup new-word ;
 208
 209 : <uninterned-word> ( name -- word )
 210     f \ <uninterned-word> counter >fixnum (word)
 211     new-words get [ dup new-word ] when ;
 212
 213 : gensym ( -- word )
 214     "( gensym )" <uninterned-word> ;
 215
 216 : define-temp ( quot effect -- word )
 217     [ gensym dup ] 2dip define-declared ;
 218
 219 : reveal ( word -- )
 220     dup [ name>> ] [ vocabulary>> ] bi dup vocab-words-assoc
 221     [ ] [ no-vocab ] ?if set-at ;
 222
 223 ERROR: bad-create name vocab ;
 224
 225 : check-create ( name vocab -- name vocab )
 226     2dup [ string? ] [ [ string? ] [ vocab? ] bi or ] bi* and
 227     [ bad-create ] unless ;
 228
 229 : create-word ( name vocab -- word )
 230     check-create 2dup lookup-word
 231     [ 2nip ] [
 232         vocab-name <word>
 233         dup reveal
 234         dup changed-definition
 235     ] if* ;
 236
 237 : constructor-word ( name vocab -- word )
 238     [ "<" ">" surround ] dip create-word ;
 239
 240 PREDICATE: parsing-word < word "parsing" word-prop ;
 241
 242 M: parsing-word definer drop \ SYNTAX: \ ; ;
 243
 244 : define-syntax ( word quot -- )
 245     [ drop ] [ define ] 2bi t "parsing" set-word-prop ;
 246
 247 : delimiter? ( obj -- ? ) "delimiter" word-prop? ;
 248
 249 : deprecated? ( obj -- ? ) "deprecated" word-prop? ;
 250
 251 ! Definition protocol
 252 M: word where "loc" word-prop ;
 253
 254 M: word set-where swap "loc" set-word-prop ;
 255
 256 M: word forget*
 257     dup "forgotten" word-prop [ drop ] [
 258         [ subwords forget-all ]
 259         [ [ name>> ] [ vocabulary>> vocab-words-assoc ] bi delete-at ]
 260         [ t "forgotten" set-word-prop ]
 261         tri
 262     ] if ;
 263
 264 ! Can be foldable because the hashcode itself is immutable
 265 M: word hashcode*
 266     nip 1 slot { fixnum } declare ; inline foldable
 267
 268 M: word literalize <wrapper> ;
 269
 270 INSTANCE: word definition-mixin