extra/assocs/extras/extras.factor

   1 ! Copyright (C) 2012 John Benediktsson, Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: arrays assocs assocs.private kernel math sequences ;
   5
   6 IN: assocs.extras
   7
   8 : assoc-sift ( assoc -- assoc' )
   9     [ nip ] assoc-filter ; inline
  10
  11 : assoc-harvest ( assoc -- assoc' )
  12     [ nip empty? ] assoc-reject ; inline
  13
  14 : deep-at ( assoc seq -- value/f )
  15     [ of ] each ; inline
  16
  17 : substitute! ( seq assoc -- seq )
  18     substituter map! ;
  19
  20 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
  21     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
  22
  23 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  24     [ drop ] prepose assoc-reduce ; inline
  25
  26 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
  27     [ nip ] prepose assoc-reduce ; inline
  28
  29 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
  30
  31 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
  32
  33 : if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
  34     [ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  35
  36 : assoc-invert-as ( assoc exemplar -- newassoc )
  37     [ swap ] swap assoc-map-as ;
  38
  39 : assoc-invert ( assoc -- newassoc )
  40     dup assoc-invert-as ;
  41
  42 : assoc-merge! ( assoc1 assoc2 -- assoc1 )
  43     over [ push-at ] with-assoc assoc-each ;
  44
  45 : assoc-merge ( assoc1 assoc2 -- newassoc )
  46     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
  47     [ assoc-merge! ] bi@ ;
  48
  49 GENERIC: delete-value-at ( value assoc -- )
  50
  51 M: assoc delete-value-at
  52     [ value-at* ] keep swap [ delete-at ] [ 2drop ] if ;