extra/compiler/cfg/gvn/gvn.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces arrays assocs hashtables kernel accessors fry
   4 grouping sorting sets sequences locals
   5 cpu.architecture
   6 sequences.deep
   7 compiler.cfg
   8 compiler.cfg.rpo
   9 compiler.cfg.def-use
  10 compiler.cfg.utilities
  11 compiler.cfg.instructions
  12 compiler.cfg.predecessors
  13 compiler.cfg.gvn.alien
  14 compiler.cfg.gvn.avail
  15 compiler.cfg.gvn.comparisons
  16 compiler.cfg.gvn.graph
  17 compiler.cfg.gvn.math
  18 compiler.cfg.gvn.rewrite
  19 compiler.cfg.gvn.slots
  20 compiler.cfg.gvn.misc
  21 compiler.cfg.gvn.expressions ;
  22 IN: compiler.cfg.gvn
  23
  24 GENERIC: simplify ( insn -- insn' )
  25
  26 M: insn simplify dup rewrite [ simplify ] [ ] ?if ;
  27 M: array simplify [ simplify ] map ;
  28 M: ##copy simplify ;
  29
  30 ! ! ! Global value numbering
  31
  32 GENERIC: value-number ( insn -- )
  33
  34 M: array value-number [ value-number ] each ;
  35
  36 M: alien-call-insn value-number drop ;
  37 M: ##callback-inputs value-number drop ;
  38
  39 M: ##copy value-number [ src>> vreg>vn ] [ dst>> ] bi set-vn ;
  40
  41 : redundant-instruction ( insn vn -- )
  42     swap dst>> set-vn ;
  43
  44 :: useful-instruction ( insn expr -- )
  45     insn dst>> :> vn
  46     vn vn set-vn
  47     vn expr exprs>vns get set-at
  48     insn vn vns>insns get set-at ;
  49
  50 : check-redundancy ( insn -- )
  51     dup >expr dup exprs>vns get at
  52     [ redundant-instruction ] [ useful-instruction ] ?if ;
  53
  54 M: ##phi value-number
  55     dup inputs>> values [ vreg>vn ] map sift
  56     dup all-equal? [
  57         [ drop ] [ first redundant-instruction ] if-empty
  58     ] [ drop check-redundancy ] if ;
  59
  60 M: insn value-number
  61     dup defs-vregs length 1 = [ check-redundancy ] [ drop ] if ;
  62
  63 : value-numbering-step ( insns -- )
  64     [ simplify value-number ] each ;
  65
  66 : value-numbering-iteration ( cfg -- )
  67     clear-exprs [ value-numbering-step ] simple-analysis ;
  68
  69 : determine-value-numbers ( cfg -- )
  70     final-iteration? off
  71     init-value-graph
  72     '[
  73         changed? off
  74         _ value-numbering-iteration
  75         changed? get
  76     ] loop ;
  77
  78 ! ! ! Global common subexpression elimination
  79
  80 GENERIC: gcse ( insn -- insn' )
  81
  82 M: array gcse [ gcse ] map ;
  83
  84 M: alien-call-insn gcse ;
  85 M: ##callback-inputs gcse ;
  86 M: ##copy gcse ;
  87
  88 : ?eliminate ( insn vn -- insn' )
  89     dup available? [
  90         [ dst>> ] dip <copy>
  91     ] [ drop make-available ] if ;
  92
  93 : eliminate-redundancy ( insn -- insn' )
  94     dup >expr exprs>vns get at
  95     [ ?eliminate ] [ make-available ] if* ;
  96
  97 M: ##phi gcse
  98     dup inputs>> values [ vreg>vn ] map sift
  99     dup all-equal? [
 100         [ first ?eliminate ] unless-empty
 101     ] [ drop eliminate-redundancy ] if ;
 102
 103 M: insn gcse
 104     dup defs-vregs length 1 = [ eliminate-redundancy ] when ;
 105
 106 : gcse-step ( insns -- insns' )
 107     [ simplify gcse ] map flatten ;
 108
 109 : eliminate-common-subexpressions ( cfg -- )
 110     final-iteration? on
 111     dup compute-avail-sets
 112     [ gcse-step ] simple-optimization ;
 113
 114 : value-numbering ( cfg -- cfg )
 115     needs-predecessors
 116     dup determine-value-numbers
 117     dup eliminate-common-subexpressions
 118
 119     cfg-changed predecessors-changed ;