extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: arrays assocs assocs.private kernel math sequences ;
   5
   6 IN: assocs.extras
   7
   8 : assoc-sift ( assoc -- assoc' )
   9     [ nip ] assoc-filter ; inline
  10
  11 : assoc-harvest ( assoc -- assoc' )
  12     [ nip empty? not ] assoc-filter ; inline
  13
  14 : deep-at ( assoc seq -- value/f )
  15     [ of ] each ; inline
  16
  17 : zip-as ( keys values exemplar -- assoc )
  18     dup sequence? [
  19         [ 2array ] swap 2map-as
  20     ] [
  21         [ 2dup min-length ] dip new-assoc
  22         [ [ set-at ] with-assoc 2each ] keep
  23     ] if ; inline
  24
  25 : substitute! ( seq assoc -- seq )
  26     substituter map! ;
  27
  28 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  29     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  30
  31 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  32     [ drop ] prepose assoc-reduce ; inline
  33
  34 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  35     [ nip ] prepose assoc-reduce ; inline
  36
  37 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  38
  39 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  40
  41 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  42     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  43
  44 : assoc-invert-as ( assoc exemplar -- newassoc )
  45     [ swap ] swap assoc-map-as ;
  46
  47 : assoc-invert ( assoc -- newassoc )
  48     dup assoc-invert-as ;
  49
  50 : (assoc-merge) ( assoc1 assoc2 -- assoc1 )
  51     over [ push-at ] with-assoc assoc-each ;
  52
  53 : assoc-merge ( seq -- merge )
  54     H{ } clone [ (assoc-merge) ] reduce ;
  55
  56 GENERIC: delete-value-at ( value assoc -- )
  57
  58 M: assoc delete-value-at
  59     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;