extra/dns/dns.factor

   1 ! Copyright (C) 2010 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.enums alien.syntax arrays assocs
   4 byte-arrays calendar combinators combinators.smart constructors
   5 destructors fry grouping io io.binary io.buffers
   6 io.encodings.binary io.encodings.string io.encodings.utf8
   7 io.files io.ports io.sockets io.sockets.private
   8 io.streams.byte-array io.timeouts kernel make math math.bitwise
   9 math.parser math.ranges math.statistics memoize namespaces
  10 nested-comments random sequences slots.syntax splitting strings
  11 system unicode.categories vectors vocabs.loader unicode.case ;
  12 IN: dns
  13
  14 ENUM: dns-type
  15 { A 1 } { NS 2 } { MD 3 } { MF 4 }
  16 { CNAME 5 } { SOA 6 } { MB 7 } { MG 8 }
  17 { MR 9 } { NULL 10 } { WKS 11 } { PTR 12 }
  18 { HINFO 13 } { MINFO 14 } { MX 15 } { TXT 16 }
  19 { RP 17 } { AFSDB 18 } { SIG 24 } { KEY 25 }
  20 { AAAA 28 } { LOC 29 } { SVR 33 } { NAPTR 35 }
  21 { KX 36 } { CERT 37 } { DNAME 39 } { OPT 41 }
  22 { APL 42 } { DS 43 } { SSHFP 44 } { IPSECKEY 45 }
  23 { RRSIG 46 } { NSEC 47 } { DNSKEY 48 } { DHCID 49 }
  24 { NSEC3 50 } { NSEC3PARAM 51 } { HIP 55 } { SPF 99 }
  25 { TKEY 249 } { TSIG 250 } { IXFR 251 }
  26 { TA 32768 } { DLV 32769 } ;
  27
  28 ENUM: dns-class { IN 1 } { CS 2 } { CH 3 } { HS 4 } ;
  29
  30 ENUM: dns-opcode QUERY IQUERY STATUS ;
  31
  32 ENUM: dns-rcode NO-ERROR FORMAT-ERROR SERVER-FAILURE
  33 NAME-ERROR NOT-IMPLEMENTED REFUSED ;
  34
  35 SYMBOL: dns-servers
  36
  37 : add-dns-server ( string -- )
  38     dns-servers get push ;
  39
  40 : remove-dns-server ( string -- )
  41     dns-servers get remove! drop ;
  42
  43 : clear-dns-servers ( -- )
  44     V{ } clone dns-servers set-global ;
  45
  46 : >dotted ( domain -- domain' )
  47     dup "." tail? [ "." append ] unless ;
  48
  49 : dotted> ( string -- string' )
  50     "." ?tail drop ;
  51
  52 TUPLE: query name type class ;
  53 CONSTRUCTOR: query ( name type class -- obj )
  54     [ >dotted ] change-name ;
  55
  56 TUPLE: rr name type class ttl rdata ;
  57
  58 TUPLE: hinfo cpu os ;
  59
  60 TUPLE: mx preference exchange ;
  61
  62 TUPLE: soa mname rname serial refresh retry expire minimum ;
  63
  64 TUPLE: a name ;
  65 CONSTRUCTOR: a ( name -- obj ) ;
  66
  67 TUPLE: aaaa name ;
  68 CONSTRUCTOR: aaaa ( name -- obj ) ;
  69
  70 TUPLE: cname name ;
  71 CONSTRUCTOR: cname ( name -- obj ) ;
  72
  73 TUPLE: ptr name ;
  74 CONSTRUCTOR: ptr ( name -- obj ) ;
  75
  76 TUPLE: ns name ;
  77 CONSTRUCTOR: ns ( name -- obj ) ;
  78
  79 TUPLE: message id qr opcode aa tc rd ra z rcode
  80 query answer-section authority-section additional-section ;
  81
  82 CONSTRUCTOR: message ( query -- obj )
  83     16 2^ random >>id
  84     0 >>qr
  85     QUERY >>opcode
  86     0 >>aa
  87     0 >>tc
  88     1 >>rd
  89     0 >>ra
  90     0 >>z
  91     NO-ERROR >>rcode
  92     [ dup sequence? [ 1array ] unless ] change-query
  93     { } >>answer-section
  94     { } >>authority-section
  95     { } >>additional-section ;
  96
  97 : message>header ( message -- n )
  98     [
  99         {
 100             [ qr>> 15 shift ]
 101             [ opcode>> enum>number 11 shift ]
 102             [ aa>> 10 shift ]
 103             [ tc>> 9 shift ]
 104             [ rd>> 8 shift ]
 105             [ ra>> 7 shift ]
 106             [ z>> 4 shift ]
 107             [ rcode>> enum>number 0 shift ]
 108         } cleave
 109     ] sum-outputs ;
 110
 111 : header>message-parts ( n -- qr opcode aa tc rd ra z rcode )
 112     {
 113         [ -15 shift BIN: 1 bitand ]
 114         [ -11 shift BIN: 111 bitand <dns-opcode> ]
 115         [ -10 shift BIN: 1 bitand ]
 116         [ -9 shift BIN: 1 bitand ]
 117         [ -8 shift BIN: 1 bitand ]
 118         [ -7 shift BIN: 1 bitand ]
 119         [ -4 shift BIN: 111 bitand ]
 120         [ BIN: 1111 bitand <dns-rcode> ]
 121     } cleave ;
 122
 123 : byte-array>ipv4 ( byte-array -- string )
 124     [ number>string ] { } map-as "." join ;
 125
 126 : byte-array>ipv6 ( byte-array -- string )
 127     2 group [ be> >hex ] { } map-as ":" join ;
 128
 129 : ipv4>byte-array ( string -- byte-array )
 130     "." split [ string>number ] B{ } map-as ;
 131
 132 : ipv6>byte-array ( string -- byte-array )
 133     T{ inet6 } inet-pton ;
 134
 135 : expand-ipv6 ( ipv6 -- ipv6' ) ipv6>byte-array byte-array>ipv6 ;
 136
 137 : reverse-ipv4 ( string -- string )
 138     ipv4>byte-array reverse byte-array>ipv4 ;
 139
 140 CONSTANT: ipv4-arpa-suffix ".in-addr.arpa"
 141
 142 : ipv4>arpa ( string -- string )
 143     reverse-ipv4 ipv4-arpa-suffix append ;
 144
 145 CONSTANT: ipv6-arpa-suffix ".ip6.arpa"
 146
 147 : ipv6>arpa ( string -- string )
 148     ipv6>byte-array [ [ -4 shift 4 bits ] [ 4 bits ] bi 2array ] { } map-as
 149     B{ } concat-as reverse
 150     [ >hex ] { } map-as "." join ipv6-arpa-suffix append ;
 151
 152 : trim-ipv4-arpa ( string -- string' )
 153     dotted> ipv4-arpa-suffix ?tail drop ;
 154
 155 : trim-ipv6-arpa ( string -- string' )
 156     dotted> ipv6-arpa-suffix ?tail drop ;
 157
 158 : arpa>ipv4 ( string -- ip ) trim-ipv4-arpa reverse-ipv4 ;
 159
 160 : arpa>ipv6 ( string -- ip )
 161     trim-ipv6-arpa "." split 2 group reverse
 162     [
 163         first2 swap [ hex> ] bi@ [ 4 shift ] [ ] bi* bitor
 164     ] B{ } map-as byte-array>ipv6 ;
 165
 166 : parse-length-bytes ( -- seq ) read1 read utf8 decode ;
 167
 168 : (parse-name) ( -- )
 169     peek1 [
 170         read1 drop
 171     ] [
 172         HEX: C0 mask? [
 173             2 read be> HEX: 3fff bitand
 174             seek-absolute [ parse-length-bytes , (parse-name) ] with-input-seek
 175         ] [
 176             parse-length-bytes , (parse-name)
 177         ] if
 178     ] if-zero ;
 179
 180 : parse-name ( -- seq )
 181     [ (parse-name) ] { } make "." join ;
 182
 183 : parse-query ( -- query )
 184     parse-name
 185     2 read be> <dns-type>
 186     2 read be> <dns-class> <query> ;
 187
 188 : parse-soa ( -- soa )
 189     soa new
 190         parse-name >>mname
 191         parse-name >>rname
 192         4 read be> >>serial
 193         4 read be> >>refresh
 194         4 read be> >>retry
 195         4 read be> >>expire
 196         4 read be> >>minimum ;
 197
 198 : parse-mx ( -- mx )
 199     mx new
 200         2 read be> >>preference
 201         parse-name >>exchange ;
 202
 203 GENERIC: parse-rdata ( n type -- obj )
 204
 205 M: object parse-rdata drop read ;
 206 M: A parse-rdata 2drop 4 read byte-array>ipv4 <a> ;
 207 M: AAAA parse-rdata 2drop 16 read byte-array>ipv6 <aaaa> ;
 208 M: CNAME parse-rdata 2drop parse-name <cname> ;
 209 M: MX parse-rdata 2drop parse-mx ;
 210 M: NS parse-rdata 2drop parse-name <ns> ;
 211 M: PTR parse-rdata 2drop parse-name <ptr> ;
 212 M: SOA parse-rdata 2drop parse-soa ;
 213
 214 : parse-rr ( -- rr )
 215     rr new
 216         parse-name >>name
 217         2 read be> <dns-type> >>type
 218         2 read be> <dns-class> >>class
 219         4 read be> >>ttl
 220         2 read be> over type>> parse-rdata >>rdata ;
 221
 222 : parse-message ( ba -- message )
 223     [ message new ] dip
 224     binary [
 225         2 read be> >>id
 226         2 read be> header>message-parts set-slots[ qr opcode aa tc rd ra z rcode ]
 227         2 read be> >>query
 228         2 read be> >>answer-section
 229         2 read be> >>authority-section
 230         2 read be> >>additional-section
 231         [ [ parse-query ] replicate ] change-query
 232         [ [ parse-rr ] replicate ] change-answer-section
 233         [ [ parse-rr ] replicate ] change-authority-section
 234         [ [ parse-rr ] replicate ] change-additional-section
 235     ] with-byte-reader ;
 236
 237 : >n/label ( string -- ba )
 238     [ length 1array ] [ utf8 encode ] bi B{ } append-as ;
 239
 240 : >name ( dn -- ba ) "." split [ >n/label ] map concat ;
 241
 242 : query>byte-array ( query -- ba )
 243     [
 244         {
 245             [ name>> >name ]
 246             [ type>> enum>number 2 >be ]
 247             [ class>> enum>number 2 >be ]
 248         } cleave
 249     ] B{ } append-outputs-as ;
 250
 251 GENERIC: rdata>byte-array ( rdata type -- obj )
 252
 253 M: A rdata>byte-array drop ipv4>byte-array ;
 254
 255 M: CNAME rdata>byte-array drop >name ;
 256
 257 M: HINFO rdata>byte-array
 258     drop
 259     [ cpu>> >name ]
 260     [ os>> >name ] bi append ;
 261
 262 M: MX rdata>byte-array
 263     drop
 264     [ preference>> 2 >be ]
 265     [ exchange>> >name ] bi append ;
 266
 267 M: NS rdata>byte-array drop >name ;
 268
 269 M: PTR rdata>byte-array drop >name ;
 270
 271 M: SOA rdata>byte-array
 272     drop
 273     [
 274         {
 275             [ mname>> >name ]
 276             [ rname>> >name ]
 277             [ serial>> 4 >be ]
 278             [ refresh>> 4 >be ]
 279             [ retry>> 4 >be ]
 280             [ expire>> 4 >be ]
 281             [ minimum>> 4 >be ]
 282         } cleave
 283     ] B{ } append-outputs-as ;
 284
 285 : rr>byte-array ( rr -- ba )
 286     [
 287         {
 288             [ name>> >name ]
 289             [ type>> enum>number 2 >be ]
 290             [ class>> enum>number 2 >be ]
 291             [ ttl>> 4 >be ]
 292             [
 293                 [ rdata>> ] [ type>> ] bi rdata>byte-array
 294                 [ length 2 >be ] [ ] bi append
 295             ]
 296         } cleave
 297     ] B{ } append-outputs-as ;
 298
 299 : message>byte-array ( message -- ba )
 300     [
 301         {
 302             [ id>> 2 >be ]
 303             [ message>header 2 >be ]
 304             [ query>> length 2 >be ]
 305             [ answer-section>> length 2 >be ]
 306             [ authority-section>> length 2 >be ]
 307             [ additional-section>> length 2 >be ]
 308             [ query>> [ query>byte-array ] map concat ]
 309             [ answer-section>> [ rr>byte-array ] map concat ]
 310             [ authority-section>> [ rr>byte-array ] map concat ]
 311             [ additional-section>> [ rr>byte-array ] map concat ]
 312         } cleave
 313     ] B{ } append-outputs-as ;
 314
 315 : udp-query ( bytes server -- bytes' )
 316     f 0 <inet4> <datagram>
 317     30 seconds over set-timeout [
 318         [ send ] [ receive drop ] bi
 319     ] with-disposal ;
 320
 321 : <dns-inet4> ( -- inet4 )
 322     dns-servers get random 53 <inet4> ;
 323
 324 : dns-query ( query -- message )
 325     <message> message>byte-array
 326     <dns-inet4> udp-query parse-message ;
 327
 328 : dns-A-query ( domain -- message ) A IN <query> dns-query ;
 329 : dns-AAAA-query ( domain -- message ) AAAA IN <query> dns-query ;
 330 : dns-MX-query ( domain -- message ) MX IN <query> dns-query ;
 331 : dns-NS-query ( domain -- message ) NS IN <query> dns-query ;
 332
 333 : reverse-lookup ( reversed-ip -- message )
 334     PTR IN <query> dns-query ;
 335
 336 : reverse-ipv4-lookup ( ip -- message )
 337     ipv4>arpa reverse-lookup ;
 338
 339 : reverse-ipv6-lookup ( ip -- message )
 340     ipv6>arpa reverse-lookup ;
 341
 342 : message>names ( message -- names )
 343     answer-section>> [ rdata>> name>> ] map ;
 344
 345 : message>a-names ( message -- names )
 346     answer-section>>
 347     [ rdata>> ] map [ a? ] filter [ name>> ] map ;
 348
 349 : message>mxs ( message -- assoc )
 350     answer-section>> [ rdata>> [ preference>> ] [ exchange>> ] bi 2array ] map ;
 351
 352 : messages>names ( messages -- names )
 353     [ message>names ] map concat ;
 354
 355 : forward-confirmed-reverse-dns-ipv4? ( ipv4-string -- ? )
 356     dup reverse-ipv4-lookup message>names
 357     [ dns-A-query ] map messages>names member? ;
 358
 359 : forward-confirmed-reverse-dns-ipv6? ( ipv6-string -- ? )
 360     expand-ipv6
 361     dup reverse-ipv6-lookup message>names
 362     [ dns-AAAA-query ] map messages>names member? ;
 363
 364 : message>query-name ( message -- string )
 365     query>> first name>> dotted> ;
 366
 367 USE: nested-comments
 368 (*
 369 M: string resolve-host
 370     dup >lower "localhost" = [
 371         drop resolve-localhost
 372     ] [
 373         dns-A-query message>a-names [ <ipv4> ] map
 374     ] if ;
 375 *)
 376
 377 HOOK: initial-dns-servers os ( -- seq )
 378
 379 {
 380     { [ os windows? ] [ "dns.windows" ] }
 381     { [ os unix? ] [ "dns.unix" ] }
 382 } cond require
 383
 384 dns-servers [ initial-dns-servers >vector ] initialize