extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: arrays assocs assocs.private fry generalizations kernel
   4 math sequences ;
   5 IN: assocs.extras
   6
   7 : deep-at ( assoc seq -- value/f )
   8     [ of ] each ; inline
   9
  10 : substitute! ( seq assoc -- seq )
  11     substituter map! ;
  12
  13 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  14     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  15
  16 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  17     [ drop ] prepose assoc-reduce ; inline
  18
  19 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  20     [ nip ] prepose assoc-reduce ; inline
  21
  22 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  23
  24 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  25
  26 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  27     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  28
  29 : assoc-invert-as ( assoc exemplar -- newassoc )
  30     [ swap ] swap assoc-map-as ;
  31
  32 : assoc-invert ( assoc -- newassoc )
  33     dup assoc-invert-as ;
  34
  35 : assoc-merge! ( assoc1 assoc2 -- assoc1 )
  36     over [ push-at ] with-assoc assoc-each ;
  37
  38 : assoc-merge ( assoc1 assoc2 -- newassoc )
  39     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  40     [ assoc-merge! ] bi@ ;
  41
  42 GENERIC: delete-value-at ( value assoc -- )
  43
  44 M: assoc delete-value-at
  45     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;
  46
  47 ERROR: key-exists value key assoc ;
  48 : set-once-at ( value key assoc -- )
  49     2dup ?at [
  50         key-exists
  51     ] [
  52         drop set-at
  53     ] if ;
  54
  55 <PRIVATE
  56
  57 : (sequence>assoc) ( seq map-quot insert-quot assoc -- assoc )
  58     [ swap curry compose each ] keep ; inline
  59
  60 : (sequence-index>assoc) ( seq map-quot insert-quot assoc -- assoc )
  61     [ swap curry compose each-index ] keep ; inline
  62
  63 PRIVATE>
  64
  65 : sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
  66     4 nrot (sequence>assoc) ; inline
  67
  68 : assoc>object ( assoc map-quot insert-quot exemplar -- object )
  69     clone [ swap curry compose assoc-each ] keep ; inline
  70
  71 : assoc>object! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- object )
  72     4 nrot assoc>object ; inline
  73
  74 : sequence>assoc ( seq map-quot insert-quot exemplar -- assoc )
  75     clone (sequence>assoc) ; inline
  76
  77 : sequence-index>assoc ( seq map-quot insert-quot exemplar -- assoc )
  78     clone (sequence-index>assoc) ; inline
  79
  80 : sequence-index>hashtable ( seq map-quot insert-quot -- hashtable )
  81     H{ } sequence-index>assoc ; inline
  82
  83 : sequence>hashtable ( seq map-quot insert-quot -- hashtable )
  84     H{ } sequence>assoc ; inline
  85
  86 : expand-keys-set-at-as ( assoc exemplar -- hashtable' )
  87     [
  88         [ swap dup sequence? [ 1array ] unless ]
  89         [ '[ _ set-at ] with each ]
  90     ] dip assoc>object ;
  91
  92 : expand-keys-set-at ( assoc -- hashtable' )
  93     H{ } expand-keys-set-at-as ;
  94
  95 : expand-keys-push-at-as ( assoc exemplar -- hashtable' )
  96     [
  97         [ swap dup sequence? [ 1array ] unless ]
  98         [ '[ _ push-at ] with each ]
  99     ] dip assoc>object ;
 100
 101 : expand-keys-push-at ( assoc -- hashtable' )
 102     H{ } expand-keys-push-at-as ; inline
 103
 104 : expand-keys-push-as ( assoc exemplar -- hashtable' )
 105     [
 106         [ [ dup sequence? [ 1array ] unless ] dip ]
 107         [ '[ 2array _ push ] curry each ]
 108     ] dip assoc>object ;
 109
 110 : expand-keys-push ( assoc -- hashtable' )
 111     V{ } expand-keys-push-as ; inline
 112
 113 : expand-values-set-at-as ( assoc exemplar -- hashtable' )
 114     [
 115         [ dup sequence? [ 1array ] unless swap ]
 116         [ '[ _ set-at ] curry each ]
 117     ] dip assoc>object ;
 118
 119 : expand-values-set-at ( assoc -- hashtable' )
 120     H{ } expand-values-set-at-as ; inline
 121
 122 : expand-values-push-at-as ( assoc exemplar -- hashtable' )
 123     [
 124         [ dup sequence? [ 1array ] unless swap ]
 125         [ '[ _ push-at ] curry each ]
 126     ] dip assoc>object ;
 127
 128 : expand-values-push-at ( assoc -- assoc )
 129     H{ } expand-values-push-at-as ; inline
 130
 131 : expand-values-push-as ( assoc exemplar -- assoc )
 132     [
 133         [ dup sequence? [ 1array ] unless ]
 134         [ '[ 2array _ push ] with each ]
 135     ] dip assoc>object ;
 136
 137 : expand-values-push ( assoc -- sequence )
 138     V{ } expand-values-push-as ; inline
 139
 140 : assoc-any-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 141     [ drop ] prepose assoc-find 2nip ; inline
 142
 143 : assoc-any-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 144     [ nip ] prepose assoc-find 2nip ; inline
 145
 146 : assoc-all-key? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 147     [ not ] compose assoc-any-key? not  ; inline
 148
 149 : assoc-all-value? ( ... assoc quot: ( ... key -- ... ? ) -- ... ? )
 150     [ not ] compose assoc-any-value? not  ; inline
 151
 152 : any-multi-key? ( assoc -- ? )
 153     [ sequence? ] assoc-any-key? ;
 154
 155 : any-multi-value? ( assoc -- ? )
 156     [ sequence? ] assoc-any-value? ;
 157
 158 : flatten-keys ( assoc -- assoc' )
 159     dup any-multi-key? [ expand-keys-set-at flatten-keys ] when ;
 160
 161 : flatten-values ( assoc -- assoc' )
 162     dup any-multi-value? [ expand-values-set-at flatten-values ] when ;