extra/compiler/cfg/gvn/alien/alien.factor

   1 ! Copyright (C) 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors combinators combinators.short-circuit fry
   4 kernel make math sequences
   5 cpu.architecture
   6 compiler.cfg.hats
   7 compiler.cfg.utilities
   8 compiler.cfg.registers
   9 compiler.cfg.instructions
  10 compiler.cfg.gvn.math
  11 compiler.cfg.gvn.graph
  12 compiler.cfg.gvn.avail
  13 compiler.cfg.gvn.rewrite ;
  14 IN: compiler.cfg.gvn.alien
  15
  16 M: ##box-displaced-alien rewrite
  17     dup displacement>> vreg>insn zero-insn?
  18     [ [ dst>> ] [ base>> ] bi <copy> ] [ drop f ] if ;
  19
  20 ! ##box-displaced-alien f 1 2 3 <class>
  21 ! ##unbox-c-ptr 4 1 <class>
  22 ! =>
  23 ! ##box-displaced-alien f 1 2 3 <class>
  24 ! ##unbox-c-ptr 5 3 <class>
  25 ! ##add 4 5 2
  26
  27 : rewrite-unbox-alien ( insn box-insn -- insn )
  28     [ dst>> ] [ src>> ] bi* <copy> ;
  29
  30 ! XXX  next-vreg makes vregs>vns change on every iteration
  31 ! (hidden in ^^unbox-c-ptr)
  32 : rewrite-unbox-displaced-alien ( insn box-insn -- insns )
  33     [
  34         [ dst>> ]
  35         [ [ base>> ] [ base-class>> ] [ displacement>> ] tri ] bi*
  36         [ ^^unbox-c-ptr ] dip
  37         ##add
  38     ] { } make ;
  39
  40 : rewrite-unbox-any-c-ptr ( insn -- insn/f )
  41     dup src>> vreg>insn
  42     {
  43         {
  44             [ dup [ ##box-alien? ] with-available-uses? ]
  45             [ rewrite-unbox-alien ]
  46         }
  47         {
  48             ! [ dup [ ##box-displaced-alien? ] with-available-uses? ]
  49             [ f ]
  50             [ rewrite-unbox-displaced-alien ]
  51         }
  52         [ 2drop f ]
  53     } cond ;
  54
  55 M: ##unbox-any-c-ptr rewrite rewrite-unbox-any-c-ptr ;
  56
  57 M: ##unbox-alien rewrite rewrite-unbox-any-c-ptr ;
  58
  59 ! Fuse ##add-imm into ##load-memory(-imm) and ##store-memory(-imm)
  60 ! just update the offset in the instruction
  61 : fuse-base-offset? ( insn -- ? )
  62     base>> vreg>insn [ ##add-imm? ] with-available-uses? ;
  63
  64 : fuse-base-offset ( insn -- insn' )
  65     clone dup base>> vreg>insn
  66     [ src1>> ] [ src2>> ] bi
  67     [ >>base ] [ '[ _ + ] change-offset ] bi* ;
  68
  69 ! Fuse ##add-imm into ##load-memory and ##store-memory
  70 ! just update the offset in the instruction
  71 : fuse-displacement-offset? ( insn -- ? )
  72     {
  73         [ scale>> 0 = ]
  74         [ displacement>> vreg>insn [ ##add-imm? ] with-available-uses? ]
  75     } 1&& ;
  76
  77 : fuse-displacement-offset ( insn -- insn' )
  78     clone dup displacement>> vreg>insn
  79     [ src1>> ] [ src2>> ] bi
  80     [ >>displacement ] [ '[ _ + ] change-offset ] bi* ;
  81
  82 ! Fuse ##add into ##load-memory-imm and ##store-memory-imm
  83 ! construct a new ##load-memory or ##store-memory with the
  84 ! ##add's operand as the displacement
  85 : fuse-displacement? ( insn -- ? )
  86     {
  87         [ offset>> 0 = complex-addressing? or ]
  88         [ base>> vreg>insn [ ##add? ] with-available-uses? ]
  89     } 1&& ;
  90
  91 GENERIC: alien-insn-value ( insn -- value )
  92
  93 M: ##load-memory-imm alien-insn-value dst>> ;
  94 M: ##store-memory-imm alien-insn-value src>> ;
  95
  96 GENERIC: new-alien-insn ( value base displacement scale offset rep c-type insn -- insn )
  97
  98 M: ##load-memory-imm new-alien-insn drop \ ##load-memory new-insn ;
  99 M: ##store-memory-imm new-alien-insn drop \ ##store-memory new-insn ;
 100
 101 : fuse-displacement ( insn -- insn' )
 102     {
 103         [ alien-insn-value ]
 104         [ base>> vreg>insn [ src1>> ] [ src2>> ] bi ]
 105         [ drop 0 ]
 106         [ offset>> ]
 107         [ rep>> ]
 108         [ c-type>> ]
 109         [ ]
 110     } cleave new-alien-insn ;
 111
 112 ! Fuse ##shl-imm into ##load-memory or ##store-memory
 113 : scale-insn? ( insn -- ? )
 114     { [ ##shl-imm? ] [ src2>> { 1 2 3 } member? ] } 1&& ;
 115
 116 : fuse-scale? ( insn -- ? )
 117     {
 118         [ scale>> 0 = ]
 119         [ displacement>> vreg>insn [ scale-insn? ] with-available-uses? ]
 120     } 1&& ;
 121
 122 : fuse-scale ( insn -- insn' )
 123     clone dup displacement>> vreg>insn
 124     [ src1>> ] [ src2>> ] bi
 125     [ >>displacement ] [ >>scale ] bi* ;
 126
 127 : rewrite-memory-op ( insn -- insn/f )
 128     complex-addressing? [
 129         {
 130             { [ dup fuse-base-offset? ] [ fuse-base-offset ] }
 131             { [ dup fuse-displacement-offset? ] [ fuse-displacement-offset ] }
 132             { [ dup fuse-scale? ] [ fuse-scale ] }
 133             [ drop f ]
 134         } cond
 135     ] [ drop f ] if ;
 136
 137 : rewrite-memory-imm-op ( insn -- insn/f )
 138     {
 139         { [ dup fuse-base-offset? ] [ fuse-base-offset ] }
 140         { [ dup fuse-displacement? ] [ fuse-displacement ] }
 141         [ drop f ]
 142     } cond ;
 143
 144 M: ##load-memory rewrite rewrite-memory-op ;
 145 M: ##load-memory-imm rewrite rewrite-memory-imm-op ;
 146 M: ##store-memory rewrite rewrite-memory-op ;
 147 M: ##store-memory-imm rewrite rewrite-memory-imm-op ;