extra/compiler/cfg/gvn/alien/alien.factor

   1 ! Copyright (C) 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors combinators combinators.short-circuit fry
   4 kernel make math sequences
   5 cpu.architecture
   6 compiler.cfg.hats
   7 compiler.cfg.utilities
   8 compiler.cfg.registers
   9 compiler.cfg.instructions
  10 compiler.cfg.gvn.math
  11 compiler.cfg.gvn.graph
  12 compiler.cfg.gvn.rewrite ;
  13 IN: compiler.cfg.gvn.alien
  14
  15 M: ##box-displaced-alien rewrite
  16     dup displacement>> vreg>insn zero-insn?
  17     [ [ dst>> ] [ base>> ] bi <copy> ] [ drop f ] if ;
  18
  19 ! ##box-displaced-alien f 1 2 3 <class>
  20 ! ##unbox-c-ptr 4 1 <class>
  21 ! =>
  22 ! ##box-displaced-alien f 1 2 3 <class>
  23 ! ##unbox-c-ptr 5 3 <class>
  24 ! ##add 4 5 2
  25
  26 : rewrite-unbox-alien ( insn box-insn -- insn )
  27     [ dst>> ] [ src>> ] bi* <copy> ;
  28
  29 : rewrite-unbox-displaced-alien ( insn box-insn -- insns )
  30     [
  31         [ dst>> ]
  32         [ [ base>> ] [ base-class>> ] [ displacement>> ] tri ] bi*
  33         [ ^^unbox-c-ptr ] dip
  34         ##add
  35     ] { } make ;
  36
  37 : rewrite-unbox-any-c-ptr ( insn -- insn/f )
  38     dup src>> vreg>insn
  39     {
  40         { [ dup ##box-alien? ] [ rewrite-unbox-alien ] }
  41         { [ dup ##box-displaced-alien? ] [ rewrite-unbox-displaced-alien ] }
  42         [ 2drop f ]
  43     } cond ;
  44
  45 M: ##unbox-any-c-ptr rewrite rewrite-unbox-any-c-ptr ;
  46
  47 M: ##unbox-alien rewrite rewrite-unbox-any-c-ptr ;
  48
  49 ! Fuse ##add-imm into ##load-memory(-imm) and ##store-memory(-imm)
  50 ! just update the offset in the instruction
  51 : fuse-base-offset? ( insn -- ? )
  52     base>> vreg>insn ##add-imm? ;
  53
  54 : fuse-base-offset ( insn -- insn' )
  55     dup base>> vreg>insn
  56     [ src1>> ] [ src2>> ] bi
  57     [ >>base ] [ '[ _ + ] change-offset ] bi* ;
  58
  59 ! Fuse ##add-imm into ##load-memory and ##store-memory
  60 ! just update the offset in the instruction
  61 : fuse-displacement-offset? ( insn -- ? )
  62     { [ scale>> 0 = ] [ displacement>> vreg>insn ##add-imm? ] } 1&& ;
  63
  64 : fuse-displacement-offset ( insn -- insn' )
  65     dup displacement>> vreg>insn
  66     [ src1>> ] [ src2>> ] bi
  67     [ >>displacement ] [ '[ _ + ] change-offset ] bi* ;
  68
  69 ! Fuse ##add into ##load-memory-imm and ##store-memory-imm
  70 ! construct a new ##load-memory or ##store-memory with the
  71 ! ##add's operand as the displacement
  72 : fuse-displacement? ( insn -- ? )
  73     {
  74         [ offset>> 0 = complex-addressing? or ]
  75         [ base>> vreg>insn ##add? ]
  76     } 1&& ;
  77
  78 GENERIC: alien-insn-value ( insn -- value )
  79
  80 M: ##load-memory-imm alien-insn-value dst>> ;
  81 M: ##store-memory-imm alien-insn-value src>> ;
  82
  83 GENERIC: new-alien-insn ( value base displacement scale offset rep c-type insn -- insn )
  84
  85 M: ##load-memory-imm new-alien-insn drop \ ##load-memory new-insn ;
  86 M: ##store-memory-imm new-alien-insn drop \ ##store-memory new-insn ;
  87
  88 : fuse-displacement ( insn -- insn' )
  89     {
  90         [ alien-insn-value ]
  91         [ base>> vreg>insn [ src1>> ] [ src2>> ] bi ]
  92         [ drop 0 ]
  93         [ offset>> ]
  94         [ rep>> ]
  95         [ c-type>> ]
  96         [ ]
  97     } cleave new-alien-insn ;
  98
  99 ! Fuse ##shl-imm into ##load-memory or ##store-memory
 100 : scale-insn? ( insn -- ? )
 101     { [ ##shl-imm? ] [ src2>> { 1 2 3 } member? ] } 1&& ;
 102
 103 : fuse-scale? ( insn -- ? )
 104     { [ scale>> 0 = ] [ displacement>> vreg>insn scale-insn? ] } 1&& ;
 105
 106 : fuse-scale ( insn -- insn' )
 107     dup displacement>> vreg>insn
 108     [ src1>> ] [ src2>> ] bi
 109     [ >>displacement ] [ >>scale ] bi* ;
 110
 111 : rewrite-memory-op ( insn -- insn/f )
 112     complex-addressing? [
 113         {
 114             { [ dup fuse-base-offset? ] [ fuse-base-offset ] }
 115             { [ dup fuse-displacement-offset? ] [ fuse-displacement-offset ] }
 116             { [ dup fuse-scale? ] [ fuse-scale ] }
 117             [ drop f ]
 118         } cond
 119     ] [ drop f ] if ;
 120
 121 : rewrite-memory-imm-op ( insn -- insn/f )
 122     {
 123         { [ dup fuse-base-offset? ] [ fuse-base-offset ] }
 124         { [ dup fuse-displacement? ] [ fuse-displacement ] }
 125         [ drop f ]
 126     } cond ;
 127
 128 M: ##load-memory rewrite rewrite-memory-op ;
 129 M: ##load-memory-imm rewrite rewrite-memory-imm-op ;
 130 M: ##store-memory rewrite rewrite-memory-op ;
 131 M: ##store-memory-imm rewrite rewrite-memory-imm-op ;