extra/checksums/sha2/sha2.factor

   1 USING: crypto.common kernel splitting math sequences namespaces
   2 io.binary symbols math.bitfields.lib checksums ;
   3 IN: checksums.sha2
   4
   5 <PRIVATE
   6
   7 SYMBOLS: vars M K H S0 S1 process-M word-size block-size ;
   8
   9 : a 0 ; inline
  10 : b 1 ; inline
  11 : c 2 ; inline
  12 : d 3 ; inline
  13 : e 4 ; inline
  14 : f 5 ; inline
  15 : g 6 ; inline
  16 : h 7 ; inline
  17
  18 : initial-H-256 ( -- seq )
  19     {
  20         HEX: 6a09e667 HEX: bb67ae85 HEX: 3c6ef372 HEX: a54ff53a
  21         HEX: 510e527f HEX: 9b05688c HEX: 1f83d9ab HEX: 5be0cd19
  22     } ;
  23
  24 : K-256 ( -- seq )
  25     {
  26         HEX: 428a2f98 HEX: 71374491 HEX: b5c0fbcf HEX: e9b5dba5
  27         HEX: 3956c25b HEX: 59f111f1 HEX: 923f82a4 HEX: ab1c5ed5
  28         HEX: d807aa98 HEX: 12835b01 HEX: 243185be HEX: 550c7dc3
  29         HEX: 72be5d74 HEX: 80deb1fe HEX: 9bdc06a7 HEX: c19bf174
  30         HEX: e49b69c1 HEX: efbe4786 HEX: 0fc19dc6 HEX: 240ca1cc
  31         HEX: 2de92c6f HEX: 4a7484aa HEX: 5cb0a9dc HEX: 76f988da
  32         HEX: 983e5152 HEX: a831c66d HEX: b00327c8 HEX: bf597fc7
  33         HEX: c6e00bf3 HEX: d5a79147 HEX: 06ca6351 HEX: 14292967
  34         HEX: 27b70a85 HEX: 2e1b2138 HEX: 4d2c6dfc HEX: 53380d13
  35         HEX: 650a7354 HEX: 766a0abb HEX: 81c2c92e HEX: 92722c85
  36         HEX: a2bfe8a1 HEX: a81a664b HEX: c24b8b70 HEX: c76c51a3
  37         HEX: d192e819 HEX: d6990624 HEX: f40e3585 HEX: 106aa070
  38         HEX: 19a4c116 HEX: 1e376c08 HEX: 2748774c HEX: 34b0bcb5
  39         HEX: 391c0cb3 HEX: 4ed8aa4a HEX: 5b9cca4f HEX: 682e6ff3
  40         HEX: 748f82ee HEX: 78a5636f HEX: 84c87814 HEX: 8cc70208
  41         HEX: 90befffa HEX: a4506ceb HEX: bef9a3f7 HEX: c67178f2
  42     } ;
  43
  44 : s0-256 ( x -- x' )
  45     [ -7 bitroll-32 ] keep
  46     [ -18 bitroll-32 ] keep
  47     -3 shift bitxor bitxor ; inline
  48
  49 : s1-256 ( x -- x' )
  50     [ -17 bitroll-32 ] keep
  51     [ -19 bitroll-32 ] keep
  52     -10 shift bitxor bitxor ; inline
  53
  54 : process-M-256 ( seq n -- )
  55     [ 16 - swap nth ] 2keep
  56     [ 15 - swap nth s0-256 ] 2keep
  57     [ 7 - swap nth ] 2keep
  58     [ 2 - swap nth s1-256 ] 2keep
  59     >r >r + + w+ r> r> swap set-nth ; inline
  60
  61 : prepare-message-schedule ( seq -- w-seq )
  62     word-size get group [ be> ] map block-size get 0 pad-right
  63     dup 16 64 dup <slice> [
  64         process-M-256
  65     ] with each ;
  66
  67 : ch ( x y z -- x' )
  68     [ bitxor bitand ] keep bitxor ;
  69
  70 : maj ( x y z -- x' )
  71     >r [ bitand ] 2keep bitor r> bitand bitor ;
  72
  73 : S0-256 ( x -- x' )
  74     [ -2 bitroll-32 ] keep
  75     [ -13 bitroll-32 ] keep
  76     -22 bitroll-32 bitxor bitxor ; inline
  77
  78 : S1-256 ( x -- x' )
  79     [ -6 bitroll-32 ] keep
  80     [ -11 bitroll-32 ] keep
  81     -25 bitroll-32 bitxor bitxor ; inline
  82
  83 : T1 ( W n -- T1 )
  84     [ swap nth ] keep
  85     K get nth +
  86     e vars get slice3 ch +
  87     e vars get nth S1-256 +
  88     h vars get nth w+ ;
  89
  90 : T2 ( -- T2 )
  91     a vars get nth S0-256
  92     a vars get slice3 maj w+ ;
  93
  94 : update-vars ( T1 T2 -- )
  95     vars get
  96     h g pick exchange
  97     g f pick exchange
  98     f e pick exchange
  99     pick d pick nth w+ e pick set-nth
 100     d c pick exchange
 101     c b pick exchange
 102     b a pick exchange
 103     >r w+ a r> set-nth ;
 104
 105 : process-chunk ( M -- )
 106     H get clone vars set
 107     prepare-message-schedule block-size get [
 108         T1 T2 update-vars
 109     ] with each vars get H get [ w+ ] 2map H set ;
 110
 111 : seq>byte-array ( n seq -- string )
 112     [ swap [ >be % ] curry each ] B{ } make ;
 113
 114 : byte-array>sha2 ( byte-array -- string )
 115     t preprocess-plaintext
 116     block-size get group [ process-chunk ] each
 117     4 H get seq>byte-array ;
 118
 119 PRIVATE>
 120
 121 SINGLETON: sha-256
 122
 123 INSTANCE: sha-256 checksum
 124
 125 M: sha-256 checksum-bytes
 126     drop [
 127         K-256 K set
 128         initial-H-256 H set
 129         4 word-size set
 130         64 block-size set
 131         byte-array>sha2
 132     ] with-scope ;