extra/alien/cxx/demangle/libstdcxx/libstdcxx.factor

   1 ! (c)2010 Joe Groff bsd license
   2 USING: alien alien.c-types alien.libraries alien.strings
   3 alien.syntax combinators destructors io.encodings.ascii kernel
   4 libc locals sequences system ;
   5 IN: alien.cxx.demangle.libstdcxx
   6
   7 FUNCTION: char* __cxa_demangle ( char* mangled_name, char* output_buffer, size_t* length, int* status ) ;
   8
   9 ERROR: demangle-memory-allocation-failure ;
  10 ERROR: invalid-mangled-name name ;
  11 ERROR: invalid-demangle-args name ;
  12
  13 : demangle-error ( name status -- )
  14     {
  15         {  0 [ drop ] }
  16         { -1 [ drop demangle-memory-allocation-failure ] }
  17         { -2 [ invalid-mangled-name ] }
  18         { -3 [ invalid-demangle-args ] }
  19     } case ;
  20
  21 : mangled-name? ( name -- ? )
  22     "_Z" head? ;
  23
  24 :: demangle ( mangled-name -- c++-name )
  25     0 ulong <ref> :> length
  26     0 int <ref> :> status [
  27         mangled-name ascii string>alien f length status __cxa_demangle &(free) :> demangled-buf
  28         mangled-name status int deref demangle-error
  29         demangled-buf ascii alien>string
  30     ] with-destructors ;