extra/checksums/sha2/sha2.factor

   1 USING: crypto.common kernel splitting grouping
   2 math sequences namespaces io.binary symbols
   3 math.bitfields.lib checksums ;
   4 IN: checksums.sha2
   5
   6 <PRIVATE
   7
   8 SYMBOLS: vars M K H S0 S1 process-M word-size block-size ;
   9
  10 : a 0 ; inline
  11 : b 1 ; inline
  12 : c 2 ; inline
  13 : d 3 ; inline
  14 : e 4 ; inline
  15 : f 5 ; inline
  16 : g 6 ; inline
  17 : h 7 ; inline
  18
  19 : initial-H-256 ( -- seq )
  20     {
  21         HEX: 6a09e667 HEX: bb67ae85 HEX: 3c6ef372 HEX: a54ff53a
  22         HEX: 510e527f HEX: 9b05688c HEX: 1f83d9ab HEX: 5be0cd19
  23     } ;
  24
  25 : K-256 ( -- seq )
  26     {
  27         HEX: 428a2f98 HEX: 71374491 HEX: b5c0fbcf HEX: e9b5dba5
  28         HEX: 3956c25b HEX: 59f111f1 HEX: 923f82a4 HEX: ab1c5ed5
  29         HEX: d807aa98 HEX: 12835b01 HEX: 243185be HEX: 550c7dc3
  30         HEX: 72be5d74 HEX: 80deb1fe HEX: 9bdc06a7 HEX: c19bf174
  31         HEX: e49b69c1 HEX: efbe4786 HEX: 0fc19dc6 HEX: 240ca1cc
  32         HEX: 2de92c6f HEX: 4a7484aa HEX: 5cb0a9dc HEX: 76f988da
  33         HEX: 983e5152 HEX: a831c66d HEX: b00327c8 HEX: bf597fc7
  34         HEX: c6e00bf3 HEX: d5a79147 HEX: 06ca6351 HEX: 14292967
  35         HEX: 27b70a85 HEX: 2e1b2138 HEX: 4d2c6dfc HEX: 53380d13
  36         HEX: 650a7354 HEX: 766a0abb HEX: 81c2c92e HEX: 92722c85
  37         HEX: a2bfe8a1 HEX: a81a664b HEX: c24b8b70 HEX: c76c51a3
  38         HEX: d192e819 HEX: d6990624 HEX: f40e3585 HEX: 106aa070
  39         HEX: 19a4c116 HEX: 1e376c08 HEX: 2748774c HEX: 34b0bcb5
  40         HEX: 391c0cb3 HEX: 4ed8aa4a HEX: 5b9cca4f HEX: 682e6ff3
  41         HEX: 748f82ee HEX: 78a5636f HEX: 84c87814 HEX: 8cc70208
  42         HEX: 90befffa HEX: a4506ceb HEX: bef9a3f7 HEX: c67178f2
  43     } ;
  44
  45 : s0-256 ( x -- x' )
  46     [ -7 bitroll-32 ] keep
  47     [ -18 bitroll-32 ] keep
  48     -3 shift bitxor bitxor ; inline
  49
  50 : s1-256 ( x -- x' )
  51     [ -17 bitroll-32 ] keep
  52     [ -19 bitroll-32 ] keep
  53     -10 shift bitxor bitxor ; inline
  54
  55 : process-M-256 ( seq n -- )
  56     [ 16 - swap nth ] 2keep
  57     [ 15 - swap nth s0-256 ] 2keep
  58     [ 7 - swap nth ] 2keep
  59     [ 2 - swap nth s1-256 ] 2keep
  60     >r >r + + w+ r> r> swap set-nth ; inline
  61
  62 : prepare-message-schedule ( seq -- w-seq )
  63     word-size get group [ be> ] map block-size get 0 pad-right
  64     dup 16 64 dup <slice> [
  65         process-M-256
  66     ] with each ;
  67
  68 : ch ( x y z -- x' )
  69     [ bitxor bitand ] keep bitxor ;
  70
  71 : maj ( x y z -- x' )
  72     >r [ bitand ] 2keep bitor r> bitand bitor ;
  73
  74 : S0-256 ( x -- x' )
  75     [ -2 bitroll-32 ] keep
  76     [ -13 bitroll-32 ] keep
  77     -22 bitroll-32 bitxor bitxor ; inline
  78
  79 : S1-256 ( x -- x' )
  80     [ -6 bitroll-32 ] keep
  81     [ -11 bitroll-32 ] keep
  82     -25 bitroll-32 bitxor bitxor ; inline
  83
  84 : T1 ( W n -- T1 )
  85     [ swap nth ] keep
  86     K get nth +
  87     e vars get slice3 ch +
  88     e vars get nth S1-256 +
  89     h vars get nth w+ ;
  90
  91 : T2 ( -- T2 )
  92     a vars get nth S0-256
  93     a vars get slice3 maj w+ ;
  94
  95 : update-vars ( T1 T2 -- )
  96     vars get
  97     h g pick exchange
  98     g f pick exchange
  99     f e pick exchange
 100     pick d pick nth w+ e pick set-nth
 101     d c pick exchange
 102     c b pick exchange
 103     b a pick exchange
 104     >r w+ a r> set-nth ;
 105
 106 : process-chunk ( M -- )
 107     H get clone vars set
 108     prepare-message-schedule block-size get [
 109         T1 T2 update-vars
 110     ] with each vars get H get [ w+ ] 2map H set ;
 111
 112 : seq>byte-array ( n seq -- string )
 113     [ swap [ >be % ] curry each ] B{ } make ;
 114
 115 : byte-array>sha2 ( byte-array -- string )
 116     t preprocess-plaintext
 117     block-size get group [ process-chunk ] each
 118     4 H get seq>byte-array ;
 119
 120 PRIVATE>
 121
 122 SINGLETON: sha-256
 123
 124 INSTANCE: sha-256 checksum
 125
 126 M: sha-256 checksum-bytes
 127     drop [
 128         K-256 K set
 129         initial-H-256 H set
 130         4 word-size set
 131         64 block-size set
 132         byte-array>sha2
 133     ] with-scope ;