extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private generalizations kernel math
   4 sequences ;
   5 IN: assocs.extras
   6
   7 : deep-at ( assoc seq -- value/f )
   8     [ of ] each ; inline
   9
  10 : substitute! ( seq assoc -- seq )
  11     substituter map! ;
  12
  13 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  14     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  15
  16 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  17     [ drop ] prepose assoc-reduce ; inline
  18
  19 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  20     [ nip ] prepose assoc-reduce ; inline
  21
  22 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  23
  24 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  25
  26 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  27     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  28
  29 : assoc-invert-as ( assoc exemplar -- newassoc )
  30     [ swap ] swap assoc-map-as ;
  31
  32 : assoc-invert ( assoc -- newassoc )
  33     dup assoc-invert-as ;
  34
  35 : assoc-merge! ( assoc1 assoc2 -- assoc1 )
  36     over [ push-at ] with-assoc assoc-each ;
  37
  38 : assoc-merge ( assoc1 assoc2 -- newassoc )
  39     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  40     [ assoc-merge! ] bi@ ;
  41
  42 GENERIC: delete-value-at ( value assoc -- )
  43
  44 M: assoc delete-value-at
  45     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
  46
  47 ERROR: key-exists value key assoc ;
  48 : set-once-at ( value key assoc -- )
  49     2dup ?at [
  50         key-exists
  51     ] [
  52         drop set-at
  53     ] if ;
  54
  55 <PRIVATE
  56
  57 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
  58     [ swap curry compose each ] keep ; inline
  59
  60 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
  61     [ swap curry compose each-index ] keep ; inline
  62
  63 PRIVATE>
  64
  65 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
  66     4 nrot (sequence>assoc) ; inline
  67
  68 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
  69     clone (sequence>assoc) ; inline
  70
  71 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
  72     clone (sequence-index>assoc) ; inline
  73
  74 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
  75     H{ } sequence-index>assoc ; inline
  76
  77 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
  78     H{ } sequence>assoc ; inline
  79