extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: arrays assocs assocs.private kernel math sequences ;
   5
   6 IN: assocs.extras
   7
   8 : assoc-harvest ( assoc -- assoc' )
   9     [ nip empty? not ] assoc-filter ; inline
  10
  11 : deep-at ( assoc seq -- value/f )
  12     [ of ] each ; inline
  13
  14 : zip-as ( keys values exemplar -- assoc )
  15     dup sequence? [
  16         [ 2array ] swap 2map-as
  17     ] [
  18         [ 2dup min-length ] dip new-assoc
  19         [ [ set-at ] with-assoc 2each ] keep
  20     ] if ; inline
  21
  22 : substitute! ( seq assoc -- seq )
  23     substituter map! ;
  24
  25 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  26     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  27
  28 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  29     [ drop ] prepose assoc-reduce ; inline
  30
  31 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  32     [ nip ] prepose assoc-reduce ; inline
  33
  34 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  35
  36 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  37
  38 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  39     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  40
  41 : assoc-invert-as ( assoc exemplar -- newassoc )
  42     [ swap ] swap assoc-map-as ;
  43
  44 : assoc-invert ( assoc -- newassoc )
  45     dup assoc-invert-as ;
  46
  47 : (assoc-merge) ( assoc1 assoc2 -- assoc1 )
  48     over [ push-at ] with-assoc assoc-each ;
  49
  50 : assoc-merge ( seq -- merge )
  51     H{ } clone [ (assoc-merge) ] reduce ;