extra/benchmark/raytracer/raytracer.factor

   1 ! Factor port of the raytracer benchmark from
   2 ! http://www.ffconsultancy.com/free/ray_tracer/languages.html
   3
   4 USING: arrays accessors specialized-arrays io io.files
   5 io.files.temp io.encodings.binary kernel math math.constants
   6 math.functions math.vectors math.parser make sequences
   7 sequences.private words hints ;
   8 SPECIALIZED-ARRAY: double
   9 IN: benchmark.raytracer
  10
  11 ! parameters
  12
  13 ! Normalized { -1 -3 2 }.
  14 CONSTANT: light
  15     double-array{
  16         -0.2672612419124244
  17         -0.8017837257372732
  18         0.5345224838248488
  19     }
  20
  21 CONSTANT: oversampling 4
  22
  23 CONSTANT: levels 3
  24
  25 CONSTANT: size 200
  26
  27 : delta ( -- n ) epsilon sqrt ; inline
  28
  29 TUPLE: ray { orig double-array read-only } { dir double-array read-only } ;
  30
  31 C: <ray> ray
  32
  33 TUPLE: hit { normal double-array read-only } { lambda float read-only } ;
  34
  35 C: <hit> hit
  36
  37 GENERIC: intersect-scene ( hit ray scene -- hit )
  38
  39 TUPLE: sphere { center double-array read-only } { radius float read-only } ;
  40
  41 C: <sphere> sphere
  42
  43 : sphere-v ( sphere ray -- v )
  44     [ center>> ] [ orig>> ] bi* v- ; inline
  45
  46 : sphere-b ( v ray -- b )
  47     dir>> v. ; inline
  48
  49 : sphere-d ( sphere b v -- d )
  50     [ radius>> sq ] [ sq ] [ norm-sq ] tri* - + ; inline
  51
  52 : -+ ( x y -- x-y x+y )
  53     [ - ] [ + ] 2bi ; inline
  54
  55 : sphere-t ( b d -- t )
  56     -+ dup 0.0 <
  57     [ 2drop 1/0. ] [ [ [ 0.0 > ] keep ] dip ? ] if ; inline
  58
  59 : sphere-b&v ( sphere ray -- b v )
  60     [ sphere-v ] [ nip ] 2bi
  61     [ sphere-b ] [ drop ] 2bi ; inline
  62
  63 : ray-sphere ( sphere ray -- t )
  64     [ drop ] [ sphere-b&v ] 2bi
  65     [ drop ] [ sphere-d ] 3bi
  66     dup 0.0 < [ 3drop 1/0. ] [ sqrt sphere-t nip ] if ; inline
  67
  68 : if-ray-sphere ( hit ray sphere quot -- hit )
  69     #! quot: hit ray sphere l -- hit
  70     [
  71         [ ] [ swap ray-sphere nip ] [ 2drop lambda>> ] 3tri
  72         [ drop ] [ < ] 2bi
  73     ] dip [ 3drop ] if ; inline
  74
  75 : sphere-n ( ray sphere l -- n )
  76     [ [ orig>> ] [ dir>> ] bi ] [ center>> ] [ ] tri*
  77     swap [ v*n ] dip v- v+ ; inline
  78
  79 M: sphere intersect-scene ( hit ray sphere -- hit )
  80     [ [ sphere-n normalize ] keep <hit> nip ] if-ray-sphere ;
  81
  82 HINTS: M\ sphere intersect-scene { hit ray sphere } ;
  83
  84 TUPLE: group < sphere { objs array read-only } ;
  85
  86 : <group> ( objs bound -- group )
  87     [ center>> ] [ radius>> ] bi rot group boa ; inline
  88
  89 : make-group ( bound quot -- )
  90     swap [ { } make ] dip <group> ; inline
  91
  92 M: group intersect-scene ( hit ray group -- hit )
  93     [ drop objs>> [ intersect-scene ] with each ] if-ray-sphere ;
  94
  95 HINTS: M\ group intersect-scene { hit ray group } ;
  96
  97 CONSTANT: initial-hit T{ hit f double-array{ 0.0 0.0 0.0 } 1/0. }
  98
  99 : initial-intersect ( ray scene -- hit )
 100     [ initial-hit ] 2dip intersect-scene ; inline
 101
 102 : ray-o ( ray hit -- o )
 103     [ [ orig>> ] [ normal>> delta v*n ] bi* ]
 104     [ [ dir>> ] [ lambda>> ] bi* v*n ]
 105     2bi v+ v+ ; inline
 106
 107 : sray-intersect ( ray scene hit -- ray )
 108     swap [ ray-o light vneg <ray> ] dip initial-intersect ; inline
 109
 110 : ray-g ( hit -- g ) normal>> light v. ; inline
 111
 112 : cast-ray ( ray scene -- g )
 113     2dup initial-intersect dup lambda>> 1/0. = [
 114         3drop 0.0
 115     ] [
 116         [ sray-intersect lambda>> 1/0. = ] keep swap
 117         [ ray-g neg ] [ drop 0.0 ] if
 118     ] if ; inline
 119
 120 : create-center ( c r d -- c2 )
 121     [ 3.0 12.0 sqrt / * ] dip n*v v+ ; inline
 122
 123 DEFER: create ( level c r -- scene )
 124
 125 : create-step ( level c r d -- scene )
 126     over [ create-center ] dip 2.0 / [ 1 - ] 2dip create ;
 127
 128 : create-offsets ( quot -- )
 129     {
 130         double-array{ -1.0 1.0 -1.0 }
 131         double-array{ 1.0 1.0 -1.0 }
 132         double-array{ -1.0 1.0 1.0 }
 133         double-array{ 1.0 1.0 1.0 }
 134     } swap each ; inline
 135
 136 : create-bound ( c r -- sphere ) 3.0 * <sphere> ;
 137
 138 : create-group ( level c r -- scene )
 139     2dup create-bound [
 140         2dup <sphere> ,
 141         [ [ 3dup ] dip create-step , ] create-offsets 3drop
 142     ] make-group ;
 143
 144 : create ( level c r -- scene )
 145     pick 1 = [ <sphere> nip ] [ create-group ] if ;
 146
 147 : ss-point ( dx dy -- point )
 148     [ oversampling /f ] bi@ 0.0 double-array{ } 3sequence ;
 149
 150 : ss-grid ( -- ss-grid )
 151     oversampling [ oversampling [ ss-point ] with map ] map ;
 152
 153 : ray-grid ( point ss-grid -- ray-grid )
 154     [
 155         [ v+ normalize double-array{ 0.0 0.0 -4.0 } swap <ray> ] with map
 156     ] with map ;
 157
 158 : ray-pixel ( scene point -- n )
 159     ss-grid ray-grid [ 0.0 ] 2dip
 160     [ [ swap cast-ray + ] with each ] with each ;
 161
 162 : pixel-grid ( -- grid )
 163     size reverse [
 164         size [
 165             [ size 0.5 * - ] bi@ swap size
 166             double-array{ } 3sequence
 167         ] with map
 168     ] map ;
 169
 170 : pgm-header ( w h -- )
 171     "P5\n" % swap # " " % # "\n255\n" % ;
 172
 173 : pgm-pixel ( n -- ) 255 * 0.5 + >fixnum , ;
 174
 175 : ray-trace ( scene -- pixels )
 176     pixel-grid [ [ ray-pixel ] with map ] with map ;
 177
 178 : run ( -- string )
 179     levels double-array{ 0.0 -1.0 0.0 } 1.0 create ray-trace [
 180         size size pgm-header
 181         [ [ oversampling sq / pgm-pixel ] each ] each
 182     ] B{ } make ;
 183
 184 : raytracer-main ( -- )
 185     run "raytracer.pnm" temp-file binary set-file-contents ;
 186
 187 MAIN: raytracer-main