core/words/words.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs definitions hashtables kernel
   4 kernel.private math math.order namespaces quotations sequences
   5 slots.private strings vocabs ;
   6 IN: words
   7
   8 BUILTIN: word
   9 { hashcode fixnum initial: 0 } name vocabulary
  10 { def quotation initial: [ ] } props pic-def pic-tail-def
  11 { sub-primitive read-only } ;
  12
  13 PRIMITIVE: word-code ( word -- start end )
  14 PRIMITIVE: word-optimized? ( word -- ? )
  15
  16 <PRIVATE
  17 PRIMITIVE: (word) ( name vocab hashcode -- word )
  18 PRIVATE>
  19
  20 : last-word ( -- word ) \ last-word get-global ;
  21
  22 : set-last-word ( word -- ) \ last-word set-global ;
  23
  24 M: word execute (execute) ;
  25
  26 M: word <=>
  27     [ [ name>> ] [ vocabulary>> ] bi 2array ] compare ;
  28
  29 M: word definer drop \ : \ ; ;
  30
  31 M: word definition def>> ;
  32
  33 : word-prop ( word name -- value ) swap props>> at ;
  34
  35 : remove-word-prop ( word name -- ) swap props>> delete-at ;
  36
  37 : remove-word-props ( word seq -- )
  38     swap props>> [ delete-at ] curry each ;
  39
  40 : set-word-prop ( word value name -- )
  41     over
  42     [ pick props>> ?set-at >>props drop ]
  43     [ nip remove-word-prop ] if ;
  44
  45 : change-word-prop ( ..a word prop quot: ( ..a value -- ..b newvalue ) -- ..b )
  46     [ swap props>> ] dip change-at ; inline
  47
  48 <PRIVATE
  49
  50 : caller ( callstack -- word )
  51     callstack>array first ;
  52
  53 PRIVATE>
  54
  55 TUPLE: undefined-word word ;
  56
  57 : undefined ( -- * ) get-callstack caller undefined-word boa throw ;
  58
  59 : undefined-def ( -- quot )
  60     ! 'f' inhibits tail call optimization in non-optimizing
  61     ! compiler, ensuring that we can pull out the caller word
  62     ! above.
  63     [ undefined f ] ;
  64
  65 PREDICATE: deferred < word def>> undefined-def = ;
  66 M: deferred definer drop \ DEFER: f ;
  67 M: deferred definition drop f ;
  68
  69 PREDICATE: primitive < word "primitive" word-prop ;
  70 M: primitive definer drop \ PRIMITIVE: f ;
  71 M: primitive definition drop f ;
  72
  73 ERROR: invalid-primitive vocabulary word effect ;
  74 : ensure-primitive ( vocabulary word effect -- )
  75     3dup
  76     [ drop vocabulary>> = ]
  77     [ drop nip primitive? ]
  78     [ [ nip "declared-effect" word-prop ] dip = ] 3tri and and
  79     [ 3drop ] [ invalid-primitive ] if ;
  80
  81 : lookup-word ( name vocab -- word ) vocab-words-assoc at ;
  82
  83 : target-word ( word -- target )
  84     [ name>> ] [ vocabulary>> ] bi lookup-word ;
  85
  86 SYMBOL: bootstrapping?
  87
  88 : if-bootstrapping ( true false -- )
  89     [ bootstrapping? get ] 2dip if ; inline
  90
  91 : bootstrap-word ( word -- target )
  92     [ target-word ] [ ] if-bootstrapping ;
  93
  94 GENERIC: crossref? ( word -- ? )
  95
  96 M: word crossref?
  97     dup "forgotten" word-prop [ drop f ] [ vocabulary>> >boolean ] if ;
  98
  99 GENERIC: subwords ( word -- seq )
 100
 101 M: word subwords drop f ;
 102
 103 GENERIC: parent-word ( word -- word/f )
 104
 105 M: word parent-word drop f ;
 106
 107 : define ( word def -- )
 108     over changed-definition [ ] like >>def drop ;
 109
 110 : changed-effect ( word -- )
 111     [ changed-effects get add-to-unit ]
 112     [ dup primitive? [ drop ] [ changed-definition ] if ] bi ;
 113
 114 : set-stack-effect ( effect word -- )
 115     2dup "declared-effect" word-prop = [ 2drop ] [
 116         [ nip changed-effect ]
 117         [ nip subwords [ changed-effect ] each ]
 118         [ swap "declared-effect" set-word-prop ]
 119         2tri
 120     ] if ;
 121
 122 : define-declared ( word def effect -- )
 123     [ nip swap set-stack-effect ] [ drop define ] 3bi ;
 124
 125 : make-deprecated ( word -- )
 126     t "deprecated" set-word-prop ;
 127
 128 : word-prop? ( obj string -- ? )
 129     over word? [ word-prop ] [ 2drop f ] if ; inline
 130
 131 : word-props? ( obj seq -- ? )
 132     over word? [ [ word-prop ] with all? ] [ 2drop f ] if ; inline
 133
 134 : inline? ( obj -- ? ) "inline" word-prop? ; inline
 135
 136 : recursive? ( obj -- ? ) "recursive" word-prop? ; inline
 137
 138 : inline-recursive? ( obj -- ? )
 139     { "inline" "recursive" } word-props? ; inline
 140
 141 ERROR: cannot-be-inline word ;
 142
 143 GENERIC: make-inline ( word -- )
 144
 145 M: word make-inline
 146     dup inline? [ drop ] [
 147         [ t "inline" set-word-prop ]
 148         [ changed-effect ]
 149         bi
 150     ] if ;
 151
 152 : define-inline ( word def effect -- )
 153     [ define-declared ] [ 2drop make-inline ] 3bi ;
 154
 155 : make-recursive ( word -- )
 156     t "recursive" set-word-prop ;
 157
 158 GENERIC: flushable? ( word -- ? )
 159
 160 M: word flushable?
 161     [ "flushable" word-prop ]
 162     [ parent-word dup [ flushable? ] when ] bi or ;
 163
 164 : make-flushable ( word -- )
 165     t "flushable" set-word-prop ;
 166
 167 GENERIC: foldable? ( word -- ? )
 168
 169 M: word foldable?
 170     [ "foldable" word-prop ]
 171     [ parent-word dup [ foldable? ] when ] bi or ;
 172
 173 : make-foldable ( word -- )
 174     [ make-flushable ]
 175     [ t "foldable" set-word-prop ] bi ;
 176
 177 GENERIC: reset-word ( word -- )
 178
 179 M: word reset-word
 180     dup flushable? [ dup changed-conditionally ] when
 181     {
 182         "unannotated-def" "parsing" "inline" "recursive"
 183         "foldable" "flushable" "reading" "writing" "reader"
 184         "writer" "delimiter" "deprecated"
 185     } remove-word-props ;
 186
 187 : reset-generic ( word -- )
 188     [ subwords forget-all ]
 189     [ reset-word ]
 190     [
 191         f >>pic-def
 192         f >>pic-tail-def
 193         {
 194             "methods"
 195             "combination"
 196             "default-method"
 197             "engines"
 198             "decision-tree"
 199         } remove-word-props
 200     ] tri ;
 201
 202 : <word> ( name vocab -- word )
 203     2dup [ hashcode ] bi@ hash-combine >fixnum (word) dup new-word ;
 204
 205 : <uninterned-word> ( name -- word )
 206     f \ <uninterned-word> counter >fixnum (word)
 207     new-words get [ dup new-word ] when ;
 208
 209 : gensym ( -- word )
 210     "( gensym )" <uninterned-word> ;
 211
 212 : define-temp ( quot effect -- word )
 213     [ gensym dup ] 2dip define-declared ;
 214
 215 : reveal ( word -- )
 216     dup [ name>> ] [ vocabulary>> ] bi dup vocab-words-assoc
 217     [ ] [ no-vocab ] ?if set-at ;
 218
 219 ERROR: bad-create name vocab ;
 220
 221 : check-create ( name vocab -- name vocab )
 222     2dup [ string? ] [ [ string? ] [ vocab? ] bi or ] bi* and
 223     [ bad-create ] unless ;
 224
 225 : create-word ( name vocab -- word )
 226     check-create 2dup lookup-word
 227     [ 2nip ] [
 228         vocab-name <word>
 229         dup reveal
 230         dup changed-definition
 231     ] if* ;
 232
 233 : constructor-word ( name vocab -- word )
 234     [ "<" ">" surround ] dip create-word ;
 235
 236 PREDICATE: parsing-word < word "parsing" word-prop ;
 237
 238 M: parsing-word definer drop \ SYNTAX: \ ; ;
 239
 240 : define-syntax ( word quot -- )
 241     [ drop ] [ define ] 2bi t "parsing" set-word-prop ;
 242
 243 : delimiter? ( obj -- ? ) "delimiter" word-prop? ;
 244
 245 : deprecated? ( obj -- ? ) "deprecated" word-prop? ;
 246
 247 ! Definition protocol
 248 M: word where "loc" word-prop ;
 249
 250 M: word set-where swap "loc" set-word-prop ;
 251
 252 M: word forget*
 253     dup "forgotten" word-prop [ drop ] [
 254         [ subwords forget-all ]
 255         [ [ name>> ] [ vocabulary>> vocab-words-assoc ] bi delete-at ]
 256         [ t "forgotten" set-word-prop ]
 257         tri
 258     ] if ;
 259
 260 ! Can be foldable because the hashcode itself is immutable
 261 M: word hashcode*
 262     nip 1 slot { fixnum } declare ; inline foldable
 263
 264 M: word literalize <wrapper> ;
 265
 266 INSTANCE: word definition-mixin