extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private fry generalizations kernel
   4 math math.statistics sequences sequences.extras sets ;
   5 IN: assocs.extras
   6
   7 : deep-at ( assoc seq -- value/f )
   8     [ of ] each ; inline
   9
  10 : substitute! ( seq assoc -- seq )
  11     substituter map! ;
  12
  13 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  14     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  15
  16 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  17     [ drop ] prepose assoc-reduce ; inline
  18
  19 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  20     [ nip ] prepose assoc-reduce ; inline
  21
  22 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  23
  24 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  25
  26 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
  27     '[ _ dip ] assoc-map ; inline
  28
  29 : map-values ( assoc quot: ( value -- value' ) -- assoc )
  30     '[ swap _ dip swap ] assoc-map ; inline
  31
  32 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
  33     '[ drop @ ] assoc-filter ; inline
  34
  35 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
  36     '[ nip @ ] assoc-filter ; inline
  37
  38 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
  39     '[ drop @ ] assoc-reject ; inline
  40
  41 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
  42     '[ nip @ ] assoc-reject ; inline
  43
  44 : rekey-new-assoc ( assoc keys -- newassoc )
  45     [ tuck of ] with H{ } map>assoc ; inline
  46
  47 : rekey-assoc ( assoc keys -- assoc )
  48     [ dup keys ] dip diff over [ delete-at ] curry each ; inline
  49
  50 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  51     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  52
  53 : assoc-invert-as ( assoc exemplar -- newassoc )
  54     [ swap ] swap assoc-map-as ;
  55
  56 : assoc-invert ( assoc -- newassoc )
  57     dup assoc-invert-as ;
  58
  59 : assoc-merge! ( assoc1 assoc2 -- assoc1 )
  60     over [ push-at ] with-assoc assoc-each ;
  61
  62 : assoc-merge ( assoc1 assoc2 -- newassoc )
  63     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  64     [ assoc-merge! ] bi@ ;
  65
  66 GENERIC: delete-value-at ( value assoc -- )
  67
  68 M: assoc delete-value-at
  69     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
  70
  71 ERROR: key-exists value key assoc ;
  72 : set-once-at ( value key assoc -- )
  73     2dup ?at [
  74         key-exists
  75     ] [
  76         drop set-at
  77     ] if ;
  78
  79 : kv-with ( obj assoc quot -- assoc curried )
  80     swapd [ -rotd call ] 2curry ; inline
  81
  82 <PRIVATE
  83
  84 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
  85     [ swap curry compose each ] keep ; inline
  86
  87 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
  88     [ swap curry compose each-index ] keep ; inline
  89
  90 PRIVATE>
  91
  92 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
  93     roll (sequence>assoc) ; inline
  94
  95 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
  96     clone [ swap curry compose assoc-each ] keep ; inline
  97
  98 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
  99     roll assoc>object ; inline
 100
 101 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 102     clone (sequence>assoc) ; inline
 103
 104 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 105     clone (sequence-index>assoc) ; inline
 106
 107 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 108     H{ } sequence-index>assoc ; inline
 109
 110 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 111     H{ } sequence>assoc ; inline
 112
 113 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 114     [
 115         [ swap dup sequence? [ 1array ] unless ]
 116         [ '[ _ set-at ] with each ]
 117     ] dip assoc>object ;
 118
 119 : expand-keys-set-at ( assoc -- hashtable' )
 120     H{ } expand-keys-set-at-as ;
 121
 122 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 123     [
 124         [ swap dup sequence? [ 1array ] unless ]
 125         [ '[ _ push-at ] with each ]
 126     ] dip assoc>object ;
 127
 128 : expand-keys-push-at ( assoc -- hashtable' )
 129     H{ } expand-keys-push-at-as ; inline
 130
 131 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 132     [
 133         [ [ dup sequence? [ 1array ] unless ] dip ]
 134         [ '[ _ 2array _ push ] each ]
 135     ] dip assoc>object ;
 136
 137 : expand-keys-push ( assoc -- hashtable' )
 138     V{ } expand-keys-push-as ; inline
 139
 140 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 141     [
 142         [ dup sequence? [ 1array ] unless swap ]
 143         [ '[ _ _ set-at ] each ]
 144     ] dip assoc>object ;
 145
 146 : expand-values-set-at ( assoc -- hashtable' )
 147     H{ } expand-values-set-at-as ; inline
 148
 149 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 150     [
 151         [ dup sequence? [ 1array ] unless swap ]
 152         [ '[ _ _ push-at ] each ]
 153     ] dip assoc>object ;
 154
 155 : expand-values-push-at ( assoc -- assoc )
 156     H{ } expand-values-push-at-as ; inline
 157
 158 : expand-values-push-as ( assoc exemplar -- assoc )
 159     [
 160         [ dup sequence? [ 1array ] unless ]
 161         [ '[ 2array _ push ] with each ]
 162     ] dip assoc>object ;
 163
 164 : expand-values-push ( assoc -- sequence )
 165     V{ } expand-values-push-as ; inline
 166
 167 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 168     [ drop ] prepose assoc-find 2nip ; inline
 169
 170 : assoc-any-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 171     [ nip ] prepose assoc-find 2nip ; inline
 172
 173 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 174     [ not ] compose assoc-any-key? not  ; inline
 175
 176 : assoc-all-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 177     [ not ] compose assoc-any-value? not  ; inline
 178
 179 : any-multi-key? ( assoc -- ? )
 180     [ sequence? ] assoc-any-key? ;
 181
 182 : any-multi-value? ( assoc -- ? )
 183     [ sequence? ] assoc-any-value? ;
 184
 185 : flatten-keys ( assoc -- assoc' )
 186     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 187
 188 : flatten-values ( assoc -- assoc' )
 189     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 190
 191 : intersect-keys ( assoc seq -- elts )
 192     [ of ] with map-zip sift-values ; inline
 193
 194 : values-of ( assoc seq -- elts )
 195     [ of ] with map sift ; inline
 196
 197 : counts ( seq elts -- counts )
 198     [ histogram ] dip intersect-keys ;