extra/benchmark/raytracer/raytracer.factor

   1 ! Factor port of the raytracer benchmark from
   2 ! http://www.ffconsultancy.com/free/ray_tracer/languages.html
   3
   4 USING: float-arrays compiler generic io io.files kernel math
   5 math.functions math.vectors math.parser namespaces sequences
   6 sequences.private words io.encodings.binary ;
   7 IN: benchmark.raytracer
   8
   9 ! parameters
  10 : light
  11     #! Normalized { -1 -3 2 }.
  12     F{
  13         -0.2672612419124244
  14         -0.8017837257372732
  15         0.5345224838248488
  16     } ; inline
  17
  18 : oversampling 4 ; inline
  19
  20 : levels 3 ; inline
  21
  22 : size 200 ; inline
  23
  24 : delta 1.4901161193847656E-8 ; inline
  25
  26 TUPLE: ray orig dir ;
  27
  28 C: <ray> ray
  29
  30 TUPLE: hit normal lambda ;
  31
  32 C: <hit> hit
  33
  34 GENERIC: intersect-scene ( hit ray scene -- hit )
  35
  36 TUPLE: sphere center radius ;
  37
  38 C: <sphere> sphere
  39
  40 : sphere-v ( sphere ray -- v )
  41     swap sphere-center swap ray-orig v- ; inline
  42
  43 : sphere-b ( ray v -- b ) swap ray-dir v. ; inline
  44
  45 : sphere-disc ( sphere v b -- d )
  46     sq swap norm-sq - swap sphere-radius sq + ; inline
  47
  48 : -+ ( x y -- x-y x+y ) [ - ] 2keep + ; inline
  49
  50 : sphere-b/d ( b d -- t )
  51     -+ dup 0.0 < [ 2drop 1.0/0.0 ] [ >r [ 0.0 > ] keep r> ? ] if ; inline
  52
  53 : ray-sphere ( sphere ray -- t )
  54     2dup sphere-v tuck sphere-b [ sphere-disc ] keep
  55     over 0.0 < [ 2drop 1.0/0.0 ] [ swap sqrt sphere-b/d ] if ;
  56     inline
  57
  58 : sphere-n ( ray sphere l -- n )
  59     pick ray-dir n*v swap sphere-center v- swap ray-orig v+ ;
  60     inline
  61
  62 : if-ray-sphere ( hit ray sphere quot -- hit )
  63     #! quot: hit ray sphere l -- hit
  64     >r pick hit-lambda >r 2dup swap ray-sphere dup r> >=
  65     [ 3drop ] r> if ; inline
  66
  67 M: sphere intersect-scene ( hit ray sphere -- hit )
  68     [ [ sphere-n normalize ] keep <hit> nip ] if-ray-sphere ;
  69
  70 TUPLE: group objs ;
  71
  72 : <group> ( objs bound -- group )
  73     { set-group-objs set-delegate } group construct ;
  74
  75 : make-group ( bound quot -- )
  76     swap >r { } make r> <group> ; inline
  77
  78 M: group intersect-scene ( hit ray group -- hit )
  79     [
  80         drop
  81         group-objs [ >r tuck r> intersect-scene swap ] each
  82         drop
  83     ] if-ray-sphere ;
  84
  85 : initial-hit T{ hit f F{ 0.0 0.0 0.0 } 1.0/0.0 } ; inline
  86
  87 : initial-intersect ( ray scene -- hit )
  88     initial-hit -rot intersect-scene ; inline
  89
  90 : ray-o ( ray hit -- o )
  91     over ray-dir over hit-lambda v*n
  92     swap hit-normal delta v*n v+
  93     swap ray-orig v+ ; inline
  94
  95 : sray-intersect ( ray scene hit -- ray )
  96     swap >r ray-o light vneg <ray> r> initial-intersect ; inline
  97
  98 : ray-g ( hit -- g ) hit-normal light v. ; inline
  99
 100 : cast-ray ( ray scene -- g )
 101     2dup initial-intersect dup hit-lambda 1.0/0.0 = [
 102         3drop 0.0
 103     ] [
 104         dup ray-g >r sray-intersect hit-lambda 1.0/0.0 =
 105         [ r> neg ] [ r> drop 0.0 ] if
 106     ] if ; inline
 107
 108 : create-center ( c r d -- c2 )
 109     >r 3.0 12.0 sqrt / * r> n*v v+ ; inline
 110
 111 DEFER: create ( level c r -- scene )
 112
 113 : create-step ( level c r d -- scene )
 114     over >r create-center r> 2.0 / >r >r 1 - r> r> create ;
 115
 116 : create-offsets ( quot -- )
 117     {
 118         F{ -1.0 1.0 -1.0 }
 119         F{ 1.0 1.0 -1.0 }
 120         F{ -1.0 1.0 1.0 }
 121         F{ 1.0 1.0 1.0 }
 122     } swap each ; inline
 123
 124 : create-bound ( c r -- sphere ) 3.0 * <sphere> ;
 125
 126 : create-group ( level c r -- scene )
 127     2dup create-bound [
 128         2dup <sphere> ,
 129         [ >r 3dup r> create-step , ] create-offsets 3drop
 130     ] make-group ;
 131
 132 : create ( level c r -- scene )
 133     pick 1 = [ <sphere> nip ] [ create-group ] if ;
 134
 135 : ss-point ( dx dy -- point )
 136     [ oversampling /f ] bi@ 0.0 3float-array ;
 137
 138 : ss-grid ( -- ss-grid )
 139     oversampling [ oversampling [ ss-point ] with map ] map ;
 140
 141 : ray-grid ( point ss-grid -- ray-grid )
 142     [
 143         [ v+ normalize { 0.0 0.0 -4.0 } swap <ray> ] with map
 144     ] with map ;
 145
 146 : ray-pixel ( scene point -- n )
 147     ss-grid ray-grid 0.0 -rot
 148     [ [ swap cast-ray + ] with each ] with each ;
 149
 150 : pixel-grid ( -- grid )
 151     size reverse [
 152         size [
 153             [ size 0.5 * - ] bi@ swap size
 154             3float-array
 155         ] with map
 156     ] map ;
 157
 158 : pgm-header ( w h -- )
 159     "P5\n" % swap # " " % # "\n255\n" % ;
 160
 161 : pgm-pixel ( n -- ) 255 * 0.5 + >fixnum , ;
 162
 163 : ray-trace ( scene -- pixels )
 164     pixel-grid [ [ ray-pixel ] with map ] with map ;
 165
 166 : run ( -- string )
 167     levels { 0.0 -1.0 0.0 } 1.0 create ray-trace [
 168         size size pgm-header
 169         [ [ oversampling sq / pgm-pixel ] each ] each
 170     ] B{ } make ;
 171
 172 : raytracer-main ( -- )
 173     run "raytracer.pnm" temp-file binary set-file-contents ;
 174
 175 MAIN: raytracer-main