extra/dns/dns.factor

   1 ! Copyright (C) 2010 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.enums alien.syntax arrays calendar
   4 combinators combinators.smart constructors destructors grouping
   5 io io.binary io.encodings.binary io.encodings.string
   6 io.encodings.utf8 io.sockets io.sockets.private
   7 io.streams.byte-array io.timeouts kernel make math math.bitwise
   8 math.parser namespaces random sequences slots.syntax splitting
   9 system vectors vocabs strings ascii ;
  10 IN: dns
  11
  12 : with-input-seek ( n seek-type quot -- )
  13     tell-input [
  14         [ seek-input ] dip call
  15     ] dip seek-absolute seek-input ; inline
  16
  17 ENUM: dns-type
  18 { A 1 } { NS 2 } { MD 3 } { MF 4 }
  19 { CNAME 5 } { SOA 6 } { MB 7 } { MG 8 }
  20 { MR 9 } { NULL 10 } { WKS 11 } { PTR 12 }
  21 { HINFO 13 } { MINFO 14 } { MX 15 } { TXT 16 }
  22 { RP 17 } { AFSDB 18 } { SIG 24 } { KEY 25 }
  23 { AAAA 28 } { LOC 29 } { SVR 33 } { NAPTR 35 }
  24 { KX 36 } { CERT 37 } { DNAME 39 } { OPT 41 }
  25 { APL 42 } { DS 43 } { SSHFP 44 } { IPSECKEY 45 }
  26 { RRSIG 46 } { NSEC 47 } { DNSKEY 48 } { DHCID 49 }
  27 { NSEC3 50 } { NSEC3PARAM 51 } { HIP 55 } { SPF 99 }
  28 { TKEY 249 } { TSIG 250 } { IXFR 251 }
  29 { TA 32768 } { DLV 32769 } ;
  30
  31 ENUM: dns-class { IN 1 } { CS 2 } { CH 3 } { HS 4 } ;
  32
  33 ENUM: dns-opcode QUERY IQUERY STATUS ;
  34
  35 ENUM: dns-rcode NO-ERROR FORMAT-ERROR SERVER-FAILURE
  36 NAME-ERROR NOT-IMPLEMENTED REFUSED ;
  37
  38 SYMBOL: dns-servers
  39
  40 : add-dns-server ( string -- )
  41     dns-servers get push ;
  42
  43 : remove-dns-server ( string -- )
  44     dns-servers get remove! drop ;
  45
  46 : clear-dns-servers ( -- )
  47     V{ } clone dns-servers set-global ;
  48
  49 : >dotted ( domain -- domain' )
  50     dup "." tail? [ "." append ] unless ;
  51
  52 : dotted> ( string -- string' )
  53     "." ?tail drop ;
  54
  55 TUPLE: query name type class ;
  56 CONSTRUCTOR: <query> query ( name type class -- obj )
  57     [ >dotted ] change-name ;
  58
  59 TUPLE: rr name type class ttl rdata ;
  60
  61 TUPLE: hinfo cpu os ;
  62
  63 TUPLE: mx preference exchange ;
  64
  65 TUPLE: soa mname rname serial refresh retry expire minimum ;
  66
  67 TUPLE: a name ;
  68 CONSTRUCTOR: <a> a ( name -- obj ) ;
  69
  70 TUPLE: aaaa name ;
  71 CONSTRUCTOR: <aaaa> aaaa ( name -- obj ) ;
  72
  73 TUPLE: cname name ;
  74 CONSTRUCTOR: <cname> cname ( name -- obj ) ;
  75
  76 TUPLE: ptr name ;
  77 CONSTRUCTOR: <ptr> ptr ( name -- obj ) ;
  78
  79 TUPLE: ns name ;
  80 CONSTRUCTOR: <ns> ns ( name -- obj ) ;
  81
  82 TUPLE: message id qr opcode aa tc rd ra z rcode
  83 query answer-section authority-section additional-section ;
  84
  85 CONSTRUCTOR: <message> message ( query -- obj )
  86     16 2^ random >>id
  87     0 >>qr
  88     QUERY >>opcode
  89     0 >>aa
  90     0 >>tc
  91     1 >>rd
  92     0 >>ra
  93     0 >>z
  94     NO-ERROR >>rcode
  95     [ dup sequence? [ 1array ] unless ] change-query
  96     { } >>answer-section
  97     { } >>authority-section
  98     { } >>additional-section ;
  99
 100 : message>header ( message -- n )
 101     [
 102         {
 103             [ qr>> 15 shift ]
 104             [ opcode>> enum>number 11 shift ]
 105             [ aa>> 10 shift ]
 106             [ tc>> 9 shift ]
 107             [ rd>> 8 shift ]
 108             [ ra>> 7 shift ]
 109             [ z>> 4 shift ]
 110             [ rcode>> enum>number 0 shift ]
 111         } cleave
 112     ] sum-outputs ;
 113
 114 : header>message-parts ( n -- qr opcode aa tc rd ra z rcode )
 115     {
 116         [ -15 shift 0b1 bitand ]
 117         [ -11 shift 0b111 bitand <dns-opcode> ]
 118         [ -10 shift 0b1 bitand ]
 119         [ -9 shift 0b1 bitand ]
 120         [ -8 shift 0b1 bitand ]
 121         [ -7 shift 0b1 bitand ]
 122         [ -4 shift 0b111 bitand ]
 123         [ 0b1111 bitand <dns-rcode> ]
 124     } cleave ;
 125
 126 : byte-array>ipv4 ( byte-array -- string )
 127     [ number>string ] { } map-as "." join ;
 128
 129 : byte-array>ipv6 ( byte-array -- string )
 130     2 group [ be> >hex ] { } map-as ":" join ;
 131
 132 : ipv4>byte-array ( string -- byte-array )
 133     "." split [ string>number ] B{ } map-as ;
 134
 135 : ipv6>byte-array ( string -- byte-array )
 136     T{ inet6 } inet-pton ;
 137
 138 : expand-ipv6 ( ipv6 -- ipv6' ) ipv6>byte-array byte-array>ipv6 ;
 139
 140 : reverse-ipv4 ( string -- string )
 141     ipv4>byte-array reverse byte-array>ipv4 ;
 142
 143 CONSTANT: ipv4-arpa-suffix ".in-addr.arpa"
 144
 145 : ipv4>arpa ( string -- string )
 146     reverse-ipv4 ipv4-arpa-suffix append ;
 147
 148 CONSTANT: ipv6-arpa-suffix ".ip6.arpa"
 149
 150 : ipv6>arpa ( string -- string )
 151     ipv6>byte-array
 152     [ [ -4 shift 4 bits ] [ 4 bits ] bi 2array ] { } map-as
 153     B{ } concat-as reverse
 154     [ >hex ] { } map-as "." join ipv6-arpa-suffix append ;
 155
 156 : trim-ipv4-arpa ( string -- string' )
 157     dotted> ipv4-arpa-suffix ?tail drop ;
 158
 159 : trim-ipv6-arpa ( string -- string' )
 160     dotted> ipv6-arpa-suffix ?tail drop ;
 161
 162 : arpa>ipv4 ( string -- ip ) trim-ipv4-arpa reverse-ipv4 ;
 163
 164 : arpa>ipv6 ( string -- ip )
 165     trim-ipv6-arpa "." split 2 group reverse
 166     [
 167         first2 swap [ hex> ] bi@ [ 4 shift ] [ ] bi* bitor
 168     ] B{ } map-as byte-array>ipv6 ;
 169
 170 : parse-length-bytes ( byte -- sequence ) read utf8 decode ;
 171
 172 : (parse-name) ( -- )
 173     read1 [
 174         dup 0xC0 mask? [
 175             8 shift read1 bitor 0x3fff bitand
 176             seek-absolute [
 177                 read1 parse-length-bytes , (parse-name)
 178             ] with-input-seek
 179         ] [
 180             parse-length-bytes , (parse-name)
 181         ] if
 182     ] unless-zero ;
 183
 184 : parse-name ( -- sequence )
 185     [ (parse-name) ] { } make "." join ;
 186
 187 : parse-query ( -- query )
 188     parse-name
 189     2 read be> <dns-type>
 190     2 read be> <dns-class> <query> ;
 191
 192 : parse-soa ( -- soa )
 193     soa new
 194         parse-name >>mname
 195         parse-name >>rname
 196         4 read be> >>serial
 197         4 read be> >>refresh
 198         4 read be> >>retry
 199         4 read be> >>expire
 200         4 read be> >>minimum ;
 201
 202 : parse-mx ( -- mx )
 203     mx new
 204         2 read be> >>preference
 205         parse-name >>exchange ;
 206
 207 GENERIC: parse-rdata ( n type -- obj )
 208
 209 M: object parse-rdata drop read ;
 210 M: A parse-rdata 2drop 4 read byte-array>ipv4 <a> ;
 211 M: AAAA parse-rdata 2drop 16 read byte-array>ipv6 <aaaa> ;
 212 M: CNAME parse-rdata 2drop parse-name <cname> ;
 213 M: MX parse-rdata 2drop parse-mx ;
 214 M: NS parse-rdata 2drop parse-name <ns> ;
 215 M: PTR parse-rdata 2drop parse-name <ptr> ;
 216 M: SOA parse-rdata 2drop parse-soa ;
 217
 218 : parse-rr ( -- rr )
 219     rr new
 220         parse-name >>name
 221         2 read be> <dns-type> >>type
 222         2 read be> <dns-class> >>class
 223         4 read be> >>ttl
 224         2 read be> over type>> parse-rdata >>rdata ;
 225
 226 : parse-message ( byte-array -- message )
 227     [ message new ] dip
 228     binary [
 229         2 read be> >>id
 230         2 read be> header>message-parts set-slots[ qr opcode aa tc rd ra z rcode ]
 231         2 read be> >>query
 232         2 read be> >>answer-section
 233         2 read be> >>authority-section
 234         2 read be> >>additional-section
 235         [ [ parse-query ] replicate ] change-query
 236         [ [ parse-rr ] replicate ] change-answer-section
 237         [ [ parse-rr ] replicate ] change-authority-section
 238         [ [ parse-rr ] replicate ] change-additional-section
 239     ] with-byte-reader ;
 240
 241 ERROR: unsupported-domain-name string ;
 242
 243 : >n/label ( string -- byte-array )
 244     dup [ ascii? ] all?
 245     [ unsupported-domain-name ] unless
 246     [ length 1array ] [ ] bi B{ } append-as ;
 247
 248 : >name ( domain -- byte-array )
 249     "." split [ >n/label ] map concat ;
 250
 251 : query>byte-array ( query -- byte-array )
 252     [
 253         {
 254             [ name>> >name ]
 255             [ type>> enum>number 2 >be ]
 256             [ class>> enum>number 2 >be ]
 257         } cleave
 258     ] B{ } append-outputs-as ;
 259
 260 GENERIC: rdata>byte-array ( rdata type -- obj )
 261
 262 M: A rdata>byte-array drop ipv4>byte-array ;
 263
 264 M: CNAME rdata>byte-array drop >name ;
 265
 266 M: HINFO rdata>byte-array
 267     drop
 268     [ cpu>> >name ]
 269     [ os>> >name ] bi append ;
 270
 271 M: MX rdata>byte-array
 272     drop
 273     [ preference>> 2 >be ]
 274     [ exchange>> >name ] bi append ;
 275
 276 M: NS rdata>byte-array drop >name ;
 277
 278 M: PTR rdata>byte-array drop >name ;
 279
 280 M: SOA rdata>byte-array
 281     drop
 282     [
 283         {
 284             [ mname>> >name ]
 285             [ rname>> >name ]
 286             [ serial>> 4 >be ]
 287             [ refresh>> 4 >be ]
 288             [ retry>> 4 >be ]
 289             [ expire>> 4 >be ]
 290             [ minimum>> 4 >be ]
 291         } cleave
 292     ] B{ } append-outputs-as ;
 293
 294 M: TXT rdata>byte-array
 295     drop ;
 296
 297 : rr>byte-array ( rr -- byte-array )
 298     [
 299         {
 300             [ name>> >name ]
 301             [ type>> enum>number 2 >be ]
 302             [ class>> enum>number 2 >be ]
 303             [ ttl>> 4 >be ]
 304             [
 305                 [ rdata>> ] [ type>> ] bi rdata>byte-array
 306                 [ length 2 >be ] [ ] bi append
 307             ]
 308         } cleave
 309     ] B{ } append-outputs-as ;
 310
 311 : message>byte-array ( message -- byte-array )
 312     [
 313         {
 314             [ id>> 2 >be ]
 315             [ message>header 2 >be ]
 316             [ query>> length 2 >be ]
 317             [ answer-section>> length 2 >be ]
 318             [ authority-section>> length 2 >be ]
 319             [ additional-section>> length 2 >be ]
 320             [ query>> [ query>byte-array ] map concat ]
 321             [ answer-section>> [ rr>byte-array ] map concat ]
 322             [ authority-section>> [ rr>byte-array ] map concat ]
 323             [ additional-section>> [ rr>byte-array ] map concat ]
 324         } cleave
 325     ] B{ } append-outputs-as ;
 326
 327 : udp-query ( bytes server -- bytes' )
 328     f 0 <inet4> <datagram>
 329     10 seconds over set-timeout [
 330         [ send ] [ receive drop ] bi
 331     ] with-disposal ;
 332
 333 : <dns-inet4> ( -- inet4 )
 334     dns-servers get random 53 <inet4> ;
 335
 336 : dns-query ( name type class -- message )
 337     <query> <message> message>byte-array
 338     <dns-inet4> udp-query parse-message ;
 339
 340 : dns-A-query ( name -- message ) A IN dns-query ;
 341 : dns-AAAA-query ( name -- message ) AAAA IN dns-query ;
 342 : dns-MX-query ( name -- message ) MX IN dns-query ;
 343 : dns-NS-query ( name -- message ) NS IN dns-query ;
 344 : dns-TXT-query ( name -- message ) TXT IN dns-query ;
 345
 346 : read-TXT-strings ( byte-array -- strings )
 347     [
 348         binary <byte-reader> [
 349             [ read1 [ read , t ] [ f ] if* ] loop
 350         ] with-input-stream
 351     ] { } make ;
 352
 353 : TXT-message>strings ( message -- strings )
 354     answer-section>>
 355     [ rdata>>
 356         read-TXT-strings [ utf8 decode ] map
 357     ] map ;
 358
 359 : TXT. ( name -- )
 360     dns-TXT-query TXT-message>strings [ [ write ] each nl ] each ;
 361
 362 : reverse-lookup ( reversed-ip -- message )
 363     PTR IN dns-query ;
 364
 365 : reverse-ipv4-lookup ( ip -- message )
 366     ipv4>arpa reverse-lookup ;
 367
 368 : reverse-ipv6-lookup ( ip -- message )
 369     ipv6>arpa reverse-lookup ;
 370
 371 : message>names ( message -- names )
 372     answer-section>> [ rdata>> name>> ] map ;
 373
 374 : filter-message-rdata>names ( message quot -- names )
 375     [ answer-section>> [ rdata>> ] map ] dip filter [ name>> ] map ; inline
 376
 377 : message>a-names ( message -- names )
 378     [ a? ] filter-message-rdata>names ;
 379
 380 : message>aaaa-names ( message -- names )
 381     [ aaaa? ] filter-message-rdata>names ;
 382
 383 : message>mxs ( message -- assoc )
 384     answer-section>> [ rdata>> [ preference>> ] [ exchange>> ] bi 2array ] map ;
 385
 386 : messages>names ( messages -- names )
 387     [ message>names ] map concat ;
 388
 389 : forward-confirmed-reverse-dns-ipv4? ( ipv4-string -- ? )
 390     dup reverse-ipv4-lookup message>names
 391     [ dns-A-query ] map messages>names member? ;
 392
 393 : forward-confirmed-reverse-dns-ipv6? ( ipv6-string -- ? )
 394     expand-ipv6
 395     dup reverse-ipv6-lookup message>names
 396     [ dns-AAAA-query ] map messages>names member? ;
 397
 398 : message>query-name ( message -- string )
 399     query>> first name>> dotted> ;
 400
 401 ! XXX: Turn on someday for nonblocking DNS lookups
 402 ! M: string resolve-host
 403     ! dup >lower "localhost" = [
 404         ! drop resolve-localhost
 405     ! ] [
 406         ! dns-A-query message>a-names [ <ipv4> ] map
 407     ! ] if ;
 408
 409 HOOK: initial-dns-servers os ( -- sequence )
 410
 411 {
 412     { [ os windows? ] [ "dns.windows" ] }
 413     { [ os unix? ] [ "dns.unix" ] }
 414 } cond require
 415
 416 : with-dns-servers ( servers quot -- )
 417     [ dns-servers ] dip with-variable ; inline
 418
 419 dns-servers [ initial-dns-servers >vector ] initialize