extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private kernel math math.statistics
   4 sequences sets ;
   5 IN: assocs.extras
   6
   7 : deep-at ( assoc seq -- value/f )
   8     [ of ] each ; inline
   9
  10 : substitute! ( seq assoc -- seq )
  11     substituter map! ;
  12
  13 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  14     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  15
  16 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  17     [ drop ] prepose assoc-reduce ; inline
  18
  19 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  20     [ nip ] prepose assoc-reduce ; inline
  21
  22 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  23
  24 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  25
  26 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
  27     '[ _ dip ] assoc-map ; inline
  28
  29 : map-values ( assoc quot: ( value -- value' ) -- assoc )
  30     '[ swap _ dip swap ] assoc-map ; inline
  31
  32 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
  33     '[ drop @ ] assoc-filter ; inline
  34
  35 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
  36     '[ nip @ ] assoc-filter ; inline
  37
  38 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
  39     '[ drop @ ] assoc-reject ; inline
  40
  41 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
  42     '[ nip @ ] assoc-reject ; inline
  43
  44 : rekey-new-assoc ( assoc keys -- newassoc )
  45     [ tuck of ] with H{ } map>assoc ; inline
  46
  47 : rekey-assoc ( assoc keys -- assoc )
  48     [ dup keys ] dip diff over [ delete-at ] curry each ; inline
  49
  50 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  51     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  52
  53 : assoc-invert-as ( assoc exemplar -- newassoc )
  54     [ swap ] swap assoc-map-as ;
  55
  56 : assoc-invert ( assoc -- newassoc )
  57     dup assoc-invert-as ;
  58
  59 : assoc-collect! ( assoc1 assoc2 -- assoc1 )
  60     over [ push-at ] with-assoc assoc-each ;
  61
  62 : assoc-collect ( assoc1 assoc2 -- newassoc )
  63     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  64     [ assoc-collect! ] bi@ ;
  65
  66 ! iterate over assoc2, replace conflicting values
  67 ! Modifies assoc1
  68 : assoc-merge! ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- assoc1' )
  69     [| key2 val2 quot | val2 key2 pick
  70      at* [ swap quot call ] [ drop ] if
  71      key2 pick set-at ] curry assoc-each ; inline
  72
  73 ! Same as above, non-destructive
  74 : assoc-merge ( assoc1 assoc2 quot: ( value1 value2 -- new-value ) -- new-assoc )
  75     pick [ [ clone ] 2dip assoc-merge! ]
  76     [ drop nip ] if
  77     ; inline
  78
  79 ! Successively apply assoc-merge operation
  80 : assoc-collapse ( seq quot: ( value1 value2 -- new-value ) -- assoc )
  81     over empty?
  82     [ 2drop f ]
  83     [ [ unclip-slice H{ } or clone ] [ [ assoc-merge! ] curry ] bi* reduce ] if ; inline
  84
  85 : assoc-collapse! ( assoc seq quot: ( value1 value2 -- new-value ) -- assoc )
  86     [ assoc-merge! ] curry each ; inline
  87
  88 : assoc-collapse-as ( seq quot: ( value1 value2 -- new-value ) exemplar -- assoc )
  89     pick first assoc-size swap new-assoc
  90     -rot assoc-collapse! ; inline
  91
  92 GENERIC: delete-value-at ( value assoc -- )
  93
  94 M: assoc delete-value-at
  95     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
  96
  97 ERROR: key-exists value key assoc ;
  98 : set-once-at ( value key assoc -- )
  99     2dup ?at [
 100         key-exists
 101     ] [
 102         drop set-at
 103     ] if ;
 104
 105 : kv-with ( obj assoc quot -- assoc curried )
 106     swapd [ -rotd call ] 2curry ; inline
 107
 108 <PRIVATE
 109
 110 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
 111     [ swap curry compose each ] keep ; inline
 112
 113 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
 114     [ swap curry compose each-index ] keep ; inline
 115
 116 PRIVATE>
 117
 118 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
 119     roll (sequence>assoc) ; inline
 120
 121 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
 122     clone [ swap curry compose assoc-each ] keep ; inline
 123
 124 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
 125     roll assoc>object ; inline
 126
 127 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
 128     clone (sequence>assoc) ; inline
 129
 130 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
 131     clone (sequence-index>assoc) ; inline
 132
 133 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
 134     H{ } sequence-index>assoc ; inline
 135
 136 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
 137     H{ } sequence>assoc ; inline
 138
 139 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
 140     [
 141         [ swap dup sequence? [ 1array ] unless ]
 142         [ '[ _ set-at ] with each ]
 143     ] dip assoc>object ;
 144
 145 : expand-keys-set-at ( assoc -- hashtable' )
 146     H{ } expand-keys-set-at-as ;
 147
 148 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
 149     [
 150         [ swap dup sequence? [ 1array ] unless ]
 151         [ '[ _ push-at ] with each ]
 152     ] dip assoc>object ;
 153
 154 : expand-keys-push-at ( assoc -- hashtable' )
 155     H{ } expand-keys-push-at-as ; inline
 156
 157 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 158     [
 159         [ [ dup sequence? [ 1array ] unless ] dip ]
 160         [ '[ _ 2array _ push ] each ]
 161     ] dip assoc>object ;
 162
 163 : expand-keys-push ( assoc -- hashtable' )
 164     V{ } expand-keys-push-as ; inline
 165
 166 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 167     [
 168         [ dup sequence? [ 1array ] unless swap ]
 169         [ '[ _ _ set-at ] each ]
 170     ] dip assoc>object ;
 171
 172 : expand-values-set-at ( assoc -- hashtable' )
 173     H{ } expand-values-set-at-as ; inline
 174
 175 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 176     [
 177         [ dup sequence? [ 1array ] unless swap ]
 178         [ '[ _ _ push-at ] each ]
 179     ] dip assoc>object ;
 180
 181 : expand-values-push-at ( assoc -- assoc )
 182     H{ } expand-values-push-at-as ; inline
 183
 184 : expand-values-push-as ( assoc exemplar -- assoc )
 185     [
 186         [ dup sequence? [ 1array ] unless ]
 187         [ '[ 2array _ push ] with each ]
 188     ] dip assoc>object ;
 189
 190 : expand-values-push ( assoc -- sequence )
 191     V{ } expand-values-push-as ; inline
 192
 193 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 194     [ drop ] prepose assoc-find 2nip ; inline
 195
 196 : assoc-any-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 197     [ nip ] prepose assoc-find 2nip ; inline
 198
 199 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 200     [ not ] compose assoc-any-key? not  ; inline
 201
 202 : assoc-all-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 203     [ not ] compose assoc-any-value? not  ; inline
 204
 205 : any-multi-key? ( assoc -- ? )
 206     [ sequence? ] assoc-any-key? ;
 207
 208 : any-multi-value? ( assoc -- ? )
 209     [ sequence? ] assoc-any-value? ;
 210
 211 : flatten-keys ( assoc -- assoc' )
 212     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 213
 214 : flatten-values ( assoc -- assoc' )
 215     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;
 216
 217 : intersect-keys ( assoc seq -- elts )
 218     [ of ] with zip-with sift-values ; inline
 219
 220 : values-of ( assoc seq -- seq' )
 221     [ of ] with map ; inline
 222
 223 : counts ( seq elts -- counts )
 224     [ histogram ] dip intersect-keys ;
 225
 226 : collect-key-by ( ... seq quot: ( ... obj -- ... key ) -- ... assoc )
 227     [ keep swap ] curry H{ } clone
 228     [ '[ @ [ first ] dip _ push-at ] each ] keep ; inline
 229
 230 : collect-value-by ( ... seq quot: ( ... obj -- ... key ) -- ... assoc )
 231     [ keep swap ] curry H{ } clone
 232     [ '[ @ [ second ] dip _ push-at ] each ] keep ; inline
 233
 234 : histogram-diff ( hashtable1 hashtable2 -- hashtable3 )
 235     [ neg swap pick at+ ] assoc-each
 236     [ 0 > ] filter-values ;
 237
 238 : push-at-each ( value keys assoc -- )
 239     '[ _ push-at ] with each ; inline
 240
 241 : collect-by-multi! ( ... assoc seq quot: ( ... obj -- ... key ) -- ... assoc )
 242     [ keep swap ] curry rot [
 243         [ push-at-each ] curry compose each
 244     ] keep ; inline
 245
 246 : collect-by-multi ( ... seq quot: ( ... obj -- ... keys ) -- ... assoc )
 247     [ H{ } clone ] 2dip collect-by-multi! ; inline