extra/curses/curses.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types alien.strings assocs byte-arrays
   4 classes.struct combinators continuations destructors
   5 fry io io.encodings.8-bit io.encodings.string io.encodings.utf8
   6 io.streams.c kernel libc locals math memoize multiline
   7 namespaces prettyprint sequences strings threads ;
   8 IN: curses
   9
  10 QUALIFIED-WITH: curses.ffi ffi
  11
  12 SYMBOL: current-window
  13
  14 CONSTANT: COLOR_BLACK 0
  15 CONSTANT: COLOR_RED   1
  16 CONSTANT: COLOR_GREEN 2
  17 CONSTANT: COLOR_YELLO 3
  18 CONSTANT: COLOR_BLUE  4
  19 CONSTANT: COLOR_MAGEN 5
  20 CONSTANT: COLOR_CYAN  6
  21 CONSTANT: COLOR_WHITE 7
  22
  23 CONSTANT: A_NORMAL      0
  24 CONSTANT: A_ATTRIBUTES  -256
  25 CONSTANT: A_CHARTEXT    255
  26 CONSTANT: A_COLOR       65280
  27 CONSTANT: A_STANDOUT    65536
  28 CONSTANT: A_UNDERLINE   131072
  29 CONSTANT: A_REVERSE     262144
  30 CONSTANT: A_BLINK       524288
  31 CONSTANT: A_DIM         1048576
  32 CONSTANT: A_BOLD        2097152
  33 CONSTANT: A_ALTCHARSET  4194304
  34 CONSTANT: A_INVIS       8388608
  35 CONSTANT: A_PROTECT     16777216
  36 CONSTANT: A_HORIZONTAL  33554432
  37 CONSTANT: A_LEFT        67108864
  38 CONSTANT: A_LOW         134217728
  39 CONSTANT: A_RIGHT       268435456
  40 CONSTANT: A_TOP         536870912
  41 CONSTANT: A_VERTICAL    1073741824
  42
  43 CONSTANT: KEY_CODE_YES  OCT: 400  /* A wchar_t contains a key code */
  44 CONSTANT: KEY_MIN       OCT: 401  /* Minimum curses key */
  45 CONSTANT: KEY_BREAK     OCT: 401  /* Break key (unreliable) */
  46 CONSTANT: KEY_SRESET    OCT: 530  /* Soft (partial) reset (unreliable) */
  47 CONSTANT: KEY_RESET     OCT: 531  /* Reset or hard reset (unreliable) */
  48 CONSTANT: KEY_DOWN      OCT: 402  /* down-arrow key */
  49 CONSTANT: KEY_UP        OCT: 403  /* up-arrow key */
  50 CONSTANT: KEY_LEFT      OCT: 404  /* left-arrow key */
  51 CONSTANT: KEY_RIGHT     OCT: 405  /* right-arrow key */
  52 CONSTANT: KEY_HOME      OCT: 406  /* home key */
  53 CONSTANT: KEY_BACKSPACE OCT: 407  /* backspace key */
  54 CONSTANT: KEY_DL        OCT: 510  /* delete-line key */
  55 CONSTANT: KEY_IL        OCT: 511  /* insert-line key */
  56 CONSTANT: KEY_DC        OCT: 512  /* delete-character key */
  57 CONSTANT: KEY_IC        OCT: 513  /* insert-character key */
  58 CONSTANT: KEY_EIC       OCT: 514  /* sent by rmir or smir in insert mode */
  59 CONSTANT: KEY_CLEAR     OCT: 515  /* clear-screen or erase key */
  60 CONSTANT: KEY_EOS       OCT: 516  /* clear-to-end-of-screen key */
  61 CONSTANT: KEY_EOL       OCT: 517  /* clear-to-end-of-line key */
  62 CONSTANT: KEY_SF        OCT: 520  /* scroll-forward key */
  63 CONSTANT: KEY_SR        OCT: 521  /* scroll-backward key */
  64 CONSTANT: KEY_NPAGE     OCT: 522  /* next-page key */
  65 CONSTANT: KEY_PPAGE     OCT: 523  /* previous-page key */
  66 CONSTANT: KEY_STAB      OCT: 524  /* set-tab key */
  67 CONSTANT: KEY_CTAB      OCT: 525  /* clear-tab key */
  68 CONSTANT: KEY_CATAB     OCT: 526  /* clear-all-tabs key */
  69 CONSTANT: KEY_ENTER     OCT: 527  /* enter/send key */
  70 CONSTANT: KEY_PRINT     OCT: 532  /* print key */
  71 CONSTANT: KEY_LL        OCT: 533  /* lower-left key (home down) */
  72 CONSTANT: KEY_A1        OCT: 534  /* upper left of keypad */
  73 CONSTANT: KEY_A3        OCT: 535  /* upper right of keypad */
  74 CONSTANT: KEY_B2        OCT: 536  /* center of keypad */
  75 CONSTANT: KEY_C1        OCT: 537  /* lower left of keypad */
  76 CONSTANT: KEY_C3        OCT: 540  /* lower right of keypad */
  77 CONSTANT: KEY_BTAB      OCT: 541  /* back-tab key */
  78 CONSTANT: KEY_BEG       OCT: 542  /* begin key */
  79 CONSTANT: KEY_CANCEL    OCT: 543  /* cancel key */
  80 CONSTANT: KEY_CLOSE     OCT: 544  /* close key */
  81 CONSTANT: KEY_COMMAND   OCT: 545  /* command key */
  82 CONSTANT: KEY_COPY      OCT: 546  /* copy key */
  83 CONSTANT: KEY_CREATE    OCT: 547  /* create key */
  84 CONSTANT: KEY_END       OCT: 550  /* end key */
  85 CONSTANT: KEY_EXIT      OCT: 551  /* exit key */
  86 CONSTANT: KEY_FIND      OCT: 552  /* find key */
  87 CONSTANT: KEY_HELP      OCT: 553  /* help key */
  88 CONSTANT: KEY_MARK      OCT: 554  /* mark key */
  89 CONSTANT: KEY_MESSAGE   OCT: 555  /* message key */
  90 CONSTANT: KEY_MOVE      OCT: 556  /* move key */
  91 CONSTANT: KEY_NEXT      OCT: 557  /* next key */
  92 CONSTANT: KEY_OPEN      OCT: 560  /* open key */
  93 CONSTANT: KEY_OPTIONS   OCT: 561  /* options key */
  94 CONSTANT: KEY_PREVIOUS  OCT: 562  /* previous key */
  95 CONSTANT: KEY_REDO      OCT: 563  /* redo key */
  96 CONSTANT: KEY_REFERENCE OCT: 564  /* reference key */
  97 CONSTANT: KEY_REFRESH   OCT: 565  /* refresh key */
  98 CONSTANT: KEY_REPLACE   OCT: 566  /* replace key */
  99 CONSTANT: KEY_RESTART   OCT: 567  /* restart key */
 100 CONSTANT: KEY_RESUME    OCT: 570  /* resume key */
 101 CONSTANT: KEY_SAVE      OCT: 571  /* save key */
 102 CONSTANT: KEY_SBEG      OCT: 572  /* shifted begin key */
 103 CONSTANT: KEY_SCANCEL   OCT: 573  /* shifted cancel key */
 104 CONSTANT: KEY_SCOMMAND  OCT: 574  /* shifted command key */
 105 CONSTANT: KEY_SCOPY     OCT: 575  /* shifted copy key */
 106 CONSTANT: KEY_SCREATE   OCT: 576  /* shifted create key */
 107 CONSTANT: KEY_SDC       OCT: 577  /* shifted delete-character key */
 108 CONSTANT: KEY_SDL       OCT: 600  /* shifted delete-line key */
 109 CONSTANT: KEY_SELECT    OCT: 601  /* select key */
 110 CONSTANT: KEY_SEND      OCT: 602  /* shifted end key */
 111 CONSTANT: KEY_SEOL      OCT: 603  /* shifted clear-to-end-of-line key */
 112 CONSTANT: KEY_SEXIT     OCT: 604  /* shifted exit key */
 113 CONSTANT: KEY_SFIND     OCT: 605  /* shifted find key */
 114 CONSTANT: KEY_SHELP     OCT: 606  /* shifted help key */
 115 CONSTANT: KEY_SHOME     OCT: 607  /* shifted home key */
 116 CONSTANT: KEY_SIC       OCT: 610  /* shifted insert-character key */
 117 CONSTANT: KEY_SLEFT     OCT: 611  /* shifted left-arrow key */
 118 CONSTANT: KEY_SMESSAGE  OCT: 612  /* shifted message key */
 119 CONSTANT: KEY_SMOVE     OCT: 613  /* shifted move key */
 120 CONSTANT: KEY_SNEXT     OCT: 614  /* shifted next key */
 121 CONSTANT: KEY_SOPTIONS  OCT: 615  /* shifted options key */
 122 CONSTANT: KEY_SPREVIOUS OCT: 616  /* shifted previous key */
 123 CONSTANT: KEY_SPRINT    OCT: 617  /* shifted print key */
 124 CONSTANT: KEY_SREDO     OCT: 620  /* shifted redo key */
 125 CONSTANT: KEY_SREPLACE  OCT: 621  /* shifted replace key */
 126 CONSTANT: KEY_SRIGHT    OCT: 622  /* shifted right-arrow key */
 127 CONSTANT: KEY_SRSUME    OCT: 623  /* shifted resume key */
 128 CONSTANT: KEY_SSAVE     OCT: 624  /* shifted save key */
 129 CONSTANT: KEY_SSUSPEND  OCT: 625  /* shifted suspend key */
 130 CONSTANT: KEY_SUNDO     OCT: 626  /* shifted undo key */
 131 CONSTANT: KEY_SUSPEND   OCT: 627  /* suspend key */
 132 CONSTANT: KEY_UNDO      OCT: 630  /* undo key */
 133 CONSTANT: KEY_MOUSE     OCT: 631  /* Mouse event has occurred */
 134 CONSTANT: KEY_RESIZE    OCT: 632  /* Terminal resize event */
 135 CONSTANT: KEY_EVENT     OCT: 633  /* We were interrupted by an event */
 136 CONSTANT: KEY_F0        OCT: 410  /* Function keys.  Space for 64 */
 137 : KEY_F ( n -- code ) KEY_F0 + ; inline /* Value of function key n */
 138
 139 ERROR: curses-failed ;
 140 ERROR: unsupported-curses-terminal ;
 141
 142 <PRIVATE
 143
 144 : >BOOLEAN ( ? -- TRUE/FALSE ) ffi:TRUE ffi:FALSE ? ; inline
 145
 146 : curses-pointer-error ( ptr/f -- ptr )
 147     dup [ curses-failed ] unless ; inline
 148 : curses-error ( n -- ) ffi:ERR = [ curses-failed ] when ;
 149
 150 PRIVATE>
 151
 152 : curses-ok? ( -- ? )
 153     { 0 1 2 } [ isatty 0 = not ] all? ;
 154
 155 TUPLE: curses-window < disposable
 156     ptr
 157     parent-window
 158     { lines integer initial: 0 }
 159     { columns integer initial: 0 }
 160     { y integer initial: 0 }
 161     { x integer initial: 0 }
 162
 163     { cbreak initial: t }
 164     { echo initial: t }
 165     { raw initial: f }
 166
 167     { scrollok initial: t }
 168     { leaveok initial: f }
 169
 170     idcok idlok immedok
 171     { keypad initial: t }
 172
 173     { encoding initial: utf8 } ;
 174
 175 : <curses-window> ( -- window )
 176     curses-window new-disposable ;
 177
 178 M: curses-window dispose* ( window -- )
 179     ptr>> ffi:delwin curses-error ;
 180
 181 <PRIVATE
 182
 183 : window-params ( window -- lines columns y x )
 184     { [ lines>> ] [ columns>> ] [ y>> ] [ x>> ] } cleave ;
 185
 186 : set-cbreak/raw ( cbreak raw -- )
 187     [ drop ffi:raw ] [
 188         [ ffi:cbreak ] [ ffi:nocbreak ] if
 189     ] if curses-error ;
 190
 191 : apply-window-options ( window -- )
 192     {
 193         [ [ ptr>> ] [ scrollok>> >BOOLEAN ] bi ffi:scrollok curses-error ]
 194         [ [ ptr>> ] [ leaveok>> >BOOLEAN ] bi ffi:leaveok curses-error ]
 195         [ [ ptr>> ] [ keypad>> >BOOLEAN ] bi ffi:keypad curses-error ]
 196     } cleave ;
 197
 198 : apply-global-options ( window -- )
 199     [ [ cbreak>> ] [ raw>> ] bi set-cbreak/raw ]
 200     [ echo>> [ ffi:echo ] [ ffi:noecho ] if curses-error ]
 201     bi ;
 202
 203 SYMBOL: n-registered-colors
 204
 205 MEMO: register-color ( fg bg -- n )
 206     [ n-registered-colors get ] 2dip ffi:init_pair curses-error
 207     n-registered-colors [ get ] [ inc ] bi ;
 208
 209 : init-colors ( -- )
 210     ffi:has_colors [
 211         1 n-registered-colors set
 212         \ register-color reset-memoized
 213         ffi:start_color curses-error
 214     ] when ;
 215
 216 PRIVATE>
 217
 218 : setup-window ( window -- window )
 219     [
 220         dup
 221         dup parent-window>> [
 222             ptr>> swap window-params ffi:derwin
 223         ] [
 224             window-params ffi:newwin
 225         ] if* [ curses-error ] keep >>ptr &dispose
 226     ] [ apply-window-options ] bi ;
 227
 228 : with-window ( window quot -- )
 229     [ current-window ] dip with-variable ; inline
 230
 231 : with-curses ( window quot -- )
 232     curses-ok? [ unsupported-curses-terminal ] unless
 233     [
 234         '[
 235             ffi:initscr curses-pointer-error
 236             >>ptr
 237             [ apply-global-options ] [ apply-window-options ] [ ] tri
 238
 239             ffi:erase curses-error
 240             init-colors
 241
 242             _ with-window
 243         ] [ ffi:endwin curses-error ] [ ] cleanup
 244     ] with-destructors ; inline
 245
 246 TUPLE: curses-terminal < disposable
 247     infd outfd ptr ;
 248
 249 : <curses-terminal> ( infd outfd ptr -- curses-terminal )
 250     curses-terminal new-disposable
 251         swap >>ptr
 252         swap >>outfd
 253         swap >>infd ;
 254
 255 M: curses-terminal dispose
 256     [ outfd>> fclose ] [ infd>> fclose ]
 257     [ ptr>> ffi:delscreen ] tri ;
 258
 259 : init-terminal ( terminal -- curses-terminal )
 260     "xterm-color" swap [ "rb" fopen ] [ "wb" fopen ] bi
 261     [ ffi:newterm curses-pointer-error ] 2keep <curses-terminal> ;
 262
 263 : start-remote-curses ( terminal window -- curses-terminal )
 264     [
 265         init-terminal
 266         ffi:initscr curses-pointer-error drop
 267         dup ptr>> ffi:set_term curses-pointer-error drop
 268     ] dip [ apply-global-options ] [ apply-window-options ] bi ;
 269
 270 <PRIVATE
 271
 272 : (wcrefresh) ( window-ptr -- ) ffi:wrefresh curses-error ; inline
 273 : (wcwrite) ( string window-ptr -- ) swap ffi:waddstr curses-error ; inline
 274
 275 :: (wcread) ( n encoding window-ptr -- string )
 276     [
 277         n 1 + malloc &free :> str
 278         window-ptr str n ffi:wgetnstr curses-error
 279         str encoding alien>string
 280     ] with-destructors ; inline
 281
 282 : (wcmove) ( y x window-ptr -- )
 283     -rot ffi:wmove curses-error ; inline
 284
 285 : (winsert-blank-line) ( y window-ptr -- )
 286     [ 0 swap (wcmove) ]
 287     [ ffi:winsertln curses-error ] bi ; inline
 288
 289 : (waddch) ( ch window-ptr -- )
 290     swap ffi:waddch curses-error ; inline
 291
 292 : (wgetch) ( window -- key )
 293     ffi:wgetch [ curses-error ] keep ; inline
 294
 295 : (wattroff) ( attribute window-ptr -- )
 296     swap ffi:wattroff curses-error ; inline
 297
 298 : (wattron) ( attribute window-ptr -- )
 299     swap ffi:wattron curses-error ; inline
 300
 301 PRIVATE>
 302
 303 : wcrefresh ( window -- ) ptr>> (wcrefresh) ;
 304 : crefresh ( -- ) current-window get wcrefresh ;
 305
 306 : wcnl ( window -- ) [ "\n" ] dip ptr>> (wcwrite) ;
 307 : cnl ( -- ) current-window get wcnl ;
 308
 309 : wcwrite ( string window -- ) ptr>> (wcwrite) ;
 310 : cwrite ( string -- ) current-window get wcwrite ;
 311
 312 : wcprint ( string window -- )
 313     ptr>> [ (wcwrite) ] [ "\n" swap (wcwrite) ] bi ;
 314 : cprint ( string -- ) current-window get wcprint ;
 315
 316 : wcprintf ( string window -- )
 317     ptr>> [ (wcwrite) ] [ "\n" swap (wcwrite) ]
 318     [ (wcrefresh) ] tri ;
 319 : cprintf ( string -- ) current-window get wcprintf ;
 320
 321 : wcwritef ( string window -- )
 322     ptr>> [ (wcwrite) ] [ (wcrefresh) ] bi ;
 323 : cwritef ( string -- ) current-window get wcwritef ;
 324
 325 : wcread ( n window -- string )
 326     [ encoding>> ] [ ptr>> ] bi (wcread) ;
 327 : curses-read ( n -- string ) current-window get wcread ;
 328
 329 : wgetch ( window -- key ) ptr>> (wgetch) ;
 330 : getch ( -- key ) current-window get wgetch ;
 331
 332 : waddch ( ch window -- ) ptr>> (waddch) ;
 333 : addch ( ch -- ) current-window get waddch ;
 334
 335 : werase ( window -- ) ptr>> ffi:werase curses-error ;
 336 : erase ( -- ) current-window get werase ;
 337
 338 : wcmove ( y x window -- )
 339     ptr>> [ (wcmove) ] [ (wcrefresh) ] bi ;
 340 : cmove ( y x -- ) current-window get wcmove ;
 341
 342 : wdelete-line ( y window -- )
 343     ptr>> [ 0 swap (wcmove) ] [ ffi:wdeleteln curses-error ] bi ;
 344 : delete-line ( y -- ) current-window get wdelete-line ;
 345
 346 : winsert-blank-line ( y window -- )
 347     ptr>> (winsert-blank-line) ;
 348 : insert-blank-line ( y -- )
 349     current-window get winsert-blank-line ;
 350
 351 : winsert-line ( string y window -- )
 352     ptr>> [ (winsert-blank-line) ] [ (wcwrite) ] bi ;
 353 : insert-line ( string y -- )
 354     current-window get winsert-line ;
 355
 356 : wattron ( attribute window -- ) ptr>> (wattron) ;
 357 : attron ( attribute -- ) current-window get wattron ;
 358
 359 : wattroff ( attribute window -- ) ptr>> (wattroff) ;
 360 : attroff ( attribute -- ) current-window get wattroff ;
 361
 362 : wall-attroff ( window -- ) [ A_NORMAL ] dip wattroff ;
 363 : all-attroff ( -- ) current-window get wall-attroff ;
 364
 365 : wccolor ( foreground background window -- )
 366     [
 367         2dup [ COLOR_WHITE = ] [ COLOR_BLACK = ] bi* and
 368         [ 2drop 0 ] [ register-color ] if ffi:COLOR_PAIR
 369     ] dip ptr>> (wattron) ;
 370
 371 : ccolor ( foreground background -- )
 372     current-window get wccolor ;