extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private fry generalizations kernel
   4 math math.statistics sequences sequences.extras ;
   5 IN: assocs.extras
   6
   7 : deep-at ( assoc seq -- value/f )
   8     [ of ] each ; inline
   9
  10 : substitute! ( seq assoc -- seq )
  11     substituter map! ;
  12
  13 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  14     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  15
  16 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  17     [ drop ] prepose assoc-reduce ; inline
  18
  19 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  20     [ nip ] prepose assoc-reduce ; inline
  21
  22 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  23
  24 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  25
  26 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
  27     '[ _ dip ] assoc-map ; inline
  28
  29 : map-values ( assoc quot: ( value -- value' ) -- assoc )
  30     '[ swap _ dip swap ] assoc-map ; inline
  31
  32 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
  33     '[ drop @ ] assoc-filter ; inline
  34
  35 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
  36     '[ nip @ ] assoc-filter ; inline
  37
  38 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
  39     '[ drop @ ] assoc-reject ; inline
  40
  41 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
  42     '[ nip @ ] assoc-reject ; inline
  43
  44 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  45     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  46
  47 : assoc-invert-as ( assoc exemplar -- newassoc )
  48     [ swap ] swap assoc-map-as ;
  49
  50 : assoc-invert ( assoc -- newassoc )
  51     dup assoc-invert-as ;
  52
  53 : assoc-merge! ( assoc1 assoc2 -- assoc1 )
  54     over [ push-at ] with-assoc assoc-each ;
  55
  56 : assoc-merge ( assoc1 assoc2 -- newassoc )
  57     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  58     [ assoc-merge! ] bi@ ;
  59
  60 GENERIC: delete-value-at ( value assoc -- )
  61
  62 M: assoc delete-value-at
  63     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
  64
  65 ERROR: key-exists value key assoc ;
  66 : set-once-at ( value key assoc -- )
  67     2dup ?at [
  68         key-exists
  69     ] [
  70         drop set-at
  71     ] if ;
  72
  73 : kv-with ( obj assoc quot -- assoc curried )
  74     swapd [ -rotd call ] 2curry ; inline
  75
  76 <PRIVATE
  77
  78 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
  79     [ swap curry compose each ] keep ; inline
  80
  81 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
  82     [ swap curry compose each-index ] keep ; inline
  83
  84 PRIVATE>
  85
  86 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
  87     roll (sequence>assoc) ; inline
  88
  89 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
  90     clone [ swap curry compose assoc-each ] keep ; inline
  91
  92 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
  93     roll assoc>object ; inline
  94
  95 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
  96     clone (sequence>assoc) ; inline
  97
  98 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
  99     clone (sequence-index>assoc) ; inline
 100
 101 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 102     H{ } sequence-index>assoc ; inline
 103
 104 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 105     H{ } sequence>assoc ; inline
 106
 107 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 108     [
 109         [ swap dup sequence? [ 1array ] unless ]
 110         [ '[ _ set-at ] with each ]
 111     ] dip assoc>object ;
 112
 113 : expand-keys-set-at ( assoc -- hashtable' )
 114     H{ } expand-keys-set-at-as ;
 115
 116 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 117     [
 118         [ swap dup sequence? [ 1array ] unless ]
 119         [ '[ _ push-at ] with each ]
 120     ] dip assoc>object ;
 121
 122 : expand-keys-push-at ( assoc -- hashtable' )
 123     H{ } expand-keys-push-at-as ; inline
 124
 125 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 126     [
 127         [ [ dup sequence? [ 1array ] unless ] dip ]
 128         [ '[ _ 2array _ push ] each ]
 129     ] dip assoc>object ;
 130
 131 : expand-keys-push ( assoc -- hashtable' )
 132     V{ } expand-keys-push-as ; inline
 133
 134 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 135     [
 136         [ dup sequence? [ 1array ] unless swap ]
 137         [ '[ _ _ set-at ] each ]
 138     ] dip assoc>object ;
 139
 140 : expand-values-set-at ( assoc -- hashtable' )
 141     H{ } expand-values-set-at-as ; inline
 142
 143 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 144     [
 145         [ dup sequence? [ 1array ] unless swap ]
 146         [ '[ _ _ push-at ] each ]
 147     ] dip assoc>object ;
 148
 149 : expand-values-push-at ( assoc -- assoc )
 150     H{ } expand-values-push-at-as ; inline
 151
 152 : expand-values-push-as ( assoc exemplar -- assoc )
 153     [
 154         [ dup sequence? [ 1array ] unless ]
 155         [ '[ 2array _ push ] with each ]
 156     ] dip assoc>object ;
 157
 158 : expand-values-push ( assoc -- sequence )
 159     V{ } expand-values-push-as ; inline
 160
 161 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 162     [ drop ] prepose assoc-find 2nip ; inline
 163
 164 : assoc-any-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 165     [ nip ] prepose assoc-find 2nip ; inline
 166
 167 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 168     [ not ] compose assoc-any-key? not  ; inline
 169
 170 : assoc-all-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 171     [ not ] compose assoc-any-value? not  ; inline
 172
 173 : any-multi-key? ( assoc -- ? )
 174     [ sequence? ] assoc-any-key? ;
 175
 176 : any-multi-value? ( assoc -- ? )
 177     [ sequence? ] assoc-any-value? ;
 178
 179 : flatten-keys ( assoc -- assoc' )
 180     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 181
 182 : flatten-values ( assoc -- assoc' )
 183     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 184
 185 : intersect-keys ( assoc seq -- elts )
 186     [ of ] with map-zip sift-values ; inline
 187
 188 : values-of ( assoc seq -- elts )
 189     [ of ] with map sift ; inline
 190
 191 : counts ( seq elts -- counts )
 192     [ histogram ] dip intersect-keys ;