extra/crontab/crontab.factor

   1 ! Copyright (C) 2018 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors arrays ascii assocs calendar calendar.english
   5 calendar.private combinators io kernel literals locals math
   6 math.order math.parser math.ranges sequences splitting ;
   7
   8 IN: crontab
   9
  10 :: parse-value ( value quot: ( value -- value' ) seq -- value )
  11     value {
  12         { [ CHAR: , over member? ] [
  13             "," split [ quot seq parse-value ] map concat ] }
  14         { [ dup "*" = ] [ drop seq ] }
  15         { [ CHAR: / over member? ] [
  16             "/" split1 [ quot seq parse-value 0 over length 1 - ] dip
  17             string>number <range> swap nths ] }
  18         { [ CHAR: - over member? ] [
  19             "-" split1 quot bi@ [a,b] ] }
  20         [ quot call 1array ]
  21     } cond ; inline recursive
  22
  23 : parse-day ( str -- n )
  24     dup string>number [ ] [
  25         >lower $[ day-abbreviations3 [ >lower ] map ] index
  26     ] ?if ;
  27
  28 : parse-month ( str -- n )
  29     dup string>number [ ] [
  30         >lower $[ month-abbreviations [ >lower ] map ] index
  31     ] ?if ;
  32
  33 TUPLE: cronentry minutes hours days months days-of-week command ;
  34
  35 CONSTANT: aliases H{
  36     { "@yearly"   "0 0 1 1 *" }
  37     { "@annually" "0 0 1 1 *" }
  38     { "@monthly"  "0 0 1 * *" }
  39     { "@weekly"   "0 0 * * 0" }
  40     { "@daily"    "0 0 * * *" }
  41     { "@midnight" "0 0 * * *" }
  42     { "@hourly"   "0 * * * *" }
  43 }
  44
  45 : parse-cronentry ( entry -- cronentry )
  46     " " split1 [ aliases ?at drop ] dip " " glue
  47     " " split1 " " split1 " " split1 " " split1 " " split1 {
  48         [ [ string>number ] T{ range f 0 60 1 } parse-value ]
  49         [ [ string>number ] T{ range f 0 24 1 } parse-value ]
  50         [ [ string>number ] T{ range f 0 31 1 } parse-value ]
  51         [ [ parse-month ] T{ range f 0 12 1 } parse-value ]
  52         [ [ parse-day ] T{ range f 0 7 1 } parse-value ]
  53         [ ]
  54     } spread cronentry boa ;
  55
  56 :: next-time-after ( cronentry timestamp -- )
  57
  58     timestamp second>> 0 > [
  59         timestamp 0 >>second 1 minutes (time+) 2drop
  60     ] when
  61
  62     timestamp month>> :> month
  63     cronentry months>> [ month >= ] find nip [
  64         dup month = [ drop f ] [ timestamp month<< t ] if
  65     ] [
  66         timestamp cronentry months>> first >>month 1 +year
  67     ] if* [ cronentry timestamp next-time-after ] when
  68
  69     timestamp hour>> :> hour
  70     cronentry hours>> [ hour >= ] find nip [
  71         dup hour = [ drop f ] [
  72             timestamp hour<< 0 timestamp minute<< t
  73         ] if
  74     ] [
  75         timestamp cronentry hours>> first >>hour 1 +day
  76     ] if* [ cronentry timestamp next-time-after ] when
  77
  78     timestamp minute>> :> minute
  79     cronentry minutes>> [ minute >= ] find nip [
  80         dup minute = [ drop f ] [ timestamp minute<< t ] if
  81     ] [
  82         timestamp cronentry minutes>> first >>minute 1 +hour
  83     ] if* [ cronentry timestamp next-time-after ] when
  84
  85     timestamp day-of-week :> weekday
  86     cronentry days-of-week>> [ weekday >= ] find nip [
  87         cronentry days-of-week>> first 7 +
  88     ] unless* weekday -
  89
  90     timestamp day>> :> day
  91     cronentry days>> [ day >= ] find nip [
  92         day -
  93     ] [
  94         timestamp 1 months time+
  95         cronentry days>> first >>day
  96         day-of-year timestamp day-of-year -
  97     ] if*
  98
  99     min [
 100         timestamp swap +day drop
 101         cronentry timestamp next-time-after
 102     ] unless-zero ;
 103
 104 : next-time ( cronentry -- timestamp )
 105     now [ next-time-after ] keep ;
 106
 107 : parse-crontab ( -- entries )
 108     lines harvest [ parse-cronentry ] map ;