extra/L-system/L-system.factor

   1
   2 USING: accessors arrays assocs calendar colors
   3 combinators.short-circuit help.markup help.syntax kernel locals
   4 math math.functions math.matrices math.order math.parser
   5 math.trig math.vectors opengl opengl.demo-support opengl.gl
   6 sbufs sequences strings threads ui.gadgets ui.gadgets.worlds
   7 ui.gestures ui.render ui.tools.workspace ;
   8
   9 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  10
  11 IN: L-system
  12
  13 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  14
  15 TUPLE: <turtle> pos ori angle length thickness color vertices saved ;
  16
  17 DEFER: default-L-parser-values
  18
  19 : reset-turtle ( turtle -- turtle )
  20   { 0 0 0 } clone   >>pos
  21   3 identity-matrix >>ori
  22   V{ } clone >>vertices
  23   V{ } clone >>saved
  24
  25   default-L-parser-values ;
  26
  27 : turtle ( -- turtle ) <turtle> new reset-turtle ;
  28
  29 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  30
  31 :: step-turtle ( TURTLE LENGTH -- turtle )
  32
  33   TURTLE
  34     TURTLE pos>>   TURTLE ori>> { 0 0 LENGTH } m.v   v+
  35   >>pos ;
  36
  37 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  38
  39 :: Rx ( ANGLE -- Rx )
  40
  41   [let | ANGLE [ ANGLE deg>rad ] |
  42
  43     [let | A [ ANGLE cos     ]
  44            B [ ANGLE sin neg ]
  45            C [ ANGLE sin     ]
  46            D [ ANGLE cos     ] |
  47
  48       { { 1 0 0 }
  49         { 0 A B }
  50         { 0 C D } }
  51
  52     ] ] ;
  53
  54 :: Ry ( ANGLE -- Ry )
  55
  56   [let | ANGLE [ ANGLE deg>rad ] |
  57
  58     [let | A [ ANGLE cos     ]
  59            B [ ANGLE sin     ]
  60            C [ ANGLE sin neg ]
  61            D [ ANGLE cos     ] |
  62
  63       { { A 0 B }
  64         { 0 1 0 }
  65         { C 0 D } }
  66
  67     ] ] ;
  68
  69 :: Rz ( ANGLE -- Rz )
  70
  71   [let | ANGLE [ ANGLE deg>rad ] |
  72
  73     [let | A [ ANGLE cos     ]
  74            B [ ANGLE sin neg ]
  75            C [ ANGLE sin     ]
  76            D [ ANGLE cos     ] |
  77
  78       { { A B 0 }
  79         { C D 0 }
  80         { 0 0 1 } }
  81
  82     ] ] ;
  83
  84 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  85
  86 :: apply-rotation ( TURTLE ROTATION -- turtle )
  87
  88   TURTLE  TURTLE ori>> ROTATION m.  >>ori ;
  89
  90 : rotate-x ( turtle angle -- turtle ) Rx apply-rotation ;
  91 : rotate-y ( turtle angle -- turtle ) Ry apply-rotation ;
  92 : rotate-z ( turtle angle -- turtle ) Rz apply-rotation ;
  93
  94 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  95
  96 : pitch-up   ( turtle angle -- turtle ) neg rotate-x ;
  97 : pitch-down ( turtle angle -- turtle )     rotate-x ;
  98
  99 : turn-left  ( turtle angle -- turtle )     rotate-y ;
 100 : turn-right ( turtle angle -- turtle ) neg rotate-y ;
 101
 102 : roll-left  ( turtle angle -- turtle ) neg rotate-z ;
 103 : roll-right ( turtle angle -- turtle )     rotate-z ;
 104
 105 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 106
 107 : V ( -- V ) { 0 1 0 } ;
 108
 109 : X ( turtle -- 3array ) ori>> [ first  ] map ;
 110 : Y ( turtle -- 3array ) ori>> [ second ] map ;
 111 : Z ( turtle -- 3array ) ori>> [ third  ] map ;
 112
 113 : set-X ( turtle seq -- turtle ) over ori>> [ set-first  ] 2each ;
 114 : set-Y ( turtle seq -- turtle ) over ori>> [ set-second ] 2each ;
 115 : set-Z ( turtle seq -- turtle ) over ori>> [ set-third  ] 2each ;
 116
 117 :: roll-until-horizontal ( TURTLE -- turtle )
 118
 119   TURTLE
 120
 121     V         TURTLE Z  cross normalize  set-X
 122
 123     TURTLE Z  TURTLE X  cross normalize  set-Y ;
 124
 125 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 126
 127 :: strafe-up ( TURTLE LENGTH -- turtle )
 128   TURTLE 90 pitch-up LENGTH step-turtle 90 pitch-down ;
 129
 130 :: strafe-down ( TURTLE LENGTH -- turtle )
 131   TURTLE 90 pitch-down LENGTH step-turtle 90 pitch-up ;
 132
 133 :: strafe-left ( TURTLE LENGTH -- turtle )
 134   TURTLE 90 turn-left LENGTH step-turtle 90 turn-right ;
 135
 136 :: strafe-right ( TURTLE LENGTH -- turtle )
 137   TURTLE 90 turn-right LENGTH step-turtle 90 turn-left ;
 138
 139 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 140
 141 : polygon ( vertices -- ) GL_POLYGON glBegin [ first3 glVertex3d ] each glEnd ;
 142
 143 : start-polygon ( turtle -- turtle ) dup vertices>> delete-all ;
 144
 145 : finish-polygon ( turtle -- turtle ) dup vertices>> polygon ;
 146
 147 : polygon-vertex ( turtle -- turtle ) dup [ pos>> ] [ vertices>> ] bi push ;
 148
 149 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 150
 151 : record-vertex ( turtle -- turtle ) dup pos>> first3 glVertex3d ;
 152
 153 : draw-forward ( turtle length -- turtle )
 154   GL_LINES glBegin [ record-vertex ] dip step-turtle record-vertex glEnd ;
 155
 156 : move-forward ( turtle length -- turtle ) step-turtle polygon-vertex ;
 157
 158 : sneak-forward ( turtle length -- turtle ) step-turtle ;
 159
 160 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 161
 162 : scale-length ( turtle m -- turtle ) over length>> * >>length ;
 163 : scale-angle  ( turtle m -- turtle ) over angle>>  * >>angle  ;
 164
 165 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 166
 167 : set-thickness ( turtle i -- turtle ) dup glLineWidth >>thickness ;
 168
 169 : scale-thickness ( turtle m -- turtle )
 170   over thickness>> * 0.5 max set-thickness ;
 171
 172 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 173
 174 : color-table ( -- colors )
 175   {
 176     T{ rgba f 0    0    0    1 } ! black
 177     T{ rgba f 0.5  0.5  0.5  1 } ! grey
 178     T{ rgba f 1    0    0    1 } ! red
 179     T{ rgba f 1    1    0    1 } ! yellow
 180     T{ rgba f 0    1    0    1 } ! green
 181     T{ rgba f 0.25 0.88 0.82 1 } ! turquoise
 182     T{ rgba f 0    0    1    1 } ! blue
 183     T{ rgba f 0.63 0.13 0.94 1 } ! purple
 184     T{ rgba f 0.00 0.50 0.00 1 } ! dark green
 185     T{ rgba f 0.00 0.82 0.82 1 } ! dark turquoise
 186     T{ rgba f 0.00 0.00 0.50 1 } ! dark blue
 187     T{ rgba f 0.58 0.00 0.82 1 } ! dark purple
 188     T{ rgba f 0.50 0.00 0.00 1 } ! dark red
 189     T{ rgba f 0.25 0.25 0.25 1 } ! dark grey
 190     T{ rgba f 0.75 0.75 0.75 1 } ! medium grey
 191     T{ rgba f 1    1    1    1 } ! white
 192   } ;
 193
 194 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 195
 196 ! : material-color ( color -- )
 197 !   GL_FRONT_AND_BACK GL_AMBIENT_AND_DIFFUSE rot gl-material ;
 198
 199 : material-color ( color -- )
 200   GL_FRONT_AND_BACK GL_AMBIENT_AND_DIFFUSE rot color>raw 4array gl-material ;
 201
 202 : set-color ( turtle i -- turtle )
 203   dup color-table nth dup gl-color material-color >>color ;
 204
 205 : inc-color ( turtle -- turtle ) dup color>> 1 + set-color ;
 206
 207 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 208
 209 : save-turtle    ( turtle -- turtle ) dup clone over saved>> push ;
 210 : restore-turtle ( turtle -- turtle )                saved>> pop  ;
 211
 212 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 213
 214 : default-L-parser-values ( turtle -- turtle )
 215   1 >>length 45 >>angle 1 >>thickness 2 >>color ;
 216
 217 : L-parser-dialect ( -- commands )
 218
 219   {
 220       { "+" [ dup angle>> turn-left  ] }
 221       { "-" [ dup angle>> turn-right ] }
 222       { "&" [ dup angle>> pitch-down ] }
 223       { "^" [ dup angle>> pitch-up   ] }
 224       { "<" [ dup angle>> roll-left  ] }
 225       { ">" [ dup angle>> roll-right ] }
 226
 227       { "|" [ 180.0         rotate-y ] }
 228       { "%" [ 180.0         rotate-z ] }
 229       { "$" [ roll-until-horizontal  ]  }
 230
 231       { "F" [ dup length>>     draw-forward  ] }
 232       { "Z" [ dup length>> 2 / draw-forward  ] }
 233       { "f" [ dup length>>     move-forward  ] }
 234       { "z" [ dup length>> 2 / move-forward  ] }
 235       { "g" [ dup length>>     sneak-forward ] }
 236       { "." [ polygon-vertex                 ] }
 237
 238       { "[" [ save-turtle      ] }
 239       { "]" [ restore-turtle   ] }
 240
 241       { "{" [ start-polygon    ] }
 242       { "}" [ finish-polygon   ] }
 243
 244       { "/" [ 1.1 scale-length    ] } ! double quote command in lparser
 245       { "'" [ 0.9 scale-length    ] }
 246       { ";" [ 1.1 scale-angle     ] }
 247       { ":" [ 0.9 scale-angle     ] }
 248       { "?" [ 1.4 scale-thickness ] }
 249       { "!" [ 0.7 scale-thickness ] }
 250
 251       { "c" [ dup color>> 1 + color-table length mod set-color ] }
 252
 253     }
 254     ;
 255
 256 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 257
 258 TUPLE: <L-system> < gadget
 259   camera display-list pedestal paused
 260   turtle-values
 261   commands axiom rules string ;
 262
 263 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 264
 265 :: iterate-system ( GADGET -- ) GADGET pedestal>> 0.5 + GADGET (>>pedestal) ;
 266
 267 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 268
 269 :: start-rotation-thread ( GADGET -- )
 270   GADGET f >>paused drop
 271   [
 272     [
 273       GADGET paused>>
 274         [ f ]
 275         [ GADGET iterate-system GADGET relayout-1 25 milliseconds sleep t ]
 276       if
 277     ]
 278     loop
 279   ]
 280   in-thread ;
 281
 282 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 283
 284 : open-paren  ( -- ch ) CHAR: ( ;
 285 : close-paren ( -- ch ) CHAR: ) ;
 286
 287 : open-paren?  ( obj -- ? ) open-paren  = ;
 288 : close-paren? ( obj -- ? ) close-paren = ;
 289
 290 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 291
 292 :: read-instruction ( STRING -- next rest )
 293
 294   { [ STRING length 1 > ] [ STRING second open-paren? ] } 0&&
 295     [ STRING  close-paren STRING index 1 + cut ]
 296     [ STRING  1                            cut ]
 297   if ;
 298
 299 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 300
 301 :: iterate-string-loop ( STRING RULES ACCUM -- )
 302   STRING empty? not
 303     [
 304       STRING read-instruction
 305
 306       [let | REST [ ] NEXT [ ] |
 307
 308         NEXT 1 head RULES at  NEXT  or  ACCUM push-all
 309
 310         REST RULES ACCUM iterate-string-loop ]
 311     ]
 312   when ;
 313
 314 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 315
 316 :: iterate-string ( STRING RULES -- string )
 317
 318   [let | ACCUM [ STRING length  10 *  <sbuf> ] |
 319
 320     STRING RULES ACCUM iterate-string-loop
 321
 322     ACCUM >string ] ;
 323
 324 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 325
 326 :: interpret-string ( STRING COMMANDS -- )
 327
 328   STRING empty? not
 329     [
 330       STRING read-instruction
 331
 332       [let | REST [ ] NEXT [ ] |
 333
 334         [let | COMMAND [ NEXT 1 head COMMANDS at ] |
 335
 336           COMMAND
 337             [
 338               NEXT length 1 =
 339                 [ COMMAND call ]
 340                 [
 341                   NEXT 2 tail 1 head* string>number
 342                   COMMAND 1 tail*
 343                   call
 344                 ]
 345               if
 346             ]
 347           when ]
 348
 349         REST COMMANDS interpret-string ]
 350     ]
 351   when ;
 352
 353 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 354
 355 :: iterate-L-system-string ( L-SYSTEM -- )
 356   L-SYSTEM string>> L-SYSTEM axiom>> or
 357   L-SYSTEM rules>>
 358   iterate-string
 359   L-SYSTEM (>>string) ;
 360
 361 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 362
 363 :: do-camera-look-at ( CAMERA -- )
 364
 365   [let | EYE   [ CAMERA pos>> ]
 366          FOCUS [ CAMERA clone 1 step-turtle pos>> ]
 367          UP    [ CAMERA clone 90 pitch-up 1 step-turtle pos>> CAMERA pos>> v- ]
 368        |
 369
 370     EYE FOCUS UP gl-look-at ] ;
 371
 372 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 373
 374 :: generate-display-list ( L-SYSTEM -- )
 375
 376   L-SYSTEM find-gl-context
 377
 378   L-SYSTEM display-list>> GL_COMPILE glNewList
 379
 380     turtle
 381     L-SYSTEM turtle-values>> [ ] or call
 382     L-SYSTEM string>> L-SYSTEM axiom>> or
 383     L-SYSTEM commands>>
 384     interpret-string
 385     drop
 386
 387   glEndList ;
 388
 389 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 390
 391 M:: <L-system> draw-gadget* ( L-SYSTEM -- )
 392
 393   black gl-clear
 394
 395   GL_FLAT glShadeModel
 396
 397   GL_PROJECTION glMatrixMode
 398   glLoadIdentity
 399   -1 1 -1 1 1.5 200 glFrustum
 400
 401   GL_MODELVIEW glMatrixMode
 402
 403   glLoadIdentity
 404
 405   L-SYSTEM camera>> do-camera-look-at
 406
 407   GL_FRONT_AND_BACK GL_LINE glPolygonMode
 408
 409   ! draw axis
 410   white gl-color GL_LINES glBegin { 0 0 0 } gl-vertex { 0 0 1 } gl-vertex glEnd
 411
 412   ! rotate pedestal
 413
 414   L-SYSTEM pedestal>> 0 0 1 glRotated
 415
 416   L-SYSTEM display-list>> glCallList ;
 417
 418 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 419
 420 M:: <L-system> graft* ( L-SYSTEM -- )
 421
 422   L-SYSTEM find-gl-context
 423
 424   1 glGenLists L-SYSTEM (>>display-list) ;
 425
 426 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 427
 428 M:: <L-system> pref-dim* ( L-SYSTEM -- dim ) { 400 400 } ;
 429
 430 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 431
 432 :: with-camera ( L-SYSTEM QUOT -- )
 433   L-SYSTEM camera>> QUOT call drop
 434   L-SYSTEM relayout-1 ;
 435
 436 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 437
 438 <L-system>
 439 H{
 440   { T{ key-down f f "LEFT"  } [ [  5 turn-left   ] with-camera ] }
 441   { T{ key-down f f "RIGHT" } [ [  5 turn-right  ] with-camera ] }
 442   { T{ key-down f f "UP"    } [ [  5 pitch-down  ] with-camera ] }
 443   { T{ key-down f f "DOWN"  } [ [  5 pitch-up    ] with-camera ] }
 444
 445   { T{ key-down f f "a"     } [ [  1 step-turtle ] with-camera ] }
 446   { T{ key-down f f "z"     } [ [ -1 step-turtle ] with-camera ] }
 447
 448   { T{ key-down f f "q"     } [ [ 5 roll-left    ] with-camera ] }
 449   { T{ key-down f f "w"     } [ [ 5 roll-right   ] with-camera ] }
 450
 451   { T{ key-down f { A+ } "LEFT"  } [ [ 1 strafe-left  ] with-camera ] }
 452   { T{ key-down f { A+ } "RIGHT" } [ [ 1 strafe-right ] with-camera ] }
 453   { T{ key-down f { A+ } "UP"    } [ [ 1 strafe-up    ] with-camera ] }
 454   { T{ key-down f { A+ } "DOWN"  } [ [ 1 strafe-down  ] with-camera ] }
 455
 456   { T{ key-down f f "r"     } [ start-rotation-thread          ] }
 457
 458   {
 459     T{ key-down f f "x" }
 460     [
 461       dup iterate-L-system-string
 462       dup generate-display-list
 463       dup relayout-1
 464       drop
 465     ]
 466   }
 467
 468   { T{ key-down f f "F1" } [ drop "L-system" help-window ] }
 469
 470 }
 471 set-gestures
 472
 473 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 474
 475 : L-system ( -- L-system )
 476
 477   <L-system> new-gadget
 478
 479     0 >>pedestal
 480
 481     ! turtle 45 turn-left 45 pitch-up 5 step-turtle 180 turn-left >>camera ;
 482
 483     turtle 90 pitch-down -5 step-turtle 2 strafe-up >>camera
 484
 485     dup start-rotation-thread
 486
 487   ;
 488
 489 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 490
 491 ARTICLE: "L-system" "L-system"
 492
 493 "Press 'x' to iterate the L-system." $nl
 494
 495 "Camera control:"
 496
 497 { $table
 498
 499   { "a" "Forward" }
 500   { "z" "Backward" }
 501
 502   { "LEFT" "Turn left" }
 503   { "RIGHT" "Turn right" }
 504   { "UP" "Pitch down" }
 505   { "DOWN" "Pitch up" }
 506
 507   { "q" "Roll left" }
 508   { "w" "Roll right" } } ;
 509
 510 ABOUT: "L-system"