extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See https://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private kernel math math.statistics
   4 sequences sets ;
   5 IN: assocs.extras
   6
   7 : push-at-each ( value keys assoc -- )
   8     '[ _ push-at ] with each ; inline
   9
  10 : deep-of ( assoc seq -- value/f )
  11     [ of ] each ; inline
  12
  13 : deep-of-but-last ( assoc seq -- obj key )
  14     unclip-last [ [ of ] each ] dip ; inline
  15
  16 : deep-change-of ( assoc seq quot -- )
  17     [ deep-of-but-last swap ] dip change-at ; inline
  18
  19 : deep-set-of ( assoc seq elt -- )
  20     [ deep-of-but-last ] dip spin set-at ; inline
  21
  22 : substitute! ( seq assoc -- seq )
  23     substituter map! ;
  24
  25 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  26     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  27
  28 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  29     [ drop ] prepose assoc-reduce ; inline
  30
  31 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  32     [ nip ] prepose assoc-reduce ; inline
  33
  34 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  35
  36 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  37
  38 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
  39     '[ _ dip ] assoc-map ; inline
  40
  41 : map-values ( assoc quot: ( value -- value' ) -- assoc )
  42     '[ swap _ dip swap ] assoc-map ; inline
  43
  44 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
  45     '[ drop @ ] assoc-filter ; inline
  46
  47 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
  48     '[ nip @ ] assoc-filter ; inline
  49
  50 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
  51     '[ drop @ ] assoc-reject ; inline
  52
  53 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
  54     '[ nip @ ] assoc-reject ; inline
  55
  56 : rekey-new-assoc ( assoc keys -- newassoc )
  57     [ tuck of ] with H{ } map>assoc ; inline
  58
  59 : rekey-assoc ( assoc keys -- assoc )
  60     [ dup keys ] dip diff over [ delete-at ] curry each ; inline
  61
  62 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  63     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  64
  65 : assoc-invert-as ( assoc exemplar -- newassoc )
  66     [ swap ] swap assoc-map-as ;
  67
  68 : assoc-invert ( assoc -- newassoc )
  69     dup assoc-invert-as ;
  70
  71 : assoc-collect! ( assoc1 assoc2 -- assoc1 )
  72     over [ push-at ] with-assoc assoc-each ;
  73
  74 : assoc-collect ( assoc1 assoc2 -- newassoc )
  75     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  76     [ assoc-collect! ] bi@ ;
  77
  78 ! iterate over assoc2, replace conflicting values
  79 ! Modifies assoc1
  80 : assoc-merge! ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- assoc1' )
  81     [| key2 val2 quot | val2 key2 pick
  82     at* [ swap quot call ] [ drop ] if
  83     key2 pick set-at ] curry assoc-each ; inline
  84
  85 ! Same as above, non-destructive
  86 : assoc-merge ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- new-assoc )
  87     pick [ [ clone ] 2dip assoc-merge! ]
  88     [ drop nip ] if
  89     ; inline
  90
  91 ! Successively apply assoc-merge operation
  92 : assoc-collapse ( seq quot: ( value1 value2 -- new-value ) -- assoc )
  93     over empty?
  94     [ 2drop f ]
  95     [ [ unclip-slice H{ } or clone ] [ [ assoc-merge! ] curry ] bi* reduce ] if ; inline
  96
  97 : assoc-collapse! ( assoc seq quot: ( value1 value2 -- new-value ) -- assoc )
  98     [ assoc-merge! ] curry each ; inline
  99
 100 : assoc-collapse-as ( seq quot: ( value1 value2 -- new-value ) exemplar -- assoc )
 101     pick first assoc-size swap new-assoc
 102     -rot assoc-collapse! ; inline
 103
 104 GENERIC: delete-value-at ( value assoc -- )
 105
 106 M: assoc delete-value-at
 107     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
 108
 109 ERROR: key-exists value key assoc ;
 110 : set-once-at ( value key assoc -- )
 111     2dup ?at [
 112         key-exists
 113     ] [
 114         drop set-at
 115     ] if ;
 116
 117 : kv-with ( obj assoc quot -- assoc curried )
 118     swapd [ -rotd call ] 2curry ; inline
 119
 120 <PRIVATE
 121
 122 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 123     [ swap curry compose each ] keep ; inline
 124
 125 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 126     [ swap curry compose each-index ] keep ; inline
 127
 128 PRIVATE>
 129
 130 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 131     roll (sequence>assoc) ; inline
 132
 133 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
 134     clone [ swap curry compose assoc-each ] keep ; inline
 135
 136 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
 137     roll assoc>object ; inline
 138
 139 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 140     clone (sequence>assoc) ; inline
 141
 142 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 143     clone (sequence-index>assoc) ; inline
 144
 145 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 146     H{ } sequence-index>assoc ; inline
 147
 148 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 149     H{ } sequence>assoc ; inline
 150
 151 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 152     [
 153         [ swap dup sequence? [ 1array ] unless ]
 154         [ '[ _ set-at ] with each ]
 155     ] dip assoc>object ;
 156
 157 : expand-keys-set-at ( assoc -- hashtable' )
 158     H{ } expand-keys-set-at-as ;
 159
 160 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 161     [
 162         [ swap dup sequence? [ 1array ] unless ]
 163         [ push-at-each ]
 164     ] dip assoc>object ;
 165
 166 : expand-keys-push-at ( assoc -- hashtable' )
 167     H{ } expand-keys-push-at-as ; inline
 168
 169 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 170     [
 171         [ [ dup sequence? [ 1array ] unless ] dip ]
 172         [ '[ _ 2array _ push ] each ]
 173     ] dip assoc>object ;
 174
 175 : expand-keys-push ( assoc -- hashtable' )
 176     V{ } expand-keys-push-as ; inline
 177
 178 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 179     [
 180         [ dup sequence? [ 1array ] unless swap ]
 181         [ '[ _ _ set-at ] each ]
 182     ] dip assoc>object ;
 183
 184 : expand-values-set-at ( assoc -- hashtable' )
 185     H{ } expand-values-set-at-as ; inline
 186
 187 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 188     [
 189         [ dup sequence? [ 1array ] unless swap ]
 190         [ '[ _ _ push-at ] each ]
 191     ] dip assoc>object ;
 192
 193 : expand-values-push-at ( assoc -- assoc )
 194     H{ } expand-values-push-at-as ; inline
 195
 196 : expand-values-push-as ( assoc exemplar -- assoc )
 197     [
 198         [ dup sequence? [ 1array ] unless ]
 199         [ '[ 2array _ push ] with each ]
 200     ] dip assoc>object ;
 201
 202 : expand-values-push ( assoc -- sequence )
 203     V{ } expand-values-push-as ; inline
 204
 205 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 206     [ drop ] prepose assoc-find 2nip ; inline
 207
 208 : assoc-any-value? ( ... assoc quot: ( ... value -- ... ? ) -- ... ? )
 209     [ nip ] prepose assoc-find 2nip ; inline
 210
 211 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 212     [ not ] compose assoc-any-key? not ; inline
 213
 214 : assoc-all-value? ( ... assoc quot: ( ... value -- ... ? ) -- ... ? )
 215     [ not ] compose assoc-any-value? not ; inline
 216
 217 : any-multi-key? ( assoc -- ? )
 218     [ sequence? ] assoc-any-key? ;
 219
 220 : any-multi-value? ( assoc -- ? )
 221     [ sequence? ] assoc-any-value? ;
 222
 223 : flatten-keys ( assoc -- assoc' )
 224     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 225
 226 : flatten-values ( assoc -- assoc' )
 227     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 228
 229 : intersect-keys-as ( assoc seq exemplar -- elts )
 230   [ [ of ] with ] dip zip-with-as sift-values ; inline
 231
 232 : intersect-keys ( assoc seq -- elts )
 233     over intersect-keys-as ; inline
 234
 235 : values-of ( assoc seq -- seq' )
 236     [ of ] with map ; inline
 237
 238 : counts ( seq elts -- counts )
 239     [ histogram ] dip intersect-keys ;
 240
 241 : histogram-diff ( hashtable1 hashtable2 -- hashtable3 )
 242     [ neg swap pick at+ ] assoc-each
 243     [ 0 > ] filter-values ;
 244
 245 : collect-by-multi! ( ... assoc seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 246     [ keep swap ] curry rot [
 247         [ push-at-each ] curry compose each
 248     ] keep ; inline
 249
 250 : collect-by-multi ( ... seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 251     [ H{ } clone ] 2dip collect-by-multi! ; inline
 252
 253
 254 : collect-assoc-by! ( ... assoc input-assoc quot: ( ... key value -- ... key' value' ) -- ... assoc )
 255     rot [ '[ @ swap _ push-at ] assoc-each ] keep ; inline
 256
 257 : collect-assoc-by ( ... input-assoc quot: ( ... key value -- ... key value ) -- ... assoc )
 258     [ H{ } clone ] 2dip collect-assoc-by! ; inline
 259
 260 : collect-key-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 261     '[ _ keepd ] collect-assoc-by! ; inline
 262
 263 : collect-key-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 264     [ H{ } clone ] 2dip collect-key-by! ; inline
 265
 266 : collect-value-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 267     '[ _ keep ] collect-assoc-by! ; inline
 268
 269 : collect-value-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 270     [ H{ } clone ] 2dip collect-value-by! ; inline
 271
 272
 273 : collect-assoc-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 274     rot [ '[ @ swap _ push-at-each ] assoc-each ] keep ; inline
 275
 276 : collect-assoc-by-multi ( ... assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 277     [ H{ } clone ] 2dip collect-assoc-by-multi! ; inline
 278
 279
 280 : collect-key-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 281     '[ _ keepd ] collect-assoc-by-multi! ; inline
 282
 283 : collect-key-by-multi ( ... assoc quot: ( ... key -- ... new-keys ) -- ... assoc )
 284     [ H{ } clone ] 2dip collect-key-by-multi! ; inline
 285
 286
 287 : collect-value-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 288     '[ _ keep ] collect-assoc-by-multi! ; inline
 289
 290 : collect-value-by-multi ( ... assoc quot: ( ... value -- ... new-keys ) -- ... assoc )
 291     [ H{ } clone ] 2dip collect-value-by-multi! ; inline