extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private fry generalizations kernel
   4 math sequences ;
   5 IN: assocs.extras
   6
   7 : deep-at ( assoc seq -- value/f )
   8     [ of ] each ; inline
   9
  10 : substitute! ( seq assoc -- seq )
  11     substituter map! ;
  12
  13 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  14     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  15
  16 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  17     [ drop ] prepose assoc-reduce ; inline
  18
  19 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  20     [ nip ] prepose assoc-reduce ; inline
  21
  22 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  23
  24 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  25
  26 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  27     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  28
  29 : assoc-invert-as ( assoc exemplar -- newassoc )
  30     [ swap ] swap assoc-map-as ;
  31
  32 : assoc-invert ( assoc -- newassoc )
  33     dup assoc-invert-as ;
  34
  35 : assoc-merge! ( assoc1 assoc2 -- assoc1 )
  36     over [ push-at ] with-assoc assoc-each ;
  37
  38 : assoc-merge ( assoc1 assoc2 -- newassoc )
  39     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  40     [ assoc-merge! ] bi@ ;
  41
  42 GENERIC: delete-value-at ( value assoc -- )
  43
  44 M: assoc delete-value-at
  45     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
  46
  47 ERROR: key-exists value key assoc ;
  48 : set-once-at ( value key assoc -- )
  49     2dup ?at [
  50         key-exists
  51     ] [
  52         drop set-at
  53     ] if ;
  54
  55 : kv-with ( obj assoc quot -- assoc curried )
  56     swapd [ -rotd call ] 2curry ; inline
  57
  58 <PRIVATE
  59
  60 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
  61     [ swap curry compose each ] keep ; inline
  62
  63 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
  64     [ swap curry compose each-index ] keep ; inline
  65
  66 PRIVATE>
  67
  68 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
  69     roll (sequence>assoc) ; inline
  70
  71 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
  72     clone [ swap curry compose assoc-each ] keep ; inline
  73
  74 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
  75     roll assoc>object ; inline
  76
  77 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
  78     clone (sequence>assoc) ; inline
  79
  80 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
  81     clone (sequence-index>assoc) ; inline
  82
  83 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
  84     H{ } sequence-index>assoc ; inline
  85
  86 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
  87     H{ } sequence>assoc ; inline
  88
  89 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
  90     [
  91         [ swap dup sequence? [ 1array ] unless ]
  92         [ '[ _ set-at ] with each ]
  93     ] dip assoc>object ;
  94
  95 : expand-keys-set-at ( assoc -- hashtable' )
  96     H{ } expand-keys-set-at-as ;
  97
  98 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
  99     [
 100         [ swap dup sequence? [ 1array ] unless ]
 101         [ '[ _ push-at ] with each ]
 102     ] dip assoc>object ;
 103
 104 : expand-keys-push-at ( assoc -- hashtable' )
 105     H{ } expand-keys-push-at-as ; inline
 106
 107 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 108     [
 109         [ [ dup sequence? [ 1array ] unless ] dip ]
 110         [ '[ _ 2array _ push ] each ]
 111     ] dip assoc>object ;
 112
 113 : expand-keys-push ( assoc -- hashtable' )
 114     V{ } expand-keys-push-as ; inline
 115
 116 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 117     [
 118         [ dup sequence? [ 1array ] unless swap ]
 119         [ '[ _ _ set-at ] each ]
 120     ] dip assoc>object ;
 121
 122 : expand-values-set-at ( assoc -- hashtable' )
 123     H{ } expand-values-set-at-as ; inline
 124
 125 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 126     [
 127         [ dup sequence? [ 1array ] unless swap ]
 128         [ '[ _ _ push-at ] each ]
 129     ] dip assoc>object ;
 130
 131 : expand-values-push-at ( assoc -- assoc )
 132     H{ } expand-values-push-at-as ; inline
 133
 134 : expand-values-push-as ( assoc exemplar -- assoc )
 135     [
 136         [ dup sequence? [ 1array ] unless ]
 137         [ '[ 2array _ push ] with each ]
 138     ] dip assoc>object ;
 139
 140 : expand-values-push ( assoc -- sequence )
 141     V{ } expand-values-push-as ; inline
 142
 143 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 144     [ drop ] prepose assoc-find 2nip ; inline
 145
 146 : assoc-any-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 147     [ nip ] prepose assoc-find 2nip ; inline
 148
 149 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 150     [ not ] compose assoc-any-key? not  ; inline
 151
 152 : assoc-all-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 153     [ not ] compose assoc-any-value? not  ; inline
 154
 155 : any-multi-key? ( assoc -- ? )
 156     [ sequence? ] assoc-any-key? ;
 157
 158 : any-multi-value? ( assoc -- ? )
 159     [ sequence? ] assoc-any-value? ;
 160
 161 : flatten-keys ( assoc -- assoc' )
 162     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 163
 164 : flatten-values ( assoc -- assoc' )
 165     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;