extra/audio/engine/test/test.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alarms audio audio.engine audio.loader calendar
   3 destructors io kernel locals math math.functions math.ranges specialized-arrays
   4 sequences random math.vectors ;
   5 FROM: alien.c-types => short ;
   6 SPECIALIZED-ARRAY: short
   7 IN: audio.engine.test
   8
   9 TUPLE: noise-generator ;
  10
  11 M: noise-generator generator-audio-format
  12     drop 1 16 8000 ;
  13 M: noise-generator generate-audio
  14     drop
  15     4096 [ -4096 4096 [a,b] random ] short-array{ } replicate-as
  16     8192 ;
  17
  18 :: audio-engine-test ( -- )
  19     "vocab:audio/engine/test/loop.aiff" read-audio :> loop-sound
  20     "vocab:audio/engine/test/once.wav" read-audio :> once-sound
  21     0 :> i!
  22     <standard-audio-engine> :> engine
  23     engine start-audio*
  24
  25     engine T{ audio-source f {  1.0 0.0 0.0 } 1.0 { 0.0 0.0 0.0 } f } loop-sound t
  26         play-static-audio-clip :> loop-clip
  27     engine T{ audio-source f { -1.0 0.0 0.0 } 1.0 { 0.0 0.0 0.0 } f } noise-generator new 2
  28         play-streaming-audio-clip :> noise-clip
  29
  30     [
  31         i 1 + i!
  32         i 0.05 * [ sin ] [ cos ] bi :> ( s c )
  33         loop-clip  source>> { c 0.0 s }          >>position drop
  34         noise-clip source>> { c 0.0 s } -2.0 v*n >>position drop
  35
  36         i 50 mod zero? [
  37             engine T{ audio-source f { 0.0 0.0 0.0 } 1.0 { 0.0 0.0 0.0 } f } once-sound f
  38             play-static-audio-clip drop
  39         ] when
  40
  41         engine update-audio
  42     ] 20 milliseconds every :> alarm
  43     "Press Enter to stop the test." print
  44     readln drop
  45     alarm cancel-alarm
  46     engine dispose ;
  47
  48 MAIN: audio-engine-test