extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See https://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private kernel math math.statistics
   4 sequences sequences.extras sets ;
   5 IN: assocs.extras
   6
   7 : of* ( assoc key -- value/f ? ) swap at* ; inline
   8
   9 : of+ ( assoc key n -- assoc ) '[ 0 or _ + ] change-of ; inline
  10
  11 : of+* ( assoc key n -- assoc old new ) '[ [ 0 or _ + ] keep swap dup ] change-of ; inline
  12
  13 : delete-of ( assoc key -- assoc ) over delete-at ; inline
  14
  15 : delete-of* ( assoc key -- assoc value/f ? )
  16     [ of* ] [ delete-of -rot ] 2bi ;
  17
  18 : ?delete-of ( assoc key -- assoc value/key ? )
  19     [ ?of ] [ delete-of -rot ] 2bi ;
  20
  21 : rename-of ( assoc key newkey -- assoc )
  22     [ delete-of* ] dip swap [ set-of ] [ 2drop ] if ;
  23
  24 : at+* ( n key assoc -- old new ) [ 0 or [ + ] keep swap dup ] change-at ; inline
  25
  26 : inc-at* ( key assoc -- old new ) [ 1 ] 2dip at+* ; inline
  27
  28 : inc-of ( assoc key -- assoc ) 1 of+ ; inline
  29
  30 : inc-of* ( assoc key -- assoc old new ) 1 of+* ; inline
  31
  32 : change-of ( ..a assoc key quot: ( ..a value -- ..b newvalue ) -- ..b assoc )
  33     [ [ of ] dip call ] 2keepd rot set-of ; inline
  34
  35 : ?change-of ( ..a assoc key quot: ( ..a value -- ..b newvalue ) -- ..b assoc )
  36     [ set-of ] compose [ 2dup ?of ] dip [ 2drop ] if ; inline
  37
  38 : maybe-set-of ( assoc key value -- assoc changed? )
  39     [ 2dup ?of ] dip swap
  40     [ dupd = [ 2drop f ] [ set-of t ] if ] [ nip set-of t ] if ;
  41
  42 : push-of ( assoc key value -- assoc )
  43     swap pick push-at ; inline
  44
  45 : push-at-each ( value keys assoc -- )
  46     '[ _ push-at ] with each ; inline
  47
  48 : deep-of ( assoc seq -- value/f )
  49     [ of ] each ; inline
  50
  51 : deep-of-but-last ( assoc seq -- obj key )
  52     unclip-last [ [ of ] each ] dip ; inline
  53
  54 : deep-change-of ( assoc seq quot -- )
  55     [ deep-of-but-last swap ] dip change-at ; inline
  56
  57 : deep-set-of ( assoc seq elt -- )
  58     [ deep-of-but-last ] dip spin set-at ; inline
  59
  60 : zip-longest-with ( seq1 seq2 fill -- assoc )
  61     pad-longest zip ;
  62
  63 : zip-longest ( seq1 seq2 -- assoc )
  64     f zip-longest-with ;
  65
  66 : substitute! ( seq assoc -- seq )
  67     substituter map! ;
  68
  69 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  70     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  71
  72 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  73     [ drop ] prepose assoc-reduce ; inline
  74
  75 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  76     [ nip ] prepose assoc-reduce ; inline
  77
  78 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  79
  80 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  81
  82 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
  83     '[ _ dip ] assoc-map ; inline
  84
  85 : map-values ( assoc quot: ( value -- value' ) -- assoc )
  86     '[ swap _ dip swap ] assoc-map ; inline
  87
  88 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
  89     '[ drop @ ] assoc-filter ; inline
  90
  91 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
  92     '[ nip @ ] assoc-filter ; inline
  93
  94 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
  95     '[ drop @ ] assoc-reject ; inline
  96
  97 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
  98     '[ nip @ ] assoc-reject ; inline
  99
 100 : rekey-new-assoc ( assoc keys -- newassoc )
 101     [ tuck of ] with H{ } map>assoc ; inline
 102
 103 : rekey-assoc ( assoc keys -- assoc )
 104     [ dup keys ] dip diff over [ delete-at ] curry each ; inline
 105
 106 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
 107     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
 108
 109 : assoc-invert-as ( assoc exemplar -- newassoc )
 110     [ swap ] swap assoc-map-as ;
 111
 112 : assoc-invert ( assoc -- newassoc )
 113     dup assoc-invert-as ;
 114
 115 : assoc-collect! ( assoc1 assoc2 -- assoc1 )
 116     over [ push-at ] with-assoc assoc-each ;
 117
 118 : assoc-collect ( assoc1 assoc2 -- newassoc )
 119     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
 120     [ assoc-collect! ] bi@ ;
 121
 122 ! iterate over assoc2, replace conflicting values
 123 ! Modifies assoc1
 124 : assoc-merge! ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- assoc1' )
 125     [| key2 val2 quot | val2 key2 pick
 126     at* [ swap quot call ] [ drop ] if
 127     key2 pick set-at ] curry assoc-each ; inline
 128
 129 ! Same as above, non-destructive
 130 : assoc-merge ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- new-assoc )
 131     pick [ [ clone ] 2dip assoc-merge! ]
 132     [ drop nip ] if
 133     ; inline
 134
 135 ! Successively apply assoc-merge operation
 136 : assoc-collapse ( seq quot: ( value1 value2 -- new-value ) -- assoc )
 137     over empty?
 138     [ 2drop f ]
 139     [ [ unclip-slice H{ } or clone ] [ [ assoc-merge! ] curry ] bi* reduce ] if ; inline
 140
 141 : assoc-collapse! ( assoc seq quot: ( value1 value2 -- new-value ) -- assoc )
 142     [ assoc-merge! ] curry each ; inline
 143
 144 : assoc-collapse-as ( seq quot: ( value1 value2 -- new-value ) exemplar -- assoc )
 145     pick first assoc-size swap new-assoc
 146     -rot assoc-collapse! ; inline
 147
 148 GENERIC: delete-value-at ( value assoc -- )
 149
 150 M: assoc delete-value-at
 151     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
 152
 153 ERROR: key-exists value key assoc ;
 154 : set-once-at ( value key assoc -- )
 155     2dup ?at [
 156         key-exists
 157     ] [
 158         drop set-at
 159     ] if ;
 160
 161 : kv-with ( obj assoc quot -- assoc curried )
 162     swapd [ -rotd call ] 2curry ; inline
 163
 164 <PRIVATE
 165
 166 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 167     [ swap curry compose each ] keep ; inline
 168
 169 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 170     [ swap curry compose each-index ] keep ; inline
 171
 172 PRIVATE>
 173
 174 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 175     roll (sequence>assoc) ; inline
 176
 177 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
 178     clone [ swap curry compose assoc-each ] keep ; inline
 179
 180 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
 181     roll assoc>object ; inline
 182
 183 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 184     clone (sequence>assoc) ; inline
 185
 186 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 187     clone (sequence-index>assoc) ; inline
 188
 189 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 190     H{ } sequence-index>assoc ; inline
 191
 192 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 193     H{ } sequence>assoc ; inline
 194
 195 : ?1array ( obj -- seq ) dup sequence? [ 1array ] unless ; inline
 196
 197 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 198     [
 199         [ swap ?1array ]
 200         [ '[ _ set-at ] with each ]
 201     ] dip assoc>object ;
 202
 203 : expand-keys-set-at ( assoc -- hashtable' )
 204     H{ } expand-keys-set-at-as ;
 205
 206 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 207     [
 208         [ swap ?1array ]
 209         [ push-at-each ]
 210     ] dip assoc>object ;
 211
 212 : expand-keys-push-at ( assoc -- hashtable' )
 213     H{ } expand-keys-push-at-as ; inline
 214
 215 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 216     [
 217         [ [ ?1array ] dip ]
 218         [ '[ _ 2array _ push ] each ]
 219     ] dip assoc>object ;
 220
 221 : expand-keys-push ( assoc -- hashtable' )
 222     V{ } expand-keys-push-as ; inline
 223
 224 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 225     [
 226         [ ?1array swap ]
 227         [ '[ _ _ set-at ] each ]
 228     ] dip assoc>object ;
 229
 230 : expand-values-set-at ( assoc -- hashtable' )
 231     H{ } expand-values-set-at-as ; inline
 232
 233 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 234     [
 235         [ ?1array swap ]
 236         [ '[ _ _ push-at ] each ]
 237     ] dip assoc>object ;
 238
 239 : expand-values-push-at ( assoc -- assoc )
 240     H{ } expand-values-push-at-as ; inline
 241
 242 : expand-values-push-as ( assoc exemplar -- assoc )
 243     [
 244         [ ?1array ]
 245         [ '[ 2array _ push ] with each ]
 246     ] dip assoc>object ;
 247
 248 : expand-values-push ( assoc -- sequence )
 249     V{ } expand-values-push-as ; inline
 250
 251 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 252     [ drop ] prepose assoc-find 2nip ; inline
 253
 254 : assoc-any-value? ( ... assoc quot: ( ... value -- ... ? ) -- ... ? )
 255     [ nip ] prepose assoc-find 2nip ; inline
 256
 257 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 258     [ not ] compose assoc-any-key? not ; inline
 259
 260 : assoc-all-value? ( ... assoc quot: ( ... value -- ... ? ) -- ... ? )
 261     [ not ] compose assoc-any-value? not ; inline
 262
 263 : any-multi-key? ( assoc -- ? )
 264     [ sequence? ] assoc-any-key? ;
 265
 266 : any-multi-value? ( assoc -- ? )
 267     [ sequence? ] assoc-any-value? ;
 268
 269 : flatten-keys ( assoc -- assoc' )
 270     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 271
 272 : flatten-values ( assoc -- assoc' )
 273     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 274
 275 : intersect-keys-as ( assoc seq exemplar -- elts )
 276   [ [ of ] with ] dip zip-with-as sift-values ; inline
 277
 278 : intersect-keys ( assoc seq -- elts )
 279     over intersect-keys-as ; inline
 280
 281 : values-of ( assoc seq -- seq' )
 282     [ of ] with map ; inline
 283
 284 : counts ( seq elts -- counts )
 285     [ histogram ] dip intersect-keys ;
 286
 287 : histogram-diff ( hashtable1 hashtable2 -- hashtable3 )
 288     [ neg swap pick at+ ] assoc-each
 289     [ 0 > ] filter-values ;
 290
 291 : collect-by-multi! ( ... assoc seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 292     [ keep swap ] curry rot [
 293         [ push-at-each ] curry compose each
 294     ] keep ; inline
 295
 296 : collect-by-multi ( ... seq quot: ( ... obj -- ... new-keys ) -- ... assoc )
 297     [ H{ } clone ] 2dip collect-by-multi! ; inline
 298
 299
 300 : collect-assoc-by! ( ... assoc input-assoc quot: ( ... key value -- ... key' value' ) -- ... assoc )
 301     rot [ '[ @ swap _ push-at ] assoc-each ] keep ; inline
 302
 303 : collect-assoc-by ( ... input-assoc quot: ( ... key value -- ... key value ) -- ... assoc )
 304     [ H{ } clone ] 2dip collect-assoc-by! ; inline
 305
 306 : collect-key-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 307     '[ _ keepd ] collect-assoc-by! ; inline
 308
 309 : collect-key-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 310     [ H{ } clone ] 2dip collect-key-by! ; inline
 311
 312 : collect-value-by! ( ... assoc input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 313     '[ _ keep ] collect-assoc-by! ; inline
 314
 315 : collect-value-by ( ... input-assoc quot: ( ... key value -- ... new-key ) -- ... assoc )
 316     [ H{ } clone ] 2dip collect-value-by! ; inline
 317
 318
 319 : collect-assoc-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 320     rot [ '[ @ swap _ push-at-each ] assoc-each ] keep ; inline
 321
 322 : collect-assoc-by-multi ( ... assoc quot: ( ... key value -- ... new-keys value' ) -- ... assoc )
 323     [ H{ } clone ] 2dip collect-assoc-by-multi! ; inline
 324
 325
 326 : collect-key-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 327     '[ _ keepd ] collect-assoc-by-multi! ; inline
 328
 329 : collect-key-by-multi ( ... assoc quot: ( ... key -- ... new-keys ) -- ... assoc )
 330     [ H{ } clone ] 2dip collect-key-by-multi! ; inline
 331
 332
 333 : collect-value-by-multi! ( ... assoc input-assoc quot: ( ... key value -- ... new-keys ) -- ... assoc )
 334     '[ _ keep ] collect-assoc-by-multi! ; inline
 335
 336 : collect-value-by-multi ( ... assoc quot: ( ... value -- ... new-keys ) -- ... assoc )
 337     [ H{ } clone ] 2dip collect-value-by-multi! ; inline
 338
 339 : assoc-operator* ( assoc quot -- alist quot' )
 340     [ >alist ] dip [ first2 swap ] prepose ; inline
 341
 342 : assoc-each* ( ... assoc quot: ( ... value key -- ... ) -- ... )
 343     assoc-operator* each ; inline