extra/curses/curses.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3
   4 USING: accessors alien.c-types alien.data alien.strings
   5 classes.struct combinators continuations destructors fry
   6 io.encodings.utf8 kernel libc locals math memoize multiline
   7 namespaces sequences unix.ffi ;
   8
   9 QUALIFIED-WITH: curses.ffi ffi
  10
  11 IN: curses
  12
  13 SYMBOL: current-window
  14
  15 CONSTANT: COLOR_BLACK 0
  16 CONSTANT: COLOR_RED   1
  17 CONSTANT: COLOR_GREEN 2
  18 CONSTANT: COLOR_YELLO 3
  19 CONSTANT: COLOR_BLUE  4
  20 CONSTANT: COLOR_MAGEN 5
  21 CONSTANT: COLOR_CYAN  6
  22 CONSTANT: COLOR_WHITE 7
  23
  24 CONSTANT: A_NORMAL      0
  25 CONSTANT: A_ATTRIBUTES  -256
  26 CONSTANT: A_CHARTEXT    255
  27 CONSTANT: A_COLOR       65280
  28 CONSTANT: A_STANDOUT    65536
  29 CONSTANT: A_UNDERLINE   131072
  30 CONSTANT: A_REVERSE     262144
  31 CONSTANT: A_BLINK       524288
  32 CONSTANT: A_DIM         1048576
  33 CONSTANT: A_BOLD        2097152
  34 CONSTANT: A_ALTCHARSET  4194304
  35 CONSTANT: A_INVIS       8388608
  36 CONSTANT: A_PROTECT     16777216
  37 CONSTANT: A_HORIZONTAL  33554432
  38 CONSTANT: A_LEFT        67108864
  39 CONSTANT: A_LOW         134217728
  40 CONSTANT: A_RIGHT       268435456
  41 CONSTANT: A_TOP         536870912
  42 CONSTANT: A_VERTICAL    1073741824
  43
  44 CONSTANT: KEY_CODE_YES  0o400  /* A wchar_t contains a key code */
  45 CONSTANT: KEY_MIN       0o401  /* Minimum curses key */
  46 CONSTANT: KEY_BREAK     0o401  /* Break key (unreliable) */
  47 CONSTANT: KEY_SRESET    0o530  /* Soft (partial) reset (unreliable) */
  48 CONSTANT: KEY_RESET     0o531  /* Reset or hard reset (unreliable) */
  49 CONSTANT: KEY_DOWN      0o402  /* down-arrow key */
  50 CONSTANT: KEY_UP        0o403  /* up-arrow key */
  51 CONSTANT: KEY_LEFT      0o404  /* left-arrow key */
  52 CONSTANT: KEY_RIGHT     0o405  /* right-arrow key */
  53 CONSTANT: KEY_HOME      0o406  /* home key */
  54 CONSTANT: KEY_BACKSPACE 0o407  /* backspace key */
  55 CONSTANT: KEY_DL        0o510  /* delete-line key */
  56 CONSTANT: KEY_IL        0o511  /* insert-line key */
  57 CONSTANT: KEY_DC        0o512  /* delete-character key */
  58 CONSTANT: KEY_IC        0o513  /* insert-character key */
  59 CONSTANT: KEY_EIC       0o514  /* sent by rmir or smir in insert mode */
  60 CONSTANT: KEY_CLEAR     0o515  /* clear-screen or erase key */
  61 CONSTANT: KEY_EOS       0o516  /* clear-to-end-of-screen key */
  62 CONSTANT: KEY_EOL       0o517  /* clear-to-end-of-line key */
  63 CONSTANT: KEY_SF        0o520  /* scroll-forward key */
  64 CONSTANT: KEY_SR        0o521  /* scroll-backward key */
  65 CONSTANT: KEY_NPAGE     0o522  /* next-page key */
  66 CONSTANT: KEY_PPAGE     0o523  /* previous-page key */
  67 CONSTANT: KEY_STAB      0o524  /* set-tab key */
  68 CONSTANT: KEY_CTAB      0o525  /* clear-tab key */
  69 CONSTANT: KEY_CATAB     0o526  /* clear-all-tabs key */
  70 CONSTANT: KEY_ENTER     0o527  /* enter/send key */
  71 CONSTANT: KEY_PRINT     0o532  /* print key */
  72 CONSTANT: KEY_LL        0o533  /* lower-left key (home down) */
  73 CONSTANT: KEY_A1        0o534  /* upper left of keypad */
  74 CONSTANT: KEY_A3        0o535  /* upper right of keypad */
  75 CONSTANT: KEY_B2        0o536  /* center of keypad */
  76 CONSTANT: KEY_C1        0o537  /* lower left of keypad */
  77 CONSTANT: KEY_C3        0o540  /* lower right of keypad */
  78 CONSTANT: KEY_BTAB      0o541  /* back-tab key */
  79 CONSTANT: KEY_BEG       0o542  /* begin key */
  80 CONSTANT: KEY_CANCEL    0o543  /* cancel key */
  81 CONSTANT: KEY_CLOSE     0o544  /* close key */
  82 CONSTANT: KEY_COMMAND   0o545  /* command key */
  83 CONSTANT: KEY_COPY      0o546  /* copy key */
  84 CONSTANT: KEY_CREATE    0o547  /* create key */
  85 CONSTANT: KEY_END       0o550  /* end key */
  86 CONSTANT: KEY_EXIT      0o551  /* exit key */
  87 CONSTANT: KEY_FIND      0o552  /* find key */
  88 CONSTANT: KEY_HELP      0o553  /* help key */
  89 CONSTANT: KEY_MARK      0o554  /* mark key */
  90 CONSTANT: KEY_MESSAGE   0o555  /* message key */
  91 CONSTANT: KEY_MOVE      0o556  /* move key */
  92 CONSTANT: KEY_NEXT      0o557  /* next key */
  93 CONSTANT: KEY_OPEN      0o560  /* open key */
  94 CONSTANT: KEY_OPTIONS   0o561  /* options key */
  95 CONSTANT: KEY_PREVIOUS  0o562  /* previous key */
  96 CONSTANT: KEY_REDO      0o563  /* redo key */
  97 CONSTANT: KEY_REFERENCE 0o564  /* reference key */
  98 CONSTANT: KEY_REFRESH   0o565  /* refresh key */
  99 CONSTANT: KEY_REPLACE   0o566  /* replace key */
 100 CONSTANT: KEY_RESTART   0o567  /* restart key */
 101 CONSTANT: KEY_RESUME    0o570  /* resume key */
 102 CONSTANT: KEY_SAVE      0o571  /* save key */
 103 CONSTANT: KEY_SBEG      0o572  /* shifted begin key */
 104 CONSTANT: KEY_SCANCEL   0o573  /* shifted cancel key */
 105 CONSTANT: KEY_SCOMMAND  0o574  /* shifted command key */
 106 CONSTANT: KEY_SCOPY     0o575  /* shifted copy key */
 107 CONSTANT: KEY_SCREATE   0o576  /* shifted create key */
 108 CONSTANT: KEY_SDC       0o577  /* shifted delete-character key */
 109 CONSTANT: KEY_SDL       0o600  /* shifted delete-line key */
 110 CONSTANT: KEY_SELECT    0o601  /* select key */
 111 CONSTANT: KEY_SEND      0o602  /* shifted end key */
 112 CONSTANT: KEY_SEOL      0o603  /* shifted clear-to-end-of-line key */
 113 CONSTANT: KEY_SEXIT     0o604  /* shifted exit key */
 114 CONSTANT: KEY_SFIND     0o605  /* shifted find key */
 115 CONSTANT: KEY_SHELP     0o606  /* shifted help key */
 116 CONSTANT: KEY_SHOME     0o607  /* shifted home key */
 117 CONSTANT: KEY_SIC       0o610  /* shifted insert-character key */
 118 CONSTANT: KEY_SLEFT     0o611  /* shifted left-arrow key */
 119 CONSTANT: KEY_SMESSAGE  0o612  /* shifted message key */
 120 CONSTANT: KEY_SMOVE     0o613  /* shifted move key */
 121 CONSTANT: KEY_SNEXT     0o614  /* shifted next key */
 122 CONSTANT: KEY_SOPTIONS  0o615  /* shifted options key */
 123 CONSTANT: KEY_SPREVIOUS 0o616  /* shifted previous key */
 124 CONSTANT: KEY_SPRINT    0o617  /* shifted print key */
 125 CONSTANT: KEY_SREDO     0o620  /* shifted redo key */
 126 CONSTANT: KEY_SREPLACE  0o621  /* shifted replace key */
 127 CONSTANT: KEY_SRIGHT    0o622  /* shifted right-arrow key */
 128 CONSTANT: KEY_SRSUME    0o623  /* shifted resume key */
 129 CONSTANT: KEY_SSAVE     0o624  /* shifted save key */
 130 CONSTANT: KEY_SSUSPEND  0o625  /* shifted suspend key */
 131 CONSTANT: KEY_SUNDO     0o626  /* shifted undo key */
 132 CONSTANT: KEY_SUSPEND   0o627  /* suspend key */
 133 CONSTANT: KEY_UNDO      0o630  /* undo key */
 134 CONSTANT: KEY_MOUSE     0o631  /* Mouse event has occurred */
 135 CONSTANT: KEY_RESIZE    0o632  /* Terminal resize event */
 136 CONSTANT: KEY_EVENT     0o633  /* We were interrupted by an event */
 137 CONSTANT: KEY_MAX       0o777  /* Maximum key value is 0633 */
 138 CONSTANT: KEY_F0        0o410  /* Function keys.  Space for 64 */
 139 : KEY_F ( n -- code ) KEY_F0 + ; inline /* Value of function key n */
 140
 141 : BUTTON1_RELEASED       ( -- mask ) 1 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 142 : BUTTON1_PRESSED        ( -- mask ) 1 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 143 : BUTTON1_CLICKED        ( -- mask ) 1 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 144 : BUTTON1_DOUBLE_CLICKED ( -- mask ) 1 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 145 : BUTTON1_TRIPLE_CLICKED ( -- mask ) 1 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 146 : BUTTON2_RELEASED       ( -- mask ) 2 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 147 : BUTTON2_PRESSED        ( -- mask ) 2 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 148 : BUTTON2_CLICKED        ( -- mask ) 2 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 149 : BUTTON2_DOUBLE_CLICKED ( -- mask ) 2 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 150 : BUTTON2_TRIPLE_CLICKED ( -- mask ) 2 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 151 : BUTTON3_RELEASED       ( -- mask ) 3 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 152 : BUTTON3_PRESSED        ( -- mask ) 3 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 153 : BUTTON3_CLICKED        ( -- mask ) 3 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 154 : BUTTON3_DOUBLE_CLICKED ( -- mask ) 3 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 155 : BUTTON3_TRIPLE_CLICKED ( -- mask ) 3 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 156 : BUTTON4_RELEASED       ( -- mask ) 4 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 157 : BUTTON4_PRESSED        ( -- mask ) 4 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 158 : BUTTON4_CLICKED        ( -- mask ) 4 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 159 : BUTTON4_DOUBLE_CLICKED ( -- mask ) 4 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 160 : BUTTON4_TRIPLE_CLICKED ( -- mask ) 4 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 161
 162 : BUTTON1_RESERVED_EVENT ( -- mask ) 1 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 163 : BUTTON2_RESERVED_EVENT ( -- mask ) 2 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 164 : BUTTON3_RESERVED_EVENT ( -- mask ) 3 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 165 : BUTTON4_RESERVED_EVENT ( -- mask ) 4 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 166
 167 : BUTTON_CTRL            ( -- mask ) 5 0o01 ffi:NCURSES_MOUSE_MASK ; inline
 168 : BUTTON_SHIFT           ( -- mask ) 5 0o02 ffi:NCURSES_MOUSE_MASK ; inline
 169 : BUTTON_ALT             ( -- mask ) 5 0o04 ffi:NCURSES_MOUSE_MASK ; inline
 170 : REPORT_MOUSE_POSITION  ( -- mask ) 5 0o10 ffi:NCURSES_MOUSE_MASK ; inline
 171
 172 : ALL_MOUSE_EVENTS ( -- mask ) REPORT_MOUSE_POSITION 1 - ; inline
 173
 174 ERROR: curses-failed ;
 175 ERROR: unsupported-curses-terminal ;
 176
 177 <PRIVATE
 178
 179 : >BOOLEAN ( ? -- TRUE/FALSE ) ffi:TRUE ffi:FALSE ? ; inline
 180
 181 : curses-pointer-error ( ptr/f -- ptr )
 182     [ curses-failed ] unless* ; inline
 183 : curses-error ( n -- ) ffi:ERR = [ curses-failed ] when ;
 184
 185 PRIVATE>
 186
 187 : curses-ok? ( -- ? )
 188     { 0 1 2 } [ isatty 0 = not ] all? ;
 189
 190 TUPLE: curses-window < disposable
 191     ptr
 192     parent-window
 193     { lines integer initial: 0 }
 194     { columns integer initial: 0 }
 195     { y integer initial: 0 }
 196     { x integer initial: 0 }
 197
 198     { cbreak initial: t }
 199     { echo initial: f }
 200     { raw initial: f }
 201
 202     { scrollok initial: t }
 203     { leaveok initial: f }
 204
 205     idcok idlok immedok
 206     { keypad initial: t }
 207
 208     { encoding initial: utf8 } ;
 209
 210 : <curses-window> ( -- window )
 211     curses-window new-disposable ;
 212
 213 M: curses-window dispose* ( window -- )
 214     ptr>> ffi:delwin curses-error ;
 215
 216 <PRIVATE
 217
 218 : window-params ( window -- lines columns y x )
 219     { [ lines>> ] [ columns>> ] [ y>> ] [ x>> ] } cleave ;
 220
 221 : set-cbreak/raw ( cbreak raw -- )
 222     [ drop ffi:raw ] [
 223         [ ffi:cbreak ] [ ffi:nocbreak ] if
 224     ] if curses-error ;
 225
 226 : apply-window-options ( window -- )
 227     {
 228         [ [ ptr>> ] [ scrollok>> >BOOLEAN ] bi ffi:scrollok curses-error ]
 229         [ [ ptr>> ] [ leaveok>> >BOOLEAN ] bi ffi:leaveok curses-error ]
 230         [ [ ptr>> ] [ keypad>> >BOOLEAN ] bi ffi:keypad curses-error ]
 231     } cleave ;
 232
 233 : apply-global-options ( window -- )
 234     [ [ cbreak>> ] [ raw>> ] bi set-cbreak/raw ]
 235     [ echo>> [ ffi:echo ] [ ffi:noecho ] if curses-error ]
 236     bi ;
 237
 238 SYMBOL: n-registered-colors
 239
 240 MEMO: register-color ( fg bg -- n )
 241     [ n-registered-colors get dup ] 2dip ffi:init_pair curses-error
 242     n-registered-colors inc ;
 243
 244 : init-colors ( -- )
 245     ffi:has_colors [
 246         1 n-registered-colors set
 247         \ register-color reset-memoized
 248         ffi:start_color curses-error
 249         ffi:stdscr 0 f ffi:wcolor_set curses-error
 250     ] when ;
 251
 252 PRIVATE>
 253
 254 : setup-window ( window -- window )
 255     [
 256         dup [ window-params ] keep
 257         parent-window>> [ ptr>> ffi:derwin ] [ ffi:newwin ] if*
 258         curses-pointer-error >>ptr &dispose
 259     ] [ apply-window-options ] bi ;
 260
 261 : with-window ( window quot -- )
 262     [ current-window ] dip with-variable ; inline
 263
 264 : with-curses ( window quot -- )
 265     curses-ok? [ unsupported-curses-terminal ] unless
 266     [
 267         '[
 268             ffi:initscr curses-pointer-error
 269             >>ptr
 270             {
 271                 [ apply-global-options ]
 272                 [ apply-window-options ]
 273                 [ ptr>> ffi:wclear curses-error ]
 274                 [ ptr>> ffi:wrefresh curses-error ]
 275                 [ ]
 276             } cleave
 277             init-colors
 278
 279             _ with-window
 280         ] [ ffi:endwin curses-error ] [ ] cleanup
 281     ] with-destructors ; inline
 282
 283 <PRIVATE
 284
 285 : (wcrefresh) ( window-ptr -- )
 286     ffi:wrefresh curses-error ; inline
 287
 288 : (wcwrite) ( string window-ptr -- )
 289     swap ffi:waddstr curses-error ; inline
 290
 291 :: (wcread) ( n encoding window-ptr -- string )
 292     [
 293         n 1 + malloc &free :> str
 294         window-ptr str n ffi:wgetnstr curses-error
 295         str encoding alien>string
 296     ] with-destructors ; inline
 297
 298 : (wcmove) ( y x window-ptr -- )
 299     -rot ffi:wmove curses-error ; inline
 300
 301 : (winsert-blank-line) ( y window-ptr -- )
 302     [ 0 swap (wcmove) ]
 303     [ ffi:winsertln curses-error ] bi ; inline
 304
 305 : (waddch) ( ch window-ptr -- )
 306     swap ffi:waddch curses-error ; inline
 307
 308 : (wgetch) ( window -- key )
 309     ffi:wgetch [ curses-error ] keep ; inline
 310
 311 : (wattroff) ( attribute window-ptr -- )
 312     swap ffi:wattroff curses-error ; inline
 313
 314 : (wattron) ( attribute window-ptr -- )
 315     swap ffi:wattron curses-error ; inline
 316
 317 PRIVATE>
 318
 319 : wcrefresh ( window -- ) ptr>> (wcrefresh) ;
 320 : crefresh ( -- ) current-window get wcrefresh ;
 321
 322 : wgetch ( window -- key ) ptr>> (wgetch) ;
 323 : getch ( -- key ) current-window get wgetch ;
 324
 325 : waddch ( ch window -- ) ptr>> (waddch) ;
 326 : addch ( ch -- ) current-window get waddch ;
 327
 328 : wcnl ( window -- ) [ CHAR: \n ] dip waddch ;
 329 : cnl ( -- ) current-window get wcnl ;
 330
 331 : wcwrite ( string window -- ) ptr>> (wcwrite) ;
 332 : cwrite ( string -- ) current-window get wcwrite ;
 333
 334 : wcprint ( string window -- )
 335     ptr>> [ (wcwrite) ] [ CHAR: \n swap (waddch) ] bi ;
 336 : cprint ( string -- ) current-window get wcprint ;
 337
 338 : wcprintf ( string window -- )
 339     ptr>> [ (wcwrite) ] [ CHAR: \n swap (waddch) ]
 340     [ (wcrefresh) ] tri ;
 341 : cprintf ( string -- ) current-window get wcprintf ;
 342
 343 : wcwritef ( string window -- )
 344     ptr>> [ (wcwrite) ] [ (wcrefresh) ] bi ;
 345 : cwritef ( string -- ) current-window get wcwritef ;
 346
 347 : wcread ( n window -- string )
 348     [ encoding>> ] [ ptr>> ] bi (wcread) ;
 349 : cread ( n -- string ) current-window get wcread ;
 350
 351 : werase ( window -- ) ptr>> ffi:werase curses-error ;
 352 : erase ( -- ) current-window get werase ;
 353
 354 : wcmove ( y x window -- )
 355     ptr>> [ (wcmove) ] [ (wcrefresh) ] bi ;
 356 : cmove ( y x -- ) current-window get wcmove ;
 357
 358 : wdelete-line ( y window -- )
 359     ptr>> [ 0 swap (wcmove) ] [ ffi:wdeleteln curses-error ] bi ;
 360 : delete-line ( y -- ) current-window get wdelete-line ;
 361
 362 : winsert-blank-line ( y window -- )
 363     ptr>> (winsert-blank-line) ;
 364 : insert-blank-line ( y -- )
 365     current-window get winsert-blank-line ;
 366
 367 : winsert-line ( string y window -- )
 368     ptr>> [ (winsert-blank-line) ] [ (wcwrite) ] bi ;
 369 : insert-line ( string y -- )
 370     current-window get winsert-line ;
 371
 372 : wattron ( attribute window -- ) ptr>> (wattron) ;
 373 : attron ( attribute -- ) current-window get wattron ;
 374
 375 : wattroff ( attribute window -- ) ptr>> (wattroff) ;
 376 : attroff ( attribute -- ) current-window get wattroff ;
 377
 378 : wall-attroff ( window -- ) [ A_NORMAL ] dip wattroff ;
 379 : all-attroff ( -- ) current-window get wall-attroff ;
 380
 381 : wccolor ( foreground background window -- )
 382     [ register-color ] dip ptr>> swap f ffi:wcolor_set curses-error ;
 383
 384 : ccolor ( foreground background -- )
 385     current-window get wccolor ;
 386
 387 : wccbox ( window -- )
 388     ptr>> 0 0 ffi:box curses-error ;
 389 : cbox ( -- )
 390     current-window get wccbox ;
 391
 392 SYMBOLS: +pressed+ +released+ +clicked+ +double+ +triple+ ;
 393
 394 TUPLE: mouse-event
 395     { id fixnum }
 396     { y fixnum }
 397     { x fixnum }
 398     { button fixnum }
 399     type
 400     alt
 401     shift
 402     ctrl ;
 403
 404 <PRIVATE
 405
 406 : substate-n ( bstate n -- substate )
 407     [ 1 + ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK 1 - bitand ] keep
 408     1 - -6 * shift ; inline
 409
 410 : button-n? ( bstate n -- ? ) substate-n 0 = not ; inline
 411
 412 : fill-in-type ( mouse-event bstate button -- )
 413     substate-n {
 414         { BUTTON1_RELEASED       [ +released+ ] }
 415         { BUTTON1_PRESSED        [ +pressed+ ] }
 416         { BUTTON1_CLICKED        [ +clicked+ ] }
 417         { BUTTON1_DOUBLE_CLICKED [ +double+ ] }
 418         { BUTTON1_TRIPLE_CLICKED [ +triple+ ] }
 419     } case >>type drop ; inline
 420
 421 : fill-in-bstate ( mouse-event bstate -- )
 422     2dup {
 423         { [ dup 1 button-n? ] [ [ 1 >>button ] dip 1 fill-in-type ] }
 424         { [ dup 2 button-n? ] [ [ 2 >>button ] dip 2 fill-in-type ] }
 425         { [ dup 3 button-n? ] [ [ 3 >>button ] dip 3 fill-in-type ] }
 426         { [ dup 4 button-n? ] [ [ 4 >>button ] dip 4 fill-in-type ] }
 427     } cond
 428     {
 429         [ BUTTON_CTRL  bitand 0 = not [ t >>ctrl  ] when drop ]
 430         [ BUTTON_SHIFT bitand 0 = not [ t >>shift ] when drop ]
 431         [ BUTTON_ALT   bitand 0 = not [ t >>alt   ] when drop ]
 432     } 2cleave ;
 433
 434 : <mouse-event> ( MEVENT -- mouse-event )
 435     [ mouse-event new ] dip {
 436         [ id>> >>id drop ]
 437         [ y>> >>y drop ]
 438         [ x>> >>x drop ]
 439         [ bstate>> fill-in-bstate ]
 440         [ drop ]
 441     } 2cleave ;
 442
 443 PRIVATE>
 444
 445 : getmouse ( -- mouse-event/f )
 446     [
 447         ffi:MEVENT malloc-struct &free
 448         dup ffi:getmouse
 449         ffi:ERR = [ drop f ] [ <mouse-event> ] if
 450     ] with-destructors ;
 451
 452 : mousemask ( mask -- newmask oldmask )
 453     0 ulong <ref> [ ffi:mousemask ] keep ulong deref ;
 454
 455 : wget-yx ( window -- y x )
 456     ptr>> [ _cury>> ] [ _curx>> ] bi ;
 457 : get-yx ( -- y x )
 458     current-window get wget-yx ;
 459
 460 : wget-y ( window -- y )
 461     ptr>> _cury>> ;
 462 : get-y ( -- y )
 463     current-window get wget-y ;
 464 : wget-x ( window -- x )
 465     ptr>> _curx>> ;
 466 : get-x ( -- x )
 467     current-window get wget-x ;
 468
 469 : wget-max-yx ( window -- y x )
 470     ptr>> [ _maxy>> 1 + ] [ _maxx>> 1 + ] bi ;
 471 : get-max-yx ( -- y x )
 472     current-window get wget-max-yx ;
 473
 474 : wget-max-y ( window -- y )
 475     ptr>> _maxy>> 1 + ;
 476 : get-max-y ( -- y )
 477     current-window get wget-max-y ;
 478 : wget-max-x ( window -- x )
 479     ptr>> _maxx>> 1 + ;
 480 : get-max-x ( -- x )
 481     current-window get wget-max-x ;