extra/benchmark/nbody/nbody.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors specialized-arrays.double fry kernel locals math
   4 math.constants math.functions math.vectors prettyprint combinators.smart
   5 sequences hints arrays ;
   6 IN: benchmark.nbody
   7
   8 : solar-mass ( -- x ) 4 pi sq * ; inline
   9 CONSTANT: days-per-year 365.24
  10
  11 TUPLE: body
  12 { location double-array }
  13 { velocity double-array }
  14 { mass float read-only } ;
  15
  16 : <body> ( location velocity mass -- body )
  17     [ days-per-year v*n ] [ solar-mass * ] bi* body boa ; inline
  18
  19 : <jupiter> ( -- body )
  20     double-array{ 4.84143144246472090e+00 -1.16032004402742839e+00 -1.03622044471123109e-01 }
  21     double-array{ 1.66007664274403694e-03 7.69901118419740425e-03 -6.90460016972063023e-05 }
  22     9.54791938424326609e-04
  23     <body> ;
  24
  25 : <saturn> ( -- body )
  26     double-array{ 8.34336671824457987e+00 4.12479856412430479e+00 -4.03523417114321381e-01 }
  27     double-array{ -2.76742510726862411e-03 4.99852801234917238e-03 2.30417297573763929e-05 }
  28     2.85885980666130812e-04
  29     <body> ;
  30
  31 : <uranus> ( -- body )
  32     double-array{ 1.28943695621391310e+01 -1.51111514016986312e+01 -2.23307578892655734e-01 }
  33     double-array{ 2.96460137564761618e-03 2.37847173959480950e-03 -2.96589568540237556e-05 }
  34     4.36624404335156298e-05
  35     <body> ;
  36
  37 : <neptune> ( -- body )
  38     double-array{ 1.53796971148509165e+01 -2.59193146099879641e+01 1.79258772950371181e-01 }
  39     double-array{ 2.68067772490389322e-03 1.62824170038242295e-03 -9.51592254519715870e-05 }
  40     5.15138902046611451e-05
  41     <body> ;
  42
  43 : <sun> ( -- body )
  44     double-array{ 0 0 0 } double-array{ 0 0 0 } 1 <body> ;
  45
  46 : offset-momentum ( body offset -- body )
  47     vneg solar-mass v/n >>velocity ; inline
  48
  49 TUPLE: nbody-system { bodies array read-only } ;
  50
  51 : init-bodies ( bodies -- )
  52     [ first ] [ double-array{ 0 0 0 } [ [ velocity>> ] [ mass>> ] bi v*n v+ ] reduce ] bi
  53     offset-momentum drop ; inline
  54
  55 : <nbody-system> ( -- system )
  56     [ <sun> <jupiter> <saturn> <uranus> <neptune> ] output>array nbody-system boa
  57     dup bodies>> init-bodies ; inline
  58
  59 :: each-pair ( bodies pair-quot: ( other-body body -- ) each-quot: ( body -- ) -- )
  60     bodies [| body i |
  61         body each-quot call
  62         bodies i 1 + tail-slice [
  63             body pair-quot call
  64         ] each
  65     ] each-index ; inline
  66
  67 : update-position ( body dt -- )
  68     [ dup velocity>> ] dip '[ _ _ v*n v+ ] change-location drop ;
  69
  70 : mag ( dt body other-body -- mag d )
  71     [ location>> ] bi@ v- [ norm-sq dup sqrt * / ] keep ; inline
  72
  73 :: update-velocity ( other-body body dt -- )
  74     dt body other-body mag
  75     [ [ body ] 2dip '[ other-body mass>> _ * _ n*v v- ] change-velocity drop ]
  76     [ [ other-body ] 2dip '[ body mass>> _ * _ n*v v+ ] change-velocity drop ] 2bi ;
  77
  78 : advance ( system dt -- )
  79     [ bodies>> ] dip
  80     [ '[ _ update-velocity ] [ drop ] each-pair ]
  81     [ '[ _ update-position ] each ]
  82     2bi ; inline
  83
  84 : inertia ( body -- e )
  85     [ mass>> ] [ velocity>> norm-sq ] bi * 0.5 * ;
  86
  87 : newton's-law ( other-body body -- e )
  88     [ [ mass>> ] bi@ * ] [ [ location>> ] bi@ distance ] 2bi / ;
  89
  90 : energy ( system -- x )
  91     [ 0.0 ] dip bodies>> [ newton's-law - ] [ inertia + ] each-pair ; inline
  92
  93 : nbody ( n -- )
  94     <nbody-system>
  95     [ energy . ] [ '[ _ 0.01 advance ] times ] [ energy . ] tri ;
  96
  97 HINTS: update-position body float ;
  98 HINTS: update-velocity body body float ;
  99 HINTS: inertia body ;
 100 HINTS: newton's-law body body ;
 101 HINTS: nbody fixnum ;
 102
 103 : nbody-main ( -- ) 1000000 nbody ;
 104
 105 MAIN: nbody-main