extra/cuda/devices/devices.factor

   1 ! Copyright (C) 2010 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types alien.data alien.strings arrays assocs
   4 byte-arrays classes.struct combinators cuda cuda.ffi cuda.utils
   5 fry io io.encodings.utf8 kernel math.parser prettyprint
   6 sequences ;
   7 IN: cuda.devices
   8
   9 : #cuda-devices ( -- n )
  10     init-cuda
  11     int <c-object> [ cuDeviceGetCount cuda-error ] keep *int ;
  12
  13 : n>cuda-device ( n -- device )
  14     init-cuda
  15     [ CUdevice <c-object> ] dip [ cuDeviceGet cuda-error ] 2keep drop *int ;
  16
  17 : enumerate-cuda-devices ( -- devices )
  18     #cuda-devices iota [ n>cuda-device ] map ;
  19
  20 : with-each-cuda-device ( quot -- )
  21     [ enumerate-cuda-devices ] dip '[ <launcher> _ with-cuda ] each ; inline
  22
  23 : cuda-device-properties ( device -- properties )
  24     [ CUdevprop <c-object> ] dip
  25     [ cuDeviceGetProperties cuda-error ] 2keep drop
  26     CUdevprop memory>struct ;
  27
  28 : cuda-devices ( -- assoc )
  29     enumerate-cuda-devices [ dup cuda-device-properties ] { } map>assoc ;
  30
  31 : cuda-device-name ( n -- string )
  32     init-cuda
  33     [ 256 [ <byte-array> ] keep ] dip
  34     [ cuDeviceGetName cuda-error ]
  35     [ 2drop utf8 alien>string ] 3bi ;
  36
  37 : cuda-device-capability ( n -- pair )
  38     init-cuda
  39     [ int <c-object> int <c-object> ] dip
  40     [ cuDeviceComputeCapability cuda-error ]
  41     [ drop [ *int ] bi@ ] 3bi 2array ;
  42
  43 : cuda-device-memory ( n -- bytes )
  44     init-cuda
  45     [ uint <c-object> ] dip
  46     [ cuDeviceTotalMem cuda-error ]
  47     [ drop *uint ] 2bi ;
  48
  49 : cuda-device-attribute ( attribute dev -- n )
  50     [ int <c-object> ] 2dip
  51     [ cuDeviceGetAttribute cuda-error ]
  52     [ 2drop *int ] 3bi ;
  53
  54 : cuda-device. ( n -- )
  55     init-cuda
  56     {
  57         [ "Device: " write number>string print ]
  58         [ "Name: " write cuda-device-name print ]
  59         [ "Memory: " write cuda-device-memory number>string print ]
  60         [
  61             "Capability: " write
  62             cuda-device-capability [ number>string ] map " " join print
  63         ]
  64         [ "Properties: " write cuda-device-properties . ]
  65         [
  66             "CU_DEVICE_ATTRIBUTE_GPU_OVERLAP: " write
  67             CU_DEVICE_ATTRIBUTE_GPU_OVERLAP swap
  68             cuda-device-attribute number>string print
  69         ]
  70     } cleave ;
  71
  72 : cuda. ( -- )
  73     init-cuda
  74     "CUDA Version: " write cuda-version number>string print nl
  75     #cuda-devices iota [ nl ] [ cuda-device. ] interleave ;
  76