extra/compiler/cfg/gvn/gvn.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces arrays assocs kernel accessors fry grouping
   4 sorting sets sequences locals
   5 cpu.architecture
   6 sequences.deep
   7 compiler.cfg
   8 compiler.cfg.rpo
   9 compiler.cfg.def-use
  10 compiler.cfg.utilities
  11 compiler.cfg.instructions
  12 compiler.cfg.gvn.alien
  13 compiler.cfg.gvn.comparisons
  14 compiler.cfg.gvn.graph
  15 compiler.cfg.gvn.math
  16 compiler.cfg.gvn.rewrite
  17 compiler.cfg.gvn.slots
  18 compiler.cfg.gvn.misc
  19 compiler.cfg.gvn.expressions ;
  20 IN: compiler.cfg.gvn
  21
  22 GENERIC: process-instruction ( insn -- insn' )
  23
  24 : redundant-instruction ( insn vn -- insn' )
  25     [ dst>> ] dip [ swap set-vn ] [ <copy> ] 2bi ;
  26
  27 :: useful-instruction ( insn expr -- insn' )
  28     insn dst>> :> vn
  29     vn vn set-vn
  30     vn expr exprs>vns get set-at
  31     insn vn vns>insns get set-at
  32     insn ;
  33
  34 : check-redundancy ( insn -- insn' )
  35     dup >expr dup exprs>vns get at
  36     [ redundant-instruction ] [ useful-instruction ] ?if ;
  37
  38 M: insn process-instruction
  39     dup rewrite [ process-instruction ] [ ] ?if ;
  40
  41 M: foldable-insn process-instruction
  42     dup rewrite
  43     [ process-instruction ]
  44     [ dup defs-vregs length 1 = [ check-redundancy ] when ] ?if ;
  45
  46 M: ##copy process-instruction
  47     dup [ src>> vreg>vn ] [ dst>> ] bi set-vn ;
  48
  49 M: ##phi process-instruction
  50     dup rewrite
  51     [ process-instruction ] [ check-redundancy ] ?if ;
  52
  53 M: array process-instruction
  54     [ process-instruction ] map ;
  55
  56 : value-numbering-step ( insns -- insns' )
  57     [ process-instruction ] map flatten ;
  58
  59 ! XXX there's going to be trouble with certain rewrites that
  60 ! modify the cfg / instructions destructively; namely those in
  61 ! comparisons.factor, alien.factor, and slots.factor
  62
  63 : value-numbering-iteration ( cfg -- )
  64     clear-exprs
  65     [ value-numbering-step drop ] simple-analysis ;
  66
  67 : identify-redundancies ( cfg -- )
  68     init-value-graph
  69     '[
  70         changed? off
  71         _ value-numbering-iteration
  72         changed? get
  73     ] loop ;
  74
  75 : eliminate-redundancies ( cfg -- )
  76     clear-exprs
  77     [ value-numbering-step ] simple-optimization ;
  78
  79 : value-numbering ( cfg -- cfg )
  80     dup identify-redundancies
  81     dup eliminate-redundancies
  82     cfg-changed predecessors-changed ;