extra/compiler/cfg/gvn/gvn.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces arrays assocs hashtables kernel accessors fry
   4 grouping sorting sets sequences locals
   5 cpu.architecture
   6 sequences.deep
   7 compiler.cfg
   8 compiler.cfg.rpo
   9 compiler.cfg.def-use
  10 compiler.cfg.utilities
  11 compiler.cfg.instructions
  12 compiler.cfg.predecessors
  13 compiler.cfg.gvn.alien
  14 compiler.cfg.gvn.avail
  15 compiler.cfg.gvn.comparisons
  16 compiler.cfg.gvn.graph
  17 compiler.cfg.gvn.math
  18 compiler.cfg.gvn.rewrite
  19 compiler.cfg.gvn.slots
  20 compiler.cfg.gvn.misc
  21 compiler.cfg.gvn.expressions ;
  22 IN: compiler.cfg.gvn
  23
  24 GENERIC: simplify ( insn -- insn' )
  25
  26 M: insn simplify dup rewrite [ simplify ] [ ] ?if ;
  27 M: array simplify [ simplify ] map ;
  28 M: ##copy simplify ;
  29
  30 GENERIC: value-number ( insn -- )
  31
  32 M: array value-number [ value-number ] each ;
  33
  34 M: alien-call-insn value-number drop ;
  35 M: ##callback-inputs value-number drop ;
  36
  37 M: ##copy value-number [ src>> vreg>vn ] [ dst>> ] bi set-vn ;
  38
  39 : redundant-instruction ( insn vn -- )
  40     swap dst>> set-vn ;
  41
  42 :: useful-instruction ( insn expr -- )
  43     insn dst>> :> vn
  44     vn vn set-vn
  45     vn expr exprs>vns get set-at
  46     insn vn vns>insns get set-at ;
  47
  48 : check-redundancy ( insn -- )
  49     dup >expr dup exprs>vns get at
  50     [ redundant-instruction ] [ useful-instruction ] ?if ;
  51
  52 M: ##phi value-number
  53     dup inputs>> values [ vreg>vn ] map sift
  54     dup all-equal? [
  55         [ drop ] [ first redundant-instruction ] if-empty
  56     ] [ drop check-redundancy ] if ;
  57
  58 M: insn value-number
  59     dup defs-vregs length 1 = [ check-redundancy ] [ drop ] if ;
  60
  61 : value-numbering-step ( insns -- )
  62     [ simplify value-number ] each ;
  63
  64 : value-numbering-iteration ( cfg -- )
  65     clear-exprs [ value-numbering-step ] simple-analysis ;
  66
  67 : determine-value-numbers ( cfg -- )
  68     final-iteration? off
  69     init-value-graph
  70     '[
  71         changed? off
  72         _ value-numbering-iteration
  73         changed? get
  74     ] loop ;
  75
  76 : value-numbering ( cfg -- cfg )
  77     needs-predecessors
  78     dup determine-value-numbers
  79
  80     cfg-changed predecessors-changed ;