extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private fry generalizations kernel
   4 math math.statistics sequences sequences.extras sets ;
   5 IN: assocs.extras
   6
   7 : deep-at ( assoc seq -- value/f )
   8     [ of ] each ; inline
   9
  10 : substitute! ( seq assoc -- seq )
  11     substituter map! ;
  12
  13 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  14     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  15
  16 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  17     [ drop ] prepose assoc-reduce ; inline
  18
  19 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  20     [ nip ] prepose assoc-reduce ; inline
  21
  22 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  23
  24 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  25
  26 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
  27     '[ _ dip ] assoc-map ; inline
  28
  29 : map-values ( assoc quot: ( value -- value' ) -- assoc )
  30     '[ swap _ dip swap ] assoc-map ; inline
  31
  32 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
  33     '[ drop @ ] assoc-filter ; inline
  34
  35 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
  36     '[ nip @ ] assoc-filter ; inline
  37
  38 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
  39     '[ drop @ ] assoc-reject ; inline
  40
  41 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
  42     '[ nip @ ] assoc-reject ; inline
  43
  44 : rekey-new-assoc ( assoc keys -- newassoc )
  45     [ tuck of ] with H{ } map>assoc ; inline
  46
  47 : rekey-assoc ( assoc keys -- assoc )
  48     [ dup keys ] dip diff over [ delete-at ] curry each ; inline
  49
  50 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  51     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  52
  53 : assoc-invert-as ( assoc exemplar -- newassoc )
  54     [ swap ] swap assoc-map-as ;
  55
  56 : assoc-invert ( assoc -- newassoc )
  57     dup assoc-invert-as ;
  58
  59 : assoc-collect! ( assoc1 assoc2 -- assoc1 )
  60     over [ push-at ] with-assoc assoc-each ;
  61
  62 : assoc-collect ( assoc1 assoc2 -- newassoc )
  63     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  64     [ assoc-collect! ] bi@ ;
  65
  66 ! iterate over assoc2, replace conflicting values
  67 ! Modifies assoc1
  68 : assoc-merge! ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- assoc1' )
  69     [| key2 val2 quot | val2 key2 pick
  70      at* [ swap quot call ] [ drop ] if
  71      key2 pick set-at ] curry assoc-each ; inline
  72
  73 ! Same as above, non-destructive
  74 : assoc-merge ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- new-assoc )
  75     pick [ [ clone ] 2dip assoc-merge! ]
  76     [ drop nip ] if
  77     ; inline
  78
  79 ! Successively apply assoc-merge operation
  80 : assoc-collapse ( seq quot: ( value1 value2 -- new-value ) -- assoc )
  81     over empty?
  82     [ 2drop f ]
  83     [ [ unclip-slice H{ } or clone ] [ [ assoc-merge! ] curry ] bi* reduce ] if ; inline
  84
  85 GENERIC: delete-value-at ( value assoc -- )
  86
  87 M: assoc delete-value-at
  88     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
  89
  90 ERROR: key-exists value key assoc ;
  91 : set-once-at ( value key assoc -- )
  92     2dup ?at [
  93         key-exists
  94     ] [
  95         drop set-at
  96     ] if ;
  97
  98 : kv-with ( obj assoc quot -- assoc curried )
  99     swapd [ -rotd call ] 2curry ; inline
 100
 101 <PRIVATE
 102
 103 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 104     [ swap curry compose each ] keep ; inline
 105
 106 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 107     [ swap curry compose each-index ] keep ; inline
 108
 109 PRIVATE>
 110
 111 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 112     roll (sequence>assoc) ; inline
 113
 114 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
 115     clone [ swap curry compose assoc-each ] keep ; inline
 116
 117 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
 118     roll assoc>object ; inline
 119
 120 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 121     clone (sequence>assoc) ; inline
 122
 123 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 124     clone (sequence-index>assoc) ; inline
 125
 126 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 127     H{ } sequence-index>assoc ; inline
 128
 129 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 130     H{ } sequence>assoc ; inline
 131
 132 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 133     [
 134         [ swap dup sequence? [ 1array ] unless ]
 135         [ '[ _ set-at ] with each ]
 136     ] dip assoc>object ;
 137
 138 : expand-keys-set-at ( assoc -- hashtable' )
 139     H{ } expand-keys-set-at-as ;
 140
 141 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 142     [
 143         [ swap dup sequence? [ 1array ] unless ]
 144         [ '[ _ push-at ] with each ]
 145     ] dip assoc>object ;
 146
 147 : expand-keys-push-at ( assoc -- hashtable' )
 148     H{ } expand-keys-push-at-as ; inline
 149
 150 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 151     [
 152         [ [ dup sequence? [ 1array ] unless ] dip ]
 153         [ '[ _ 2array _ push ] each ]
 154     ] dip assoc>object ;
 155
 156 : expand-keys-push ( assoc -- hashtable' )
 157     V{ } expand-keys-push-as ; inline
 158
 159 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 160     [
 161         [ dup sequence? [ 1array ] unless swap ]
 162         [ '[ _ _ set-at ] each ]
 163     ] dip assoc>object ;
 164
 165 : expand-values-set-at ( assoc -- hashtable' )
 166     H{ } expand-values-set-at-as ; inline
 167
 168 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 169     [
 170         [ dup sequence? [ 1array ] unless swap ]
 171         [ '[ _ _ push-at ] each ]
 172     ] dip assoc>object ;
 173
 174 : expand-values-push-at ( assoc -- assoc )
 175     H{ } expand-values-push-at-as ; inline
 176
 177 : expand-values-push-as ( assoc exemplar -- assoc )
 178     [
 179         [ dup sequence? [ 1array ] unless ]
 180         [ '[ 2array _ push ] with each ]
 181     ] dip assoc>object ;
 182
 183 : expand-values-push ( assoc -- sequence )
 184     V{ } expand-values-push-as ; inline
 185
 186 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 187     [ drop ] prepose assoc-find 2nip ; inline
 188
 189 : assoc-any-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 190     [ nip ] prepose assoc-find 2nip ; inline
 191
 192 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 193     [ not ] compose assoc-any-key? not  ; inline
 194
 195 : assoc-all-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 196     [ not ] compose assoc-any-value? not  ; inline
 197
 198 : any-multi-key? ( assoc -- ? )
 199     [ sequence? ] assoc-any-key? ;
 200
 201 : any-multi-value? ( assoc -- ? )
 202     [ sequence? ] assoc-any-value? ;
 203
 204 : flatten-keys ( assoc -- assoc' )
 205     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 206
 207 : flatten-values ( assoc -- assoc' )
 208     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 209
 210 : intersect-keys ( assoc seq -- elts )
 211     [ of ] with zip-with sift-values ; inline
 212
 213 : values-of ( assoc seq -- elts )
 214     [ of ] with map sift ; inline
 215
 216 : counts ( seq elts -- counts )
 217     [ histogram ] dip intersect-keys ;