extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: arrays assocs assocs.private kernel math sequences ;
   5
   6 IN: assocs.extras
   7
   8 : deep-at ( assoc seq -- value/f )
   9     [ of ] each ; inline
  10
  11 : substitute! ( seq assoc -- seq )
  12     substituter map! ;
  13
  14 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  15     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  16
  17 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  18     [ drop ] prepose assoc-reduce ; inline
  19
  20 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  21     [ nip ] prepose assoc-reduce ; inline
  22
  23 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  24
  25 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  26
  27 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  28     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  29
  30 : assoc-invert-as ( assoc exemplar -- newassoc )
  31     [ swap ] swap assoc-map-as ;
  32
  33 : assoc-invert ( assoc -- newassoc )
  34     dup assoc-invert-as ;
  35
  36 : assoc-merge! ( assoc1 assoc2 -- assoc1 )
  37     over [ push-at ] with-assoc assoc-each ;
  38
  39 : assoc-merge ( assoc1 assoc2 -- newassoc )
  40     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  41     [ assoc-merge! ] bi@ ;
  42
  43 GENERIC: delete-value-at ( value assoc -- )
  44
  45 M: assoc delete-value-at
  46     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;