extra/compiler/cfg/gvn/alien/alien.factor

   1 ! Copyright (C) 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors combinators combinators.short-circuit fry
   4 kernel make math sequences
   5 cpu.architecture
   6 compiler.cfg.hats
   7 compiler.cfg.utilities
   8 compiler.cfg.registers
   9 compiler.cfg.instructions
  10 compiler.cfg.gvn.math
  11 compiler.cfg.gvn.graph
  12 compiler.cfg.gvn.avail
  13 compiler.cfg.gvn.rewrite ;
  14 IN: compiler.cfg.gvn.alien
  15
  16 M: ##box-displaced-alien rewrite
  17     dup displacement>> vreg>insn zero-insn?
  18     [ [ dst>> ] [ base>> ] bi <copy> ] [ drop f ] if ;
  19
  20 ! ##box-displaced-alien f 1 2 3 <class>
  21 ! ##unbox-c-ptr 4 1 <class>
  22 ! =>
  23 ! ##box-displaced-alien f 1 2 3 <class>
  24 ! ##unbox-c-ptr 5 3 <class>
  25 ! ##add 4 5 2
  26
  27 : rewrite-unbox-alien ( insn box-insn -- insn )
  28     [ dst>> ] [ src>> ] bi* <copy> ;
  29
  30 : rewrite-unbox-displaced-alien ( insn box-insn -- insns )
  31     [
  32         [ dst>> ]
  33         [ [ base>> ] [ base-class>> ] [ displacement>> ] tri ] bi*
  34         [ ^^unbox-c-ptr ] dip
  35         ##add
  36     ] { } make ;
  37
  38 : rewrite-unbox-any-c-ptr ( insn -- insn/f )
  39     dup src>> vreg>insn
  40     {
  41         {
  42             [ dup [ ##box-alien? ] with-available-uses? ]
  43             [ rewrite-unbox-alien ]
  44         }
  45         {
  46             [ dup [ ##box-displaced-alien? ] with-available-uses? ]
  47             [ rewrite-unbox-displaced-alien ]
  48         }
  49         [ 2drop f ]
  50     } cond ;
  51
  52 M: ##unbox-any-c-ptr rewrite rewrite-unbox-any-c-ptr ;
  53
  54 M: ##unbox-alien rewrite rewrite-unbox-any-c-ptr ;
  55
  56 ! Fuse ##add-imm into ##load-memory(-imm) and ##store-memory(-imm)
  57 ! just update the offset in the instruction
  58 : fuse-base-offset? ( insn -- ? )
  59     base>> vreg>insn [ ##add-imm? ] with-available-uses? ;
  60
  61 : fuse-base-offset ( insn -- insn' )
  62     clone dup base>> vreg>insn
  63     [ src1>> ] [ src2>> ] bi
  64     [ >>base ] [ '[ _ + ] change-offset ] bi* ;
  65
  66 ! Fuse ##add-imm into ##load-memory and ##store-memory
  67 ! just update the offset in the instruction
  68 : fuse-displacement-offset? ( insn -- ? )
  69     {
  70         [ scale>> 0 = ]
  71         [ displacement>> vreg>insn [ ##add-imm? ] with-available-uses? ]
  72     } 1&& ;
  73
  74 : fuse-displacement-offset ( insn -- insn' )
  75     clone dup displacement>> vreg>insn
  76     [ src1>> ] [ src2>> ] bi
  77     [ >>displacement ] [ '[ _ + ] change-offset ] bi* ;
  78
  79 ! Fuse ##add into ##load-memory-imm and ##store-memory-imm
  80 ! construct a new ##load-memory or ##store-memory with the
  81 ! ##add's operand as the displacement
  82 : fuse-displacement? ( insn -- ? )
  83     {
  84         [ offset>> 0 = complex-addressing? or ]
  85         [ base>> vreg>insn [ ##add? ] with-available-uses? ]
  86     } 1&& ;
  87
  88 GENERIC: alien-insn-value ( insn -- value )
  89
  90 M: ##load-memory-imm alien-insn-value dst>> ;
  91 M: ##store-memory-imm alien-insn-value src>> ;
  92
  93 GENERIC: new-alien-insn ( value base displacement scale offset rep c-type insn -- insn )
  94
  95 M: ##load-memory-imm new-alien-insn drop \ ##load-memory new-insn ;
  96 M: ##store-memory-imm new-alien-insn drop \ ##store-memory new-insn ;
  97
  98 : fuse-displacement ( insn -- insn' )
  99     {
 100         [ alien-insn-value ]
 101         [ base>> vreg>insn [ src1>> ] [ src2>> ] bi ]
 102         [ drop 0 ]
 103         [ offset>> ]
 104         [ rep>> ]
 105         [ c-type>> ]
 106         [ ]
 107     } cleave new-alien-insn ;
 108
 109 ! Fuse ##shl-imm into ##load-memory or ##store-memory
 110 : scale-insn? ( insn -- ? )
 111     { [ ##shl-imm? ] [ src2>> { 1 2 3 } member? ] } 1&& ;
 112
 113 : fuse-scale? ( insn -- ? )
 114     {
 115         [ scale>> 0 = ]
 116         [ displacement>> vreg>insn [ scale-insn? ] with-available-uses? ]
 117     } 1&& ;
 118
 119 : fuse-scale ( insn -- insn' )
 120     clone dup displacement>> vreg>insn
 121     [ src1>> ] [ src2>> ] bi
 122     [ >>displacement ] [ >>scale ] bi* ;
 123
 124 : rewrite-memory-op ( insn -- insn/f )
 125     complex-addressing? [
 126         {
 127             { [ dup fuse-base-offset? ] [ fuse-base-offset ] }
 128             { [ dup fuse-displacement-offset? ] [ fuse-displacement-offset ] }
 129             { [ dup fuse-scale? ] [ fuse-scale ] }
 130             [ drop f ]
 131         } cond
 132     ] [ drop f ] if ;
 133
 134 : rewrite-memory-imm-op ( insn -- insn/f )
 135     {
 136         { [ dup fuse-base-offset? ] [ fuse-base-offset ] }
 137         { [ dup fuse-displacement? ] [ fuse-displacement ] }
 138         [ drop f ]
 139     } cond ;
 140
 141 M: ##load-memory rewrite rewrite-memory-op ;
 142 M: ##load-memory-imm rewrite rewrite-memory-imm-op ;
 143 M: ##store-memory rewrite rewrite-memory-op ;
 144 M: ##store-memory-imm rewrite rewrite-memory-imm-op ;