extra/curses/curses.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types alien.strings classes.struct
   4 combinators continuations destructors fry io.encodings.utf8
   5 kernel libc locals math memoize multiline namespaces sequences
   6 unix.ffi ;
   7
   8 QUALIFIED-WITH: curses.ffi ffi
   9
  10 IN: curses
  11
  12 SYMBOL: current-window
  13
  14 CONSTANT: COLOR_BLACK 0
  15 CONSTANT: COLOR_RED   1
  16 CONSTANT: COLOR_GREEN 2
  17 CONSTANT: COLOR_YELLO 3
  18 CONSTANT: COLOR_BLUE  4
  19 CONSTANT: COLOR_MAGEN 5
  20 CONSTANT: COLOR_CYAN  6
  21 CONSTANT: COLOR_WHITE 7
  22
  23 CONSTANT: A_NORMAL      0
  24 CONSTANT: A_ATTRIBUTES  -256
  25 CONSTANT: A_CHARTEXT    255
  26 CONSTANT: A_COLOR       65280
  27 CONSTANT: A_STANDOUT    65536
  28 CONSTANT: A_UNDERLINE   131072
  29 CONSTANT: A_REVERSE     262144
  30 CONSTANT: A_BLINK       524288
  31 CONSTANT: A_DIM         1048576
  32 CONSTANT: A_BOLD        2097152
  33 CONSTANT: A_ALTCHARSET  4194304
  34 CONSTANT: A_INVIS       8388608
  35 CONSTANT: A_PROTECT     16777216
  36 CONSTANT: A_HORIZONTAL  33554432
  37 CONSTANT: A_LEFT        67108864
  38 CONSTANT: A_LOW         134217728
  39 CONSTANT: A_RIGHT       268435456
  40 CONSTANT: A_TOP         536870912
  41 CONSTANT: A_VERTICAL    1073741824
  42
  43 CONSTANT: KEY_CODE_YES  OCT: 400  /* A wchar_t contains a key code */
  44 CONSTANT: KEY_MIN       OCT: 401  /* Minimum curses key */
  45 CONSTANT: KEY_BREAK     OCT: 401  /* Break key (unreliable) */
  46 CONSTANT: KEY_SRESET    OCT: 530  /* Soft (partial) reset (unreliable) */
  47 CONSTANT: KEY_RESET     OCT: 531  /* Reset or hard reset (unreliable) */
  48 CONSTANT: KEY_DOWN      OCT: 402  /* down-arrow key */
  49 CONSTANT: KEY_UP        OCT: 403  /* up-arrow key */
  50 CONSTANT: KEY_LEFT      OCT: 404  /* left-arrow key */
  51 CONSTANT: KEY_RIGHT     OCT: 405  /* right-arrow key */
  52 CONSTANT: KEY_HOME      OCT: 406  /* home key */
  53 CONSTANT: KEY_BACKSPACE OCT: 407  /* backspace key */
  54 CONSTANT: KEY_DL        OCT: 510  /* delete-line key */
  55 CONSTANT: KEY_IL        OCT: 511  /* insert-line key */
  56 CONSTANT: KEY_DC        OCT: 512  /* delete-character key */
  57 CONSTANT: KEY_IC        OCT: 513  /* insert-character key */
  58 CONSTANT: KEY_EIC       OCT: 514  /* sent by rmir or smir in insert mode */
  59 CONSTANT: KEY_CLEAR     OCT: 515  /* clear-screen or erase key */
  60 CONSTANT: KEY_EOS       OCT: 516  /* clear-to-end-of-screen key */
  61 CONSTANT: KEY_EOL       OCT: 517  /* clear-to-end-of-line key */
  62 CONSTANT: KEY_SF        OCT: 520  /* scroll-forward key */
  63 CONSTANT: KEY_SR        OCT: 521  /* scroll-backward key */
  64 CONSTANT: KEY_NPAGE     OCT: 522  /* next-page key */
  65 CONSTANT: KEY_PPAGE     OCT: 523  /* previous-page key */
  66 CONSTANT: KEY_STAB      OCT: 524  /* set-tab key */
  67 CONSTANT: KEY_CTAB      OCT: 525  /* clear-tab key */
  68 CONSTANT: KEY_CATAB     OCT: 526  /* clear-all-tabs key */
  69 CONSTANT: KEY_ENTER     OCT: 527  /* enter/send key */
  70 CONSTANT: KEY_PRINT     OCT: 532  /* print key */
  71 CONSTANT: KEY_LL        OCT: 533  /* lower-left key (home down) */
  72 CONSTANT: KEY_A1        OCT: 534  /* upper left of keypad */
  73 CONSTANT: KEY_A3        OCT: 535  /* upper right of keypad */
  74 CONSTANT: KEY_B2        OCT: 536  /* center of keypad */
  75 CONSTANT: KEY_C1        OCT: 537  /* lower left of keypad */
  76 CONSTANT: KEY_C3        OCT: 540  /* lower right of keypad */
  77 CONSTANT: KEY_BTAB      OCT: 541  /* back-tab key */
  78 CONSTANT: KEY_BEG       OCT: 542  /* begin key */
  79 CONSTANT: KEY_CANCEL    OCT: 543  /* cancel key */
  80 CONSTANT: KEY_CLOSE     OCT: 544  /* close key */
  81 CONSTANT: KEY_COMMAND   OCT: 545  /* command key */
  82 CONSTANT: KEY_COPY      OCT: 546  /* copy key */
  83 CONSTANT: KEY_CREATE    OCT: 547  /* create key */
  84 CONSTANT: KEY_END       OCT: 550  /* end key */
  85 CONSTANT: KEY_EXIT      OCT: 551  /* exit key */
  86 CONSTANT: KEY_FIND      OCT: 552  /* find key */
  87 CONSTANT: KEY_HELP      OCT: 553  /* help key */
  88 CONSTANT: KEY_MARK      OCT: 554  /* mark key */
  89 CONSTANT: KEY_MESSAGE   OCT: 555  /* message key */
  90 CONSTANT: KEY_MOVE      OCT: 556  /* move key */
  91 CONSTANT: KEY_NEXT      OCT: 557  /* next key */
  92 CONSTANT: KEY_OPEN      OCT: 560  /* open key */
  93 CONSTANT: KEY_OPTIONS   OCT: 561  /* options key */
  94 CONSTANT: KEY_PREVIOUS  OCT: 562  /* previous key */
  95 CONSTANT: KEY_REDO      OCT: 563  /* redo key */
  96 CONSTANT: KEY_REFERENCE OCT: 564  /* reference key */
  97 CONSTANT: KEY_REFRESH   OCT: 565  /* refresh key */
  98 CONSTANT: KEY_REPLACE   OCT: 566  /* replace key */
  99 CONSTANT: KEY_RESTART   OCT: 567  /* restart key */
 100 CONSTANT: KEY_RESUME    OCT: 570  /* resume key */
 101 CONSTANT: KEY_SAVE      OCT: 571  /* save key */
 102 CONSTANT: KEY_SBEG      OCT: 572  /* shifted begin key */
 103 CONSTANT: KEY_SCANCEL   OCT: 573  /* shifted cancel key */
 104 CONSTANT: KEY_SCOMMAND  OCT: 574  /* shifted command key */
 105 CONSTANT: KEY_SCOPY     OCT: 575  /* shifted copy key */
 106 CONSTANT: KEY_SCREATE   OCT: 576  /* shifted create key */
 107 CONSTANT: KEY_SDC       OCT: 577  /* shifted delete-character key */
 108 CONSTANT: KEY_SDL       OCT: 600  /* shifted delete-line key */
 109 CONSTANT: KEY_SELECT    OCT: 601  /* select key */
 110 CONSTANT: KEY_SEND      OCT: 602  /* shifted end key */
 111 CONSTANT: KEY_SEOL      OCT: 603  /* shifted clear-to-end-of-line key */
 112 CONSTANT: KEY_SEXIT     OCT: 604  /* shifted exit key */
 113 CONSTANT: KEY_SFIND     OCT: 605  /* shifted find key */
 114 CONSTANT: KEY_SHELP     OCT: 606  /* shifted help key */
 115 CONSTANT: KEY_SHOME     OCT: 607  /* shifted home key */
 116 CONSTANT: KEY_SIC       OCT: 610  /* shifted insert-character key */
 117 CONSTANT: KEY_SLEFT     OCT: 611  /* shifted left-arrow key */
 118 CONSTANT: KEY_SMESSAGE  OCT: 612  /* shifted message key */
 119 CONSTANT: KEY_SMOVE     OCT: 613  /* shifted move key */
 120 CONSTANT: KEY_SNEXT     OCT: 614  /* shifted next key */
 121 CONSTANT: KEY_SOPTIONS  OCT: 615  /* shifted options key */
 122 CONSTANT: KEY_SPREVIOUS OCT: 616  /* shifted previous key */
 123 CONSTANT: KEY_SPRINT    OCT: 617  /* shifted print key */
 124 CONSTANT: KEY_SREDO     OCT: 620  /* shifted redo key */
 125 CONSTANT: KEY_SREPLACE  OCT: 621  /* shifted replace key */
 126 CONSTANT: KEY_SRIGHT    OCT: 622  /* shifted right-arrow key */
 127 CONSTANT: KEY_SRSUME    OCT: 623  /* shifted resume key */
 128 CONSTANT: KEY_SSAVE     OCT: 624  /* shifted save key */
 129 CONSTANT: KEY_SSUSPEND  OCT: 625  /* shifted suspend key */
 130 CONSTANT: KEY_SUNDO     OCT: 626  /* shifted undo key */
 131 CONSTANT: KEY_SUSPEND   OCT: 627  /* suspend key */
 132 CONSTANT: KEY_UNDO      OCT: 630  /* undo key */
 133 CONSTANT: KEY_MOUSE     OCT: 631  /* Mouse event has occurred */
 134 CONSTANT: KEY_RESIZE    OCT: 632  /* Terminal resize event */
 135 CONSTANT: KEY_EVENT     OCT: 633  /* We were interrupted by an event */
 136 CONSTANT: KEY_MAX       OCT: 777  /* Maximum key value is 0633 */
 137 CONSTANT: KEY_F0        OCT: 410  /* Function keys.  Space for 64 */
 138 : KEY_F ( n -- code ) KEY_F0 + ; inline /* Value of function key n */
 139
 140 : BUTTON1_RELEASED       ( -- mask ) 1 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 141 : BUTTON1_PRESSED        ( -- mask ) 1 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 142 : BUTTON1_CLICKED        ( -- mask ) 1 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 143 : BUTTON1_DOUBLE_CLICKED ( -- mask ) 1 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 144 : BUTTON1_TRIPLE_CLICKED ( -- mask ) 1 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 145 : BUTTON2_RELEASED       ( -- mask ) 2 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 146 : BUTTON2_PRESSED        ( -- mask ) 2 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 147 : BUTTON2_CLICKED        ( -- mask ) 2 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 148 : BUTTON2_DOUBLE_CLICKED ( -- mask ) 2 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 149 : BUTTON2_TRIPLE_CLICKED ( -- mask ) 2 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 150 : BUTTON3_RELEASED       ( -- mask ) 3 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 151 : BUTTON3_PRESSED        ( -- mask ) 3 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 152 : BUTTON3_CLICKED        ( -- mask ) 3 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 153 : BUTTON3_DOUBLE_CLICKED ( -- mask ) 3 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 154 : BUTTON3_TRIPLE_CLICKED ( -- mask ) 3 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 155 : BUTTON4_RELEASED       ( -- mask ) 4 ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK ; inline
 156 : BUTTON4_PRESSED        ( -- mask ) 4 ffi:NCURSES_BUTTON_PRESSED  ffi:NCURSES_MOUSE_MASK ; inline
 157 : BUTTON4_CLICKED        ( -- mask ) 4 ffi:NCURSES_BUTTON_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 158 : BUTTON4_DOUBLE_CLICKED ( -- mask ) 4 ffi:NCURSES_DOUBLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 159 : BUTTON4_TRIPLE_CLICKED ( -- mask ) 4 ffi:NCURSES_TRIPLE_CLICKED  ffi:NCURSES_MOUSE_MASK ; inline
 160
 161 : BUTTON1_RESERVED_EVENT ( -- mask ) 1 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 162 : BUTTON2_RESERVED_EVENT ( -- mask ) 2 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 163 : BUTTON3_RESERVED_EVENT ( -- mask ) 3 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 164 : BUTTON4_RESERVED_EVENT ( -- mask ) 4 ffi:NCURSES_RESERVED_EVENT ffi:NCURSES_MOUSE_MASK ; inline
 165
 166 : BUTTON_CTRL            ( -- mask ) 5 OCT: 01 ffi:NCURSES_MOUSE_MASK ; inline
 167 : BUTTON_SHIFT           ( -- mask ) 5 OCT: 02 ffi:NCURSES_MOUSE_MASK ; inline
 168 : BUTTON_ALT             ( -- mask ) 5 OCT: 04 ffi:NCURSES_MOUSE_MASK ; inline
 169 : REPORT_MOUSE_POSITION  ( -- mask ) 5 OCT: 10 ffi:NCURSES_MOUSE_MASK ; inline
 170
 171 : ALL_MOUSE_EVENTS ( -- mask ) REPORT_MOUSE_POSITION 1 - ; inline
 172
 173 ERROR: curses-failed ;
 174 ERROR: unsupported-curses-terminal ;
 175
 176 <PRIVATE
 177
 178 : >BOOLEAN ( ? -- TRUE/FALSE ) ffi:TRUE ffi:FALSE ? ; inline
 179
 180 : curses-pointer-error ( ptr/f -- ptr )
 181     [ curses-failed ] unless* ; inline
 182 : curses-error ( n -- ) ffi:ERR = [ curses-failed ] when ;
 183
 184 PRIVATE>
 185
 186 : curses-ok? ( -- ? )
 187     { 0 1 2 } [ isatty 0 = not ] all? ;
 188
 189 TUPLE: curses-window < disposable
 190     ptr
 191     parent-window
 192     { lines integer initial: 0 }
 193     { columns integer initial: 0 }
 194     { y integer initial: 0 }
 195     { x integer initial: 0 }
 196
 197     { cbreak initial: t }
 198     { echo initial: f }
 199     { raw initial: f }
 200
 201     { scrollok initial: t }
 202     { leaveok initial: f }
 203
 204     idcok idlok immedok
 205     { keypad initial: t }
 206
 207     { encoding initial: utf8 } ;
 208
 209 : <curses-window> ( -- window )
 210     curses-window new-disposable ;
 211
 212 M: curses-window dispose* ( window -- )
 213     ptr>> ffi:delwin curses-error ;
 214
 215 <PRIVATE
 216
 217 : window-params ( window -- lines columns y x )
 218     { [ lines>> ] [ columns>> ] [ y>> ] [ x>> ] } cleave ;
 219
 220 : set-cbreak/raw ( cbreak raw -- )
 221     [ drop ffi:raw ] [
 222         [ ffi:cbreak ] [ ffi:nocbreak ] if
 223     ] if curses-error ;
 224
 225 : apply-window-options ( window -- )
 226     {
 227         [ [ ptr>> ] [ scrollok>> >BOOLEAN ] bi ffi:scrollok curses-error ]
 228         [ [ ptr>> ] [ leaveok>> >BOOLEAN ] bi ffi:leaveok curses-error ]
 229         [ [ ptr>> ] [ keypad>> >BOOLEAN ] bi ffi:keypad curses-error ]
 230     } cleave ;
 231
 232 : apply-global-options ( window -- )
 233     [ [ cbreak>> ] [ raw>> ] bi set-cbreak/raw ]
 234     [ echo>> [ ffi:echo ] [ ffi:noecho ] if curses-error ]
 235     bi ;
 236
 237 SYMBOL: n-registered-colors
 238
 239 MEMO: register-color ( fg bg -- n )
 240     [ n-registered-colors get dup ] 2dip ffi:init_pair curses-error
 241     n-registered-colors inc ;
 242
 243 : init-colors ( -- )
 244     ffi:has_colors [
 245         1 n-registered-colors set
 246         \ register-color reset-memoized
 247         ffi:start_color curses-error
 248         ffi:stdscr 0 f ffi:wcolor_set curses-error
 249     ] when ;
 250
 251 PRIVATE>
 252
 253 : setup-window ( window -- window )
 254     [
 255         dup [ window-params ] keep
 256         parent-window>> [ ptr>> ffi:derwin ] [ ffi:newwin ] if*
 257         curses-pointer-error >>ptr &dispose
 258     ] [ apply-window-options ] bi ;
 259
 260 : with-window ( window quot -- )
 261     [ current-window ] dip with-variable ; inline
 262
 263 : with-curses ( window quot -- )
 264     curses-ok? [ unsupported-curses-terminal ] unless
 265     [
 266         '[
 267             ffi:initscr curses-pointer-error
 268             >>ptr
 269             {
 270                 [ apply-global-options ]
 271                 [ apply-window-options ]
 272                 [ ptr>> ffi:wclear curses-error ]
 273                 [ ptr>> ffi:wrefresh curses-error ]
 274                 [ ]
 275             } cleave
 276             init-colors
 277
 278             _ with-window
 279         ] [ ffi:endwin curses-error ] [ ] cleanup
 280     ] with-destructors ; inline
 281
 282 <PRIVATE
 283
 284 : (wcrefresh) ( window-ptr -- )
 285     ffi:wrefresh curses-error ; inline
 286
 287 : (wcwrite) ( string window-ptr -- )
 288     swap ffi:waddstr curses-error ; inline
 289
 290 :: (wcread) ( n encoding window-ptr -- string )
 291     [
 292         n 1 + malloc &free :> str
 293         window-ptr str n ffi:wgetnstr curses-error
 294         str encoding alien>string
 295     ] with-destructors ; inline
 296
 297 : (wcmove) ( y x window-ptr -- )
 298     -rot ffi:wmove curses-error ; inline
 299
 300 : (winsert-blank-line) ( y window-ptr -- )
 301     [ 0 swap (wcmove) ]
 302     [ ffi:winsertln curses-error ] bi ; inline
 303
 304 : (waddch) ( ch window-ptr -- )
 305     swap ffi:waddch curses-error ; inline
 306
 307 : (wgetch) ( window -- key )
 308     ffi:wgetch [ curses-error ] keep ; inline
 309
 310 : (wattroff) ( attribute window-ptr -- )
 311     swap ffi:wattroff curses-error ; inline
 312
 313 : (wattron) ( attribute window-ptr -- )
 314     swap ffi:wattron curses-error ; inline
 315
 316 PRIVATE>
 317
 318 : wcrefresh ( window -- ) ptr>> (wcrefresh) ;
 319 : crefresh ( -- ) current-window get wcrefresh ;
 320
 321 : wgetch ( window -- key ) ptr>> (wgetch) ;
 322 : getch ( -- key ) current-window get wgetch ;
 323
 324 : waddch ( ch window -- ) ptr>> (waddch) ;
 325 : addch ( ch -- ) current-window get waddch ;
 326
 327 : wcnl ( window -- ) [ CHAR: \n ] dip waddch ;
 328 : cnl ( -- ) current-window get wcnl ;
 329
 330 : wcwrite ( string window -- ) ptr>> (wcwrite) ;
 331 : cwrite ( string -- ) current-window get wcwrite ;
 332
 333 : wcprint ( string window -- )
 334     ptr>> [ (wcwrite) ] [ CHAR: \n swap (waddch) ] bi ;
 335 : cprint ( string -- ) current-window get wcprint ;
 336
 337 : wcprintf ( string window -- )
 338     ptr>> [ (wcwrite) ] [ CHAR: \n swap (waddch) ]
 339     [ (wcrefresh) ] tri ;
 340 : cprintf ( string -- ) current-window get wcprintf ;
 341
 342 : wcwritef ( string window -- )
 343     ptr>> [ (wcwrite) ] [ (wcrefresh) ] bi ;
 344 : cwritef ( string -- ) current-window get wcwritef ;
 345
 346 : wcread ( n window -- string )
 347     [ encoding>> ] [ ptr>> ] bi (wcread) ;
 348 : cread ( n -- string ) current-window get wcread ;
 349
 350 : werase ( window -- ) ptr>> ffi:werase curses-error ;
 351 : erase ( -- ) current-window get werase ;
 352
 353 : wcmove ( y x window -- )
 354     ptr>> [ (wcmove) ] [ (wcrefresh) ] bi ;
 355 : cmove ( y x -- ) current-window get wcmove ;
 356
 357 : wdelete-line ( y window -- )
 358     ptr>> [ 0 swap (wcmove) ] [ ffi:wdeleteln curses-error ] bi ;
 359 : delete-line ( y -- ) current-window get wdelete-line ;
 360
 361 : winsert-blank-line ( y window -- )
 362     ptr>> (winsert-blank-line) ;
 363 : insert-blank-line ( y -- )
 364     current-window get winsert-blank-line ;
 365
 366 : winsert-line ( string y window -- )
 367     ptr>> [ (winsert-blank-line) ] [ (wcwrite) ] bi ;
 368 : insert-line ( string y -- )
 369     current-window get winsert-line ;
 370
 371 : wattron ( attribute window -- ) ptr>> (wattron) ;
 372 : attron ( attribute -- ) current-window get wattron ;
 373
 374 : wattroff ( attribute window -- ) ptr>> (wattroff) ;
 375 : attroff ( attribute -- ) current-window get wattroff ;
 376
 377 : wall-attroff ( window -- ) [ A_NORMAL ] dip wattroff ;
 378 : all-attroff ( -- ) current-window get wall-attroff ;
 379
 380 : wccolor ( foreground background window -- )
 381     [ register-color ] dip ptr>> swap f ffi:wcolor_set curses-error ;
 382
 383 : ccolor ( foreground background -- )
 384     current-window get wccolor ;
 385
 386 : wccbox ( window -- )
 387     ptr>> 0 0 ffi:box curses-error ;
 388 : cbox ( -- )
 389     current-window get wccbox ;
 390
 391 SYMBOLS: +pressed+ +released+ +clicked+ +double+ +triple+ ;
 392
 393 TUPLE: mouse-event
 394     { id fixnum }
 395     { y fixnum }
 396     { x fixnum }
 397     { button fixnum }
 398     type
 399     alt
 400     shift
 401     ctrl ;
 402
 403 <PRIVATE
 404
 405 : substate-n ( bstate n -- substate )
 406     [ 1 + ffi:NCURSES_BUTTON_RELEASED ffi:NCURSES_MOUSE_MASK 1 - bitand ] keep
 407     1 - -6 * shift ; inline
 408
 409 : button-n? ( bstate n -- ? ) substate-n 0 = not ; inline
 410
 411 : fill-in-type ( mouse-event bstate button -- )
 412     substate-n {
 413         { BUTTON1_RELEASED       [ +released+ ] }
 414         { BUTTON1_PRESSED        [ +pressed+ ] }
 415         { BUTTON1_CLICKED        [ +clicked+ ] }
 416         { BUTTON1_DOUBLE_CLICKED [ +double+ ] }
 417         { BUTTON1_TRIPLE_CLICKED [ +triple+ ] }
 418     } case >>type drop ; inline
 419
 420 : fill-in-bstate ( mouse-event bstate -- )
 421     2dup {
 422         { [ dup 1 button-n? ] [ [ 1 >>button ] dip 1 fill-in-type ] }
 423         { [ dup 2 button-n? ] [ [ 2 >>button ] dip 2 fill-in-type ] }
 424         { [ dup 3 button-n? ] [ [ 3 >>button ] dip 3 fill-in-type ] }
 425         { [ dup 4 button-n? ] [ [ 4 >>button ] dip 4 fill-in-type ] }
 426     } cond
 427     {
 428         [ BUTTON_CTRL  bitand 0 = not [ t >>ctrl  ] when drop ]
 429         [ BUTTON_SHIFT bitand 0 = not [ t >>shift ] when drop ]
 430         [ BUTTON_ALT   bitand 0 = not [ t >>alt   ] when drop ]
 431     } 2cleave ;
 432
 433 : <mouse-event> ( MEVENT -- mouse-event )
 434     [ mouse-event new ] dip {
 435         [ id>> >>id drop ]
 436         [ y>> >>y drop ]
 437         [ x>> >>x drop ]
 438         [ bstate>> fill-in-bstate ]
 439         [ drop ]
 440     } 2cleave ;
 441
 442 PRIVATE>
 443
 444 : getmouse ( -- mouse-event/f )
 445     [
 446         ffi:MEVENT malloc-struct &free
 447         dup ffi:getmouse
 448         ffi:ERR = [ drop f ] [ <mouse-event> ] if
 449     ] with-destructors ;
 450
 451 : mousemask ( mask -- newmask oldmask )
 452     0 <ulong> [ ffi:mousemask ] keep *ulong ;
 453
 454 : wget-yx ( window -- y x )
 455     ptr>> [ _cury>> ] [ _curx>> ] bi ;
 456 : get-yx ( -- y x )
 457     current-window get wget-yx ;
 458
 459 : wget-y ( window -- y )
 460     ptr>> _cury>> ;
 461 : get-y ( -- y )
 462     current-window get wget-y ;
 463 : wget-x ( window -- x )
 464     ptr>> _curx>> ;
 465 : get-x ( -- x )
 466     current-window get wget-x ;
 467
 468 : wget-max-yx ( window -- y x )
 469     ptr>> [ _maxy>> 1 + ] [ _maxx>> 1 + ] bi ;
 470 : get-max-yx ( -- y x )
 471     current-window get wget-max-yx ;
 472
 473 : wget-max-y ( window -- y )
 474     ptr>> _maxy>> 1 + ;
 475 : get-max-y ( -- y )
 476     current-window get wget-max-y ;
 477 : wget-max-x ( window -- x )
 478     ptr>> _maxx>> 1 + ;
 479 : get-max-x ( -- x )
 480     current-window get wget-max-x ;