extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See https://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private kernel math math.statistics
   4 sequences sets ;
   5 IN: assocs.extras
   6
   7 : change-of ( ..a assoc key quot: ( ..a value -- ..b newvalue ) -- ..b assoc )
   8     [ [ of ] dip call ] 2keepd rot set-of ; inline
   9
  10 : of* ( assoc key -- value/f ? ) swap at* ; inline
  11
  12 : of+ ( assoc key n -- assoc ) '[ 0 or _ + ] change-of ; inline
  13
  14 : of+* ( assoc key n -- assoc old new )
  15     '[ [ 0 or _ + ] keep swap dup ] change-of ; inline
  16
  17 : delete-of ( assoc key -- assoc ) over delete-at ; inline
  18
  19 : delete-of* ( assoc key -- assoc value/f ? )
  20     [ of* ] [ delete-of -rot ] 2bi ;
  21
  22 : ?delete-of ( assoc key -- assoc value/key ? )
  23     [ ?of ] [ delete-of -rot ] 2bi ;
  24
  25 : delete-keys-of ( assoc keys -- assoc )
  26     [ delete-of ] each ;
  27
  28 : rename-of ( assoc key newkey -- assoc )
  29     [ delete-of* ] dip swap [ set-of ] [ 2drop ] if ;
  30
  31 : inc-of ( assoc key -- assoc ) 1 of+ ; inline
  32
  33 : inc-of* ( assoc key -- assoc old new ) 1 of+* ; inline
  34
  35 : ?change-of ( ..a assoc key quot: ( ..a value -- ..b newvalue ) -- ..b assoc )
  36     [ set-of ] compose [ 2dup ?of ] dip [ 2drop ] if ; inline
  37
  38 : maybe-set-of ( assoc key value -- assoc changed? )
  39     [ 2dup ?of ] dip swap
  40     [ dupd = [ 2drop f ] [ set-of t ] if ] [ nip set-of t ] if ;
  41
  42 : push-of ( assoc key value -- assoc )
  43     swap pick push-at ; inline
  44
  45 : push-at-each ( value keys assoc -- )
  46     '[ _ push-at ] with each ; inline
  47
  48 : deep-of ( assoc seq -- value/f )
  49     [ of ] each ; inline
  50
  51 : deep-of-but-last ( assoc seq -- obj key )
  52     unclip-last [ [ of ] each ] dip ; inline
  53
  54 : deep-change-of ( assoc seq quot -- )
  55     [ deep-of-but-last swap ] dip change-at ; inline
  56
  57 : deep-set-of ( assoc seq elt -- )
  58     [ deep-of-but-last ] dip spin set-at ; inline
  59
  60 : substitute! ( seq assoc -- seq )
  61     substituter map! ;
  62
  63 : rekey-new-assoc ( assoc keys -- newassoc )
  64     [ tuck of ] with H{ } map>assoc ; inline
  65
  66 : rekey-assoc ( assoc keys -- assoc )
  67     [ dup keys ] dip diff over [ delete-at ] curry each ; inline
  68
  69 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  70     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  71
  72 : assoc-invert-as ( assoc exemplar -- newassoc )
  73     [ swap ] swap assoc-map-as ;
  74
  75 : assoc-invert ( assoc -- newassoc )
  76     dup assoc-invert-as ;
  77
  78 : assoc-collect! ( assoc1 assoc2 -- assoc1 )
  79     over [ push-at ] with-assoc assoc-each ;
  80
  81 : assoc-collect ( assoc1 assoc2 -- newassoc )
  82     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  83     [ assoc-collect! ] bi@ ;
  84
  85 ! iterate over assoc2, replace conflicting values
  86 ! Modifies assoc1
  87 : assoc-merge! ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- assoc1' )
  88     [| key2 val2 quot | val2 key2 pick
  89     at* [ swap quot call ] [ drop ] if
  90     key2 pick set-at ] curry assoc-each ; inline
  91
  92 ! Same as above, non-destructive
  93 : assoc-merge ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- new-assoc )
  94     pick [ [ clone ] 2dip assoc-merge! ]
  95     [ drop nip ] if
  96     ; inline
  97
  98 ! Successively apply assoc-merge operation
  99 : assoc-collapse ( seq quot: ( value1 value2 -- new-value ) -- assoc )
 100     over empty?
 101     [ 2drop f ]
 102     [ [ unclip-slice H{ } or clone ] [ [ assoc-merge! ] curry ] bi* reduce ] if ; inline
 103
 104 : assoc-collapse! ( assoc seq quot: ( value1 value2 -- new-value ) -- assoc )
 105     [ assoc-merge! ] curry each ; inline
 106
 107 : assoc-collapse-as ( seq quot: ( value1 value2 -- new-value ) exemplar -- assoc )
 108     pick first assoc-size swap new-assoc
 109     -rot assoc-collapse! ; inline
 110
 111 GENERIC: delete-value-at ( value assoc -- )
 112
 113 M: assoc delete-value-at
 114     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
 115
 116 ERROR: key-exists value key assoc ;
 117 : set-once-at ( value key assoc -- )
 118     2dup ?at [
 119         key-exists
 120     ] [
 121         drop set-at
 122     ] if ;
 123
 124 : ?set-once-at ( value key assoc -- value' first-time? )
 125     [ ?at not ] keep '[ [  _ set-at ] keepd t ] [ nip f ] if ;
 126
 127 : kv-with ( obj assoc quot -- assoc curried )
 128     swapd [ -rotd call ] 2curry ; inline
 129
 130 <PRIVATE
 131
 132 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 133     [ swap curry compose each ] keep ; inline
 134
 135 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 136     [ swap curry compose each-index ] keep ; inline
 137
 138 PRIVATE>
 139
 140 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 141     roll (sequence>assoc) ; inline
 142
 143 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
 144     clone [ swap curry compose assoc-each ] keep ; inline
 145
 146 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
 147     roll assoc>object ; inline
 148
 149 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 150     clone (sequence>assoc) ; inline
 151
 152 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 153     clone (sequence-index>assoc) ; inline
 154
 155 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 156     H{ } sequence-index>assoc ; inline
 157
 158 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 159     H{ } sequence>assoc ; inline
 160
 161 : ?1array ( obj -- seq ) dup sequence? [ 1array ] unless ; inline
 162
 163 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 164     [
 165         [ swap ?1array ]
 166         [ '[ _ set-at ] with each ]
 167     ] dip assoc>object ;
 168
 169 : expand-keys-set-at ( assoc -- hashtable' )
 170     H{ } expand-keys-set-at-as ;
 171
 172 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 173     [
 174         [ swap ?1array ]
 175         [ push-at-each ]
 176     ] dip assoc>object ;
 177
 178 : expand-keys-push-at ( assoc -- hashtable' )
 179     H{ } expand-keys-push-at-as ; inline
 180
 181 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 182     [
 183         [ [ ?1array ] dip ]
 184         [ '[ _ 2array _ push ] each ]
 185     ] dip assoc>object ;
 186
 187 : expand-keys-push ( assoc -- hashtable' )
 188     V{ } expand-keys-push-as ; inline
 189
 190 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 191     [
 192         [ ?1array swap ]
 193         [ '[ _ _ set-at ] each ]
 194     ] dip assoc>object ;
 195
 196 : expand-values-set-at ( assoc -- hashtable' )
 197     H{ } expand-values-set-at-as ; inline
 198
 199 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 200     [
 201         [ ?1array swap ]
 202         [ '[ _ _ push-at ] each ]
 203     ] dip assoc>object ;
 204
 205 : expand-values-push-at ( assoc -- assoc )
 206     H{ } expand-values-push-at-as ; inline
 207
 208 : expand-values-push-as ( assoc exemplar -- assoc )
 209     [
 210         [ ?1array ]
 211         [ '[ 2array _ push ] with each ]
 212     ] dip assoc>object ;
 213
 214 : expand-values-push ( assoc -- sequence )
 215     V{ } expand-values-push-as ; inline
 216
 217 : any-multi-key? ( assoc -- ? ) [ sequence? ] any-key? ;
 218
 219 : any-multi-value? ( assoc -- ? ) [ sequence? ] any-value? ;
 220
 221 : flatten-keys ( assoc -- assoc' )
 222     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 223
 224 : flatten-values ( assoc -- assoc' )
 225     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 226
 227 : intersect-keys-as ( assoc seq exemplar -- elts )
 228   [ [ of ] with ] dip zip-with-as sift-values ; inline
 229
 230 : intersect-keys ( assoc seq -- elts )
 231     over intersect-keys-as ; inline
 232
 233 : values-of ( assoc seq -- seq' )
 234     [ of ] with map ; inline
 235
 236 : counts ( seq elts -- counts )
 237     [ histogram ] dip intersect-keys ;
 238
 239 : histogram-diff ( hashtable1 hashtable2 -- hashtable3 )
 240     [ neg swap pick at+ ] assoc-each
 241     [ 0 > ] filter-values ;
 242
 243 : collect-by-multi! ( ... assoc seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 244     [ keep swap ] curry rot [
 245         [ push-at-each ] curry compose each
 246     ] keep ; inline
 247
 248 : collect-by-multi ( ... seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 249     [ H{ } clone ] 2dip collect-by-multi! ; inline
 250
 251
 252 : collect-assoc-by! ( ... assoc input-assoc quot: ( ... key value -- ... key' value' ) -- ... assoc )
 253     rot [ '[ @ swap _ push-at ] assoc-each ] keep ; inline
 254
 255 : collect-assoc-by ( ... input-assoc quot: ( ... key value -- ... key value ) -- ... assoc )
 256     [ H{ } clone ] 2dip collect-assoc-by! ; inline
 257
 258 : collect-key-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 259     '[ _ keepd ] collect-assoc-by! ; inline
 260
 261 : collect-key-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 262     [ H{ } clone ] 2dip collect-key-by! ; inline
 263
 264 : collect-value-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 265     '[ _ keep ] collect-assoc-by! ; inline
 266
 267 : collect-value-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 268     [ H{ } clone ] 2dip collect-value-by! ; inline
 269
 270
 271 : collect-assoc-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 272     rot [ '[ @ swap _ push-at-each ] assoc-each ] keep ; inline
 273
 274 : collect-assoc-by-multi ( ... assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 275     [ H{ } clone ] 2dip collect-assoc-by-multi! ; inline
 276
 277
 278 : collect-key-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 279     '[ _ keepd ] collect-assoc-by-multi! ; inline
 280
 281 : collect-key-by-multi ( ... assoc quot: ( ... key -- ... new-keys ) -- ... assoc )
 282     [ H{ } clone ] 2dip collect-key-by-multi! ; inline
 283
 284
 285 : collect-value-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 286     '[ _ keep ] collect-assoc-by-multi! ; inline
 287
 288 : collect-value-by-multi ( ... assoc quot: ( ... value -- ... new-keys ) -- ... assoc )
 289     [ H{ } clone ] 2dip collect-value-by-multi! ; inline
 290
 291 : assoc-operator* ( assoc quot -- alist quot' )
 292     [ >alist ] dip [ first2 swap ] prepose ; inline
 293
 294 : assoc-each* ( ... assoc quot: ( ... value key -- ... ) -- ... )
 295     assoc-operator* each ; inline
 296
 297 : collect-index-by! ( ... assoc seq quot: ( ... obj -- ... key ) -- ... assoc )
 298     rot [ '[ @ swap _ push-at ] each-index ] keep ; inline
 299
 300 : collect-index-by ( ... seq quot: ( ... obj -- ... key ) -- ... assoc )
 301     [ H{ } clone ] 2dip collect-index-by! ; inline
 302
 303 : assoc-interleave ( ... assoc between quot: ( ... key value -- ... ) -- ... )
 304     [ >alist ] 2dip [ first2 ] prepose interleave ; inline