extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See https://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private kernel math math.statistics
   4 sequences sets ;
   5 IN: assocs.extras
   6
   7 : change-of ( ..a assoc key quot: ( ..a value -- ..b newvalue ) -- ..b assoc )
   8     [ [ of ] dip call ] 2keepd rot set-of ; inline
   9
  10 : of* ( assoc key -- value/f ? ) swap at* ; inline
  11
  12 : of+ ( assoc key n -- assoc ) '[ 0 or _ + ] change-of ; inline
  13
  14 : of+* ( assoc key n -- assoc old new ) '[ [ 0 or _ + ] keep swap dup ] change-of ; inline
  15
  16 : delete-of ( assoc key -- assoc ) over delete-at ; inline
  17
  18 : delete-of* ( assoc key -- assoc value/f ? )
  19     [ of* ] [ delete-of -rot ] 2bi ;
  20
  21 : ?delete-of ( assoc key -- assoc value/key ? )
  22     [ ?of ] [ delete-of -rot ] 2bi ;
  23
  24 : rename-of ( assoc key newkey -- assoc )
  25     [ delete-of* ] dip swap [ set-of ] [ 2drop ] if ;
  26
  27 : inc-of ( assoc key -- assoc ) 1 of+ ; inline
  28
  29 : inc-of* ( assoc key -- assoc old new ) 1 of+* ; inline
  30
  31 : ?change-of ( ..a assoc key quot: ( ..a value -- ..b newvalue ) -- ..b assoc )
  32     [ set-of ] compose [ 2dup ?of ] dip [ 2drop ] if ; inline
  33
  34 : maybe-set-of ( assoc key value -- assoc changed? )
  35     [ 2dup ?of ] dip swap
  36     [ dupd = [ 2drop f ] [ set-of t ] if ] [ nip set-of t ] if ;
  37
  38 : push-of ( assoc key value -- assoc )
  39     swap pick push-at ; inline
  40
  41 : push-at-each ( value keys assoc -- )
  42     '[ _ push-at ] with each ; inline
  43
  44 : deep-of ( assoc seq -- value/f )
  45     [ of ] each ; inline
  46
  47 : deep-of-but-last ( assoc seq -- obj key )
  48     unclip-last [ [ of ] each ] dip ; inline
  49
  50 : deep-change-of ( assoc seq quot -- )
  51     [ deep-of-but-last swap ] dip change-at ; inline
  52
  53 : deep-set-of ( assoc seq elt -- )
  54     [ deep-of-but-last ] dip spin set-at ; inline
  55
  56 : substitute! ( seq assoc -- seq )
  57     substituter map! ;
  58
  59 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  60     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  61
  62 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  63     [ drop ] prepose assoc-reduce ; inline
  64
  65 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  66     [ nip ] prepose assoc-reduce ; inline
  67
  68 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  69
  70 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  71
  72 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
  73     '[ _ dip ] assoc-map ; inline
  74
  75 : map-values ( assoc quot: ( value -- value' ) -- assoc )
  76     '[ swap _ dip swap ] assoc-map ; inline
  77
  78 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
  79     '[ drop @ ] assoc-filter ; inline
  80
  81 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
  82     '[ nip @ ] assoc-filter ; inline
  83
  84 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
  85     '[ drop @ ] assoc-reject ; inline
  86
  87 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
  88     '[ nip @ ] assoc-reject ; inline
  89
  90 : rekey-new-assoc ( assoc keys -- newassoc )
  91     [ tuck of ] with H{ } map>assoc ; inline
  92
  93 : rekey-assoc ( assoc keys -- assoc )
  94     [ dup keys ] dip diff over [ delete-at ] curry each ; inline
  95
  96 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  97     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  98
  99 : assoc-invert-as ( assoc exemplar -- newassoc )
 100     [ swap ] swap assoc-map-as ;
 101
 102 : assoc-invert ( assoc -- newassoc )
 103     dup assoc-invert-as ;
 104
 105 : assoc-collect! ( assoc1 assoc2 -- assoc1 )
 106     over [ push-at ] with-assoc assoc-each ;
 107
 108 : assoc-collect ( assoc1 assoc2 -- newassoc )
 109     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
 110     [ assoc-collect! ] bi@ ;
 111
 112 ! iterate over assoc2, replace conflicting values
 113 ! Modifies assoc1
 114 : assoc-merge! ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- assoc1' )
 115     [| key2 val2 quot | val2 key2 pick
 116     at* [ swap quot call ] [ drop ] if
 117     key2 pick set-at ] curry assoc-each ; inline
 118
 119 ! Same as above, non-destructive
 120 : assoc-merge ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- new-assoc )
 121     pick [ [ clone ] 2dip assoc-merge! ]
 122     [ drop nip ] if
 123     ; inline
 124
 125 ! Successively apply assoc-merge operation
 126 : assoc-collapse ( seq quot: ( value1 value2 -- new-value ) -- assoc )
 127     over empty?
 128     [ 2drop f ]
 129     [ [ unclip-slice H{ } or clone ] [ [ assoc-merge! ] curry ] bi* reduce ] if ; inline
 130
 131 : assoc-collapse! ( assoc seq quot: ( value1 value2 -- new-value ) -- assoc )
 132     [ assoc-merge! ] curry each ; inline
 133
 134 : assoc-collapse-as ( seq quot: ( value1 value2 -- new-value ) exemplar -- assoc )
 135     pick first assoc-size swap new-assoc
 136     -rot assoc-collapse! ; inline
 137
 138 GENERIC: delete-value-at ( value assoc -- )
 139
 140 M: assoc delete-value-at
 141     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
 142
 143 ERROR: key-exists value key assoc ;
 144 : set-once-at ( value key assoc -- )
 145     2dup ?at [
 146         key-exists
 147     ] [
 148         drop set-at
 149     ] if ;
 150
 151 : kv-with ( obj assoc quot -- assoc curried )
 152     swapd [ -rotd call ] 2curry ; inline
 153
 154 <PRIVATE
 155
 156 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 157     [ swap curry compose each ] keep ; inline
 158
 159 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 160     [ swap curry compose each-index ] keep ; inline
 161
 162 PRIVATE>
 163
 164 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 165     roll (sequence>assoc) ; inline
 166
 167 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
 168     clone [ swap curry compose assoc-each ] keep ; inline
 169
 170 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
 171     roll assoc>object ; inline
 172
 173 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 174     clone (sequence>assoc) ; inline
 175
 176 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 177     clone (sequence-index>assoc) ; inline
 178
 179 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 180     H{ } sequence-index>assoc ; inline
 181
 182 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 183     H{ } sequence>assoc ; inline
 184
 185 : ?1array ( obj -- seq ) dup sequence? [ 1array ] unless ; inline
 186
 187 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 188     [
 189         [ swap ?1array ]
 190         [ '[ _ set-at ] with each ]
 191     ] dip assoc>object ;
 192
 193 : expand-keys-set-at ( assoc -- hashtable' )
 194     H{ } expand-keys-set-at-as ;
 195
 196 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 197     [
 198         [ swap ?1array ]
 199         [ push-at-each ]
 200     ] dip assoc>object ;
 201
 202 : expand-keys-push-at ( assoc -- hashtable' )
 203     H{ } expand-keys-push-at-as ; inline
 204
 205 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 206     [
 207         [ [ ?1array ] dip ]
 208         [ '[ _ 2array _ push ] each ]
 209     ] dip assoc>object ;
 210
 211 : expand-keys-push ( assoc -- hashtable' )
 212     V{ } expand-keys-push-as ; inline
 213
 214 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 215     [
 216         [ ?1array swap ]
 217         [ '[ _ _ set-at ] each ]
 218     ] dip assoc>object ;
 219
 220 : expand-values-set-at ( assoc -- hashtable' )
 221     H{ } expand-values-set-at-as ; inline
 222
 223 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 224     [
 225         [ ?1array swap ]
 226         [ '[ _ _ push-at ] each ]
 227     ] dip assoc>object ;
 228
 229 : expand-values-push-at ( assoc -- assoc )
 230     H{ } expand-values-push-at-as ; inline
 231
 232 : expand-values-push-as ( assoc exemplar -- assoc )
 233     [
 234         [ ?1array ]
 235         [ '[ 2array _ push ] with each ]
 236     ] dip assoc>object ;
 237
 238 : expand-values-push ( assoc -- sequence )
 239     V{ } expand-values-push-as ; inline
 240
 241 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 242     [ drop ] prepose assoc-find 2nip ; inline
 243
 244 : assoc-any-value? ( ... assoc quot: ( ... value -- ... ? ) -- ... ? )
 245     [ nip ] prepose assoc-find 2nip ; inline
 246
 247 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 248     [ not ] compose assoc-any-key? not ; inline
 249
 250 : assoc-all-value? ( ... assoc quot: ( ... value -- ... ? ) -- ... ? )
 251     [ not ] compose assoc-any-value? not ; inline
 252
 253 : any-multi-key? ( assoc -- ? )
 254     [ sequence? ] assoc-any-key? ;
 255
 256 : any-multi-value? ( assoc -- ? )
 257     [ sequence? ] assoc-any-value? ;
 258
 259 : flatten-keys ( assoc -- assoc' )
 260     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 261
 262 : flatten-values ( assoc -- assoc' )
 263     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 264
 265 : intersect-keys-as ( assoc seq exemplar -- elts )
 266   [ [ of ] with ] dip zip-with-as sift-values ; inline
 267
 268 : intersect-keys ( assoc seq -- elts )
 269     over intersect-keys-as ; inline
 270
 271 : values-of ( assoc seq -- seq' )
 272     [ of ] with map ; inline
 273
 274 : counts ( seq elts -- counts )
 275     [ histogram ] dip intersect-keys ;
 276
 277 : histogram-diff ( hashtable1 hashtable2 -- hashtable3 )
 278     [ neg swap pick at+ ] assoc-each
 279     [ 0 > ] filter-values ;
 280
 281 : collect-by-multi! ( ... assoc seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 282     [ keep swap ] curry rot [
 283         [ push-at-each ] curry compose each
 284     ] keep ; inline
 285
 286 : collect-by-multi ( ... seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 287     [ H{ } clone ] 2dip collect-by-multi! ; inline
 288
 289
 290 : collect-assoc-by! ( ... assoc input-assoc quot: ( ... key value -- ... key' value' ) -- ... assoc )
 291     rot [ '[ @ swap _ push-at ] assoc-each ] keep ; inline
 292
 293 : collect-assoc-by ( ... input-assoc quot: ( ... key value -- ... key value ) -- ... assoc )
 294     [ H{ } clone ] 2dip collect-assoc-by! ; inline
 295
 296 : collect-key-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 297     '[ _ keepd ] collect-assoc-by! ; inline
 298
 299 : collect-key-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 300     [ H{ } clone ] 2dip collect-key-by! ; inline
 301
 302 : collect-value-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 303     '[ _ keep ] collect-assoc-by! ; inline
 304
 305 : collect-value-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 306     [ H{ } clone ] 2dip collect-value-by! ; inline
 307
 308
 309 : collect-assoc-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 310     rot [ '[ @ swap _ push-at-each ] assoc-each ] keep ; inline
 311
 312 : collect-assoc-by-multi ( ... assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 313     [ H{ } clone ] 2dip collect-assoc-by-multi! ; inline
 314
 315
 316 : collect-key-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 317     '[ _ keepd ] collect-assoc-by-multi! ; inline
 318
 319 : collect-key-by-multi ( ... assoc quot: ( ... key -- ... new-keys ) -- ... assoc )
 320     [ H{ } clone ] 2dip collect-key-by-multi! ; inline
 321
 322
 323 : collect-value-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 324     '[ _ keep ] collect-assoc-by-multi! ; inline
 325
 326 : collect-value-by-multi ( ... assoc quot: ( ... value -- ... new-keys ) -- ... assoc )
 327     [ H{ } clone ] 2dip collect-value-by-multi! ; inline
 328
 329 : assoc-operator* ( assoc quot -- alist quot' )
 330     [ >alist ] dip [ first2 swap ] prepose ; inline
 331
 332 : assoc-each* ( ... assoc quot: ( ... value key -- ... ) -- ... )
 333     assoc-operator* each ; inline