extra/audio/wav/wav.factor

   1 ! Copyright (C) 2009 Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types alien.syntax audio combinators endian
   4 combinators.short-circuit io io.binary io.encodings.binary
   5 io.files io.streams.byte-array kernel locals math
   6 sequences alien alien.data classes.struct accessors
   7 audio.chunked-file audio.loader ;
   8 IN: audio.wav
   9
  10 CONSTANT: RIFF-MAGIC "RIFF"
  11 CONSTANT: WAVE-MAGIC "WAVE"
  12 CONSTANT: FMT-MAGIC  "fmt "
  13 CONSTANT: DATA-MAGIC "data"
  14
  15 STRUCT: riff-chunk-header
  16     { id char[4] }
  17     { size char[4] } ;
  18
  19 STRUCT: riff-chunk
  20     { header riff-chunk-header }
  21     { format char[4] } ;
  22
  23 STRUCT: wav-fmt-chunk
  24     { header riff-chunk-header }
  25     { audio-format uchar[2] }
  26     { num-channels uchar[2] }
  27     { sample-rate uchar[4] }
  28     { byte-rate uchar[4] }
  29     { block-align uchar[2] }
  30     { bits-per-sample uchar[2] } ;
  31
  32 STRUCT: wav-data-chunk
  33     { header riff-chunk-header }
  34     { body uchar[0] } ;
  35
  36 : read-riff-chunk ( -- byte-array/f )
  37     riff-chunk heap-size ensured-read* ;
  38
  39 :: read-wav-chunks ( -- fmt data )
  40     f :> fmt! f :> data!
  41     [ { [ fmt data and not ] [ read-chunk ] } 0&& ]
  42     [ {
  43         { [ dup FMT-MAGIC  wav-fmt-chunk  check-chunk ] [ wav-fmt-chunk  memory>struct fmt!  ] }
  44         { [ dup DATA-MAGIC wav-data-chunk check-chunk ] [ wav-data-chunk memory>struct data! ] }
  45         [ drop ]
  46     } cond ] while*
  47     fmt data 2dup and [ invalid-audio-file ] unless ;
  48
  49 : verify-wav ( chunk -- )
  50     {
  51         [ RIFF-MAGIC id= ]
  52         [ riff-chunk memory>struct format>> 4 memory>byte-array WAVE-MAGIC id= ]
  53     } 1&&
  54     [ invalid-audio-file ] unless ;
  55
  56 : (read-wav) ( -- audio )
  57     read-wav-chunks
  58     [
  59         [ num-channels>>    2 memory>byte-array le> ]
  60         [ bits-per-sample>> 2 memory>byte-array le> ]
  61         [ sample-rate>>     4 memory>byte-array le> ] tri
  62     ] [
  63         [ header>> size>> 4 memory>byte-array le> dup ]
  64         [ body>> >c-ptr ] bi swap memory>byte-array
  65     ] bi*
  66     <audio> convert-data-endian ;
  67
  68 : read-wav ( filename -- audio )
  69     little-endian [
  70         binary [
  71             read-riff-chunk verify-wav (read-wav)
  72         ] with-file-reader
  73     ] with-endianness ;
  74
  75 "wav" [ read-wav ] register-audio-extension