extra/audio/engine/engine.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien audio classes.struct fry calendar alarms
   3 combinators combinators.short-circuit destructors generalizations
   4 kernel literals locals math openal sequences specialized-arrays strings ;
   5 QUALIFIED-WITH: alien.c-types c
   6 SPECIALIZED-ARRAYS: c:float c:uchar c:uint ;
   7 IN: audio.engine
   8
   9 TUPLE: audio-source
  10     { position initial: { 0.0 0.0 0.0 } }
  11     { gain float initial: 1.0 }
  12     { velocity initial: { 0.0 0.0 0.0 } }
  13     { relative? boolean initial: f }
  14     { distance float initial: 1.0 }
  15     { rolloff float initial: 1.0 } ;
  16
  17 TUPLE: audio-orientation
  18     { forward initial: { 0.0 0.0 -1.0 } }
  19     { up initial: { 0.0 1.0 0.0 } } ;
  20
  21 C: <audio-orientation> audio-orientation
  22
  23 : orientation>float-array ( orientation -- float-array )
  24     [ forward>> first3 ]
  25     [ up>> first3 ] bi 6 float-array{ } nsequence ; inline
  26
  27 TUPLE: audio-listener
  28     { position initial: { 0.0 0.0 0.0 } }
  29     { gain float initial: 1.0 }
  30     { velocity initial: { 0.0 0.0 0.0 } }
  31     { orientation initial: T{ audio-orientation } } ;
  32
  33 GENERIC: audio-position ( source/listener -- position )
  34 GENERIC: audio-gain ( source/listener -- gain )
  35 GENERIC: audio-velocity ( source/listener -- velocity )
  36 GENERIC: audio-relative? ( source -- relative? )
  37 GENERIC: audio-distance ( source -- distance )
  38 GENERIC: audio-rolloff ( source -- rolloff )
  39 GENERIC: audio-orientation ( listener -- orientation )
  40
  41 M: object audio-position drop { 0.0 0.0 0.0 } ; inline
  42 M: object audio-gain drop 1.0 ; inline
  43 M: object audio-velocity drop { 0.0 0.0 0.0 } ; inline
  44 M: object audio-relative? drop f ; inline
  45 M: object audio-distance drop 1.0 ; inline
  46 M: object audio-rolloff drop 1.0 ; inline
  47 M: object audio-orientation drop T{ audio-orientation } ; inline
  48
  49 M: audio-source audio-position position>> ; inline
  50 M: audio-source audio-gain gain>> ; inline
  51 M: audio-source audio-velocity velocity>> ; inline
  52 M: audio-source audio-relative? relative?>> ; inline
  53 M: audio-source audio-distance distance>> ; inline
  54 M: audio-source audio-rolloff rolloff>> ; inline
  55
  56 M: audio-listener audio-position position>> ; inline
  57 M: audio-listener audio-gain gain>> ; inline
  58 M: audio-listener audio-velocity velocity>> ; inline
  59 M: audio-listener audio-orientation orientation>> ; inline
  60
  61 GENERIC: generate-audio ( generator -- c-ptr size )
  62 GENERIC: generator-audio-format ( generator -- channels sample-bits sample-rate )
  63
  64 TUPLE: audio-engine < disposable
  65     { voice-count integer }
  66     { al-device c-ptr }
  67     { al-context c-ptr }
  68     al-sources
  69     listener
  70     { next-source integer }
  71     clips
  72     update-alarm ;
  73
  74 TUPLE: audio-clip < disposable
  75     { audio-engine audio-engine }
  76     source
  77     { al-source integer } ;
  78
  79 TUPLE: static-audio-clip < audio-clip
  80     { al-buffer integer } ;
  81
  82 TUPLE: streaming-audio-clip < audio-clip
  83     generator
  84     { channels integer }
  85     { sample-bits integer }
  86     { sample-rate integer }
  87     { al-buffers uint-array }
  88     { done? boolean } ;
  89
  90 ERROR: audio-device-not-found device-name ;
  91 ERROR: audio-context-not-available device-name ;
  92
  93 :: <audio-engine> ( device-name voice-count -- engine )
  94     [
  95         device-name alcOpenDevice :> al-device
  96         al-device [ device-name audio-device-not-found ] unless
  97         al-device |alcCloseDevice* drop
  98
  99         al-device f alcCreateContext :> al-context
 100         al-context [ device-name audio-context-not-available ] unless
 101         al-context |alcDestroyContext drop
 102
 103         al-context alcSuspendContext
 104
 105         audio-engine new-disposable
 106             voice-count >>voice-count
 107             al-device >>al-device
 108             al-context >>al-context
 109     ] with-destructors ;
 110
 111 : <standard-audio-engine> ( -- engine )
 112     f 16 <audio-engine> ;
 113
 114 <PRIVATE
 115
 116 : make-engine-current ( audio-engine -- )
 117     al-context>> alcMakeContextCurrent drop ; inline
 118
 119 : allocate-sources ( audio-engine -- sources )
 120     voice-count>> dup (uint-array) [ alGenSources ] keep ; inline
 121
 122 :: flush-source ( al-source -- )
 123     al-source alSourceStop
 124     0 c:<uint> :> dummy-buffer
 125     al-source AL_BUFFERS_PROCESSED get-source-param [
 126         al-source 1 dummy-buffer alSourceUnqueueBuffers
 127     ] times
 128     al-source AL_BUFFER 0 alSourcei ;
 129
 130 : free-sources ( sources -- )
 131     [ length ] keep alDeleteSources ; inline
 132
 133 :: (get-available-source) ( sources source# stop-source# -- next-source# al-source/f )
 134     source# sources nth :> al-source
 135     source# 1 + sources length mod :> next-source#
 136     al-source {
 137         [ AL_BUFFERS_PROCESSED get-source-param 0 = ]
 138         [ AL_BUFFERS_QUEUED get-source-param 0 = ]
 139         [ AL_SOURCE_STATE get-source-param { $ AL_INITIAL $ AL_STOPPED } member? ]
 140     } 1&&
 141     [ next-source# al-source ] [
 142         next-source# stop-source# =
 143         [ next-source# f ]
 144         [ sources next-source# stop-source# (get-available-source) ] if
 145     ] if ;
 146
 147 :: get-available-source ( audio-engine -- al-source/f )
 148     audio-engine [ al-sources>> ] [ next-source>> ] bi dup (get-available-source)
 149         :> ( next-source al-source )
 150     audio-engine next-source >>next-source drop
 151     al-source ;
 152
 153 :: queue-clip-buffer ( audio-clip al-buffer -- )
 154     audio-clip done?>> [
 155         audio-clip al-source>> :> al-source
 156         audio-clip generator>> :> generator
 157         generator generate-audio :> ( data size )
 158
 159         size { [ not ] [ zero? ] } 1|| [
 160             audio-clip t >>done? drop
 161         ] [
 162             al-buffer audio-clip openal-format data size audio-clip sample-rate>> alBufferData
 163             al-source 1 al-buffer c:<uint> alSourceQueueBuffers
 164         ] if
 165     ] unless ;
 166
 167 : update-listener ( audio-engine -- )
 168     listener>> {
 169         [ AL_POSITION swap audio-position first3 alListener3f ]
 170         [ AL_GAIN swap audio-gain alListenerf ]
 171         [ AL_VELOCITY swap audio-velocity first3 alListener3f ]
 172         [ AL_ORIENTATION swap audio-orientation orientation>float-array alListenerfv ]
 173     } cleave ;
 174
 175 : update-source ( audio-clip -- )
 176     [ al-source>> ] [ source>> ] bi {
 177         [ AL_POSITION swap audio-position first3 alSource3f ]
 178         [ AL_GAIN swap audio-gain alSourcef ]
 179         [ AL_VELOCITY swap audio-velocity first3 alSource3f ]
 180         [ AL_SOURCE_RELATIVE swap audio-relative? c:>c-bool alSourcei ]
 181         [ AL_REFERENCE_DISTANCE swap audio-distance alSourcef ]
 182         [ AL_ROLLOFF_FACTOR swap audio-rolloff alSourcef ]
 183     } 2cleave ;
 184
 185 GENERIC: (update-audio-clip) ( audio-clip -- )
 186
 187 M: static-audio-clip (update-audio-clip)
 188     drop ;
 189
 190 M:: streaming-audio-clip (update-audio-clip) ( audio-clip -- )
 191     audio-clip al-source>> :> al-source
 192     0 c:<uint> :> buffer
 193     al-source AL_BUFFERS_PROCESSED get-source-param [
 194         al-source 1 buffer alSourceUnqueueBuffers
 195         audio-clip buffer c:*uint queue-clip-buffer
 196     ] times ;
 197
 198 : update-audio-clip ( audio-clip -- )
 199     [ update-source ] [
 200         dup al-source>> AL_SOURCE_STATE get-source-param AL_STOPPED =
 201         [ dispose ] [ (update-audio-clip) ] if
 202     ] bi ;
 203
 204 : clip-al-sources ( clips -- length sources )
 205     [ length ] [ [ al-source>> ] uint-array{ } map-as ] bi ;
 206
 207 PRIVATE>
 208
 209 DEFER: update-audio
 210
 211 : start-audio* ( audio-engine -- )
 212     dup al-sources>> [ drop ] [
 213         {
 214             [ make-engine-current ]
 215             [ al-context>> alcProcessContext ]
 216             [
 217                 dup allocate-sources >>al-sources
 218                 0 >>next-source
 219                 V{ } clone >>clips
 220                 drop
 221             ]
 222             [ update-listener ]
 223         } cleave
 224     ] if ;
 225
 226 : start-audio ( audio-engine -- )
 227     dup start-audio*
 228     dup '[ _ update-audio ] 20 milliseconds every >>update-alarm
 229     drop ;
 230
 231 : stop-audio ( audio-engine -- )
 232     dup al-sources>> [
 233         {
 234             [ make-engine-current ]
 235             [ update-alarm>> [ cancel-alarm ] when* ]
 236             [ clips>> clone [ dispose ] each ]
 237             [ al-sources>> free-sources ]
 238             [
 239                 f >>al-sources
 240                 f >>clips
 241                 f >>update-alarm
 242                 drop
 243             ]
 244             [ al-context>> alcSuspendContext ]
 245         } cleave
 246     ] [ drop ] if ;
 247
 248 M: audio-engine dispose*
 249     dup stop-audio
 250     [ [ alcDestroyContext ] when* f ] change-al-context
 251     [ [ alcCloseDevice*   ] when* f ] change-al-device
 252     drop ;
 253
 254 :: <static-audio-clip> ( audio-engine source audio loop? -- audio-clip/f )
 255     audio-engine get-available-source :> al-source
 256
 257     al-source [
 258         1 0 c:<uint> [ alGenBuffers ] keep c:*uint :> al-buffer
 259         al-buffer audio { [ openal-format ] [ data>> ] [ size>> ] [ sample-rate>> ] } cleave
 260             alBufferData
 261
 262         al-source AL_BUFFER al-buffer alSourcei
 263         al-source AL_LOOPING loop? c:>c-bool alSourcei
 264
 265         static-audio-clip new-disposable
 266             audio-engine >>audio-engine
 267             source >>source
 268             al-source >>al-source
 269             al-buffer >>al-buffer
 270             :> clip
 271         clip audio-engine clips>> push
 272         clip
 273     ] [ f ] if ;
 274
 275 :: <streaming-audio-clip> ( audio-engine source generator buffer-count -- audio-clip/f )
 276     audio-engine get-available-source :> al-source
 277
 278     al-source [
 279         buffer-count dup (uint-array) [ alGenBuffers ] keep :> al-buffers
 280         generator generator-audio-format :> ( channels sample-bits sample-rate )
 281
 282         streaming-audio-clip new-disposable
 283             audio-engine >>audio-engine
 284             source >>source
 285             al-source >>al-source
 286             generator >>generator
 287             channels >>channels
 288             sample-bits >>sample-bits
 289             sample-rate >>sample-rate
 290             al-buffers >>al-buffers
 291             :> clip
 292         al-buffers [ clip swap queue-clip-buffer ] each
 293         clip audio-engine clips>> push
 294         clip
 295     ] [ generator dispose f ] if ;
 296
 297 M: audio-clip dispose*
 298     [ dup audio-engine>> clips>> remove! drop ]
 299     [ al-source>> flush-source ] bi ;
 300
 301 M: static-audio-clip dispose*
 302     [ call-next-method ]
 303     [ [ 1 ] dip al-buffer>> c:<uint> alDeleteBuffers ] bi ;
 304
 305 M: streaming-audio-clip dispose*
 306     [ call-next-method ]
 307     [ generator>> dispose ]
 308     [ al-buffers>> [ length ] keep alDeleteBuffers ] tri ;
 309
 310 : play-clip ( audio-clip -- )
 311     [ update-source ]
 312     [ al-source>> alSourcePlay ] bi ;
 313
 314 : play-clips ( audio-clips -- )
 315     [ [ update-source ] each ]
 316     [ clip-al-sources alSourcePlayv ] bi ;
 317
 318 : play-static-audio-clip ( audio-engine source audio loop? -- audio-clip/f )
 319     <static-audio-clip> dup [ play-clip ] when* ;
 320
 321 : play-streaming-audio-clip ( audio-engine source generator buffer-count -- audio-clip/f )
 322     <streaming-audio-clip> dup [ play-clip ] when* ;
 323
 324 : pause-clip ( audio-clip -- )
 325     al-source>> alSourcePause ;
 326
 327 : pause-clips ( audio-clips -- )
 328     clip-al-sources alSourcePausev ;
 329
 330 : stop-clip ( audio-clip -- )
 331     dispose ;
 332
 333 : stop-clips ( audio-clips -- )
 334     [ clip-al-sources alSourceStopv ]
 335     [ [ dispose ] each ] bi ;
 336
 337 : update-audio ( audio-engine -- )
 338     {
 339         [ make-engine-current ]
 340         [ update-listener ]
 341         [ clips>> clone [ update-audio-clip ] each ]
 342     } cleave ;
 343