extra/dns/dns.factor

   1 ! Copyright (C) 2010 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.enums alien.syntax arrays assocs
   4 byte-arrays calendar combinators combinators.smart constructors
   5 destructors fry grouping io io.binary io.buffers
   6 io.encodings.binary io.encodings.string io.encodings.utf8
   7 io.files io.ports io.sockets io.sockets.private
   8 io.streams.byte-array io.timeouts kernel make math math.bitwise
   9 math.parser math.ranges math.statistics memoize namespaces
  10 nested-comments random sequences slots.syntax splitting strings
  11 system unicode.categories vectors vocabs.loader unicode.case ;
  12 IN: dns
  13
  14 : with-temporary-input-seek ( n seek-type quot -- )
  15     tell-input [
  16         [ seek-input ] dip call
  17     ] dip seek-absolute seek-input ; inline
  18
  19 ENUM: dns-type
  20 { A 1 } { NS 2 } { MD 3 } { MF 4 }
  21 { CNAME 5 } { SOA 6 } { MB 7 } { MG 8 }
  22 { MR 9 } { NULL 10 } { WKS 11 } { PTR 12 }
  23 { HINFO 13 } { MINFO 14 } { MX 15 } { TXT 16 }
  24 { RP 17 } { AFSDB 18 } { SIG 24 } { KEY 25 }
  25 { AAAA 28 } { LOC 29 } { SVR 33 } { NAPTR 35 }
  26 { KX 36 } { CERT 37 } { DNAME 39 } { OPT 41 }
  27 { APL 42 } { DS 43 } { SSHFP 44 } { IPSECKEY 45 }
  28 { RRSIG 46 } { NSEC 47 } { DNSKEY 48 } { DHCID 49 }
  29 { NSEC3 50 } { NSEC3PARAM 51 } { HIP 55 } { SPF 99 }
  30 { TKEY 249 } { TSIG 250 } { IXFR 251 }
  31 { TA 32768 } { DLV 32769 } ;
  32
  33 ENUM: dns-class { IN 1 } { CS 2 } { CH 3 } { HS 4 } ;
  34
  35 ENUM: dns-opcode QUERY IQUERY STATUS ;
  36
  37 ENUM: dns-rcode NO-ERROR FORMAT-ERROR SERVER-FAILURE
  38 NAME-ERROR NOT-IMPLEMENTED REFUSED ;
  39
  40 SYMBOL: dns-servers
  41
  42 : add-dns-server ( string -- )
  43     dns-servers get push ;
  44
  45 : remove-dns-server ( string -- )
  46     dns-servers get remove! drop ;
  47
  48 : clear-dns-servers ( -- )
  49     V{ } clone dns-servers set-global ;
  50
  51 : >dotted ( domain -- domain' )
  52     dup "." tail? [ "." append ] unless ;
  53
  54 : dotted> ( string -- string' )
  55     "." ?tail drop ;
  56
  57 TUPLE: query name type class ;
  58 CONSTRUCTOR: query ( name type class -- obj )
  59     [ >dotted ] change-name ;
  60
  61 TUPLE: rr name type class ttl rdata ;
  62
  63 TUPLE: hinfo cpu os ;
  64
  65 TUPLE: mx preference exchange ;
  66
  67 TUPLE: soa mname rname serial refresh retry expire minimum ;
  68
  69 TUPLE: a name ;
  70 CONSTRUCTOR: a ( name -- obj ) ;
  71
  72 TUPLE: aaaa name ;
  73 CONSTRUCTOR: aaaa ( name -- obj ) ;
  74
  75 TUPLE: cname name ;
  76 CONSTRUCTOR: cname ( name -- obj ) ;
  77
  78 TUPLE: ptr name ;
  79 CONSTRUCTOR: ptr ( name -- obj ) ;
  80
  81 TUPLE: ns name ;
  82 CONSTRUCTOR: ns ( name -- obj ) ;
  83
  84 TUPLE: message id qr opcode aa tc rd ra z rcode
  85 query answer-section authority-section additional-section ;
  86
  87 CONSTRUCTOR: message ( query -- obj )
  88     16 2^ random >>id
  89     0 >>qr
  90     QUERY >>opcode
  91     0 >>aa
  92     0 >>tc
  93     1 >>rd
  94     0 >>ra
  95     0 >>z
  96     NO-ERROR >>rcode
  97     [ dup sequence? [ 1array ] unless ] change-query
  98     { } >>answer-section
  99     { } >>authority-section
 100     { } >>additional-section ;
 101
 102 : message>header ( message -- n )
 103     [
 104         {
 105             [ qr>> 15 shift ]
 106             [ opcode>> enum>number 11 shift ]
 107             [ aa>> 10 shift ]
 108             [ tc>> 9 shift ]
 109             [ rd>> 8 shift ]
 110             [ ra>> 7 shift ]
 111             [ z>> 4 shift ]
 112             [ rcode>> enum>number 0 shift ]
 113         } cleave
 114     ] sum-outputs ;
 115
 116 : header>message-parts ( n -- qr opcode aa tc rd ra z rcode )
 117     {
 118         [ -15 shift BIN: 1 bitand ]
 119         [ -11 shift BIN: 111 bitand <dns-opcode> ]
 120         [ -10 shift BIN: 1 bitand ]
 121         [ -9 shift BIN: 1 bitand ]
 122         [ -8 shift BIN: 1 bitand ]
 123         [ -7 shift BIN: 1 bitand ]
 124         [ -4 shift BIN: 111 bitand ]
 125         [ BIN: 1111 bitand <dns-rcode> ]
 126     } cleave ;
 127
 128 : byte-array>ipv4 ( byte-array -- string )
 129     [ number>string ] { } map-as "." join ;
 130
 131 : byte-array>ipv6 ( byte-array -- string )
 132     2 group [ be> >hex ] { } map-as ":" join ;
 133
 134 : ipv4>byte-array ( string -- byte-array )
 135     "." split [ string>number ] B{ } map-as ;
 136
 137 : ipv6>byte-array ( string -- byte-array )
 138     T{ inet6 } inet-pton ;
 139
 140 : expand-ipv6 ( ipv6 -- ipv6' ) ipv6>byte-array byte-array>ipv6 ;
 141
 142 : reverse-ipv4 ( string -- string )
 143     ipv4>byte-array reverse byte-array>ipv4 ;
 144
 145 CONSTANT: ipv4-arpa-suffix ".in-addr.arpa"
 146
 147 : ipv4>arpa ( string -- string )
 148     reverse-ipv4 ipv4-arpa-suffix append ;
 149
 150 CONSTANT: ipv6-arpa-suffix ".ip6.arpa"
 151
 152 : ipv6>arpa ( string -- string )
 153     ipv6>byte-array [ [ -4 shift 4 bits ] [ 4 bits ] bi 2array ] { } map-as
 154     B{ } concat-as reverse
 155     [ >hex ] { } map-as "." join ipv6-arpa-suffix append ;
 156
 157 : trim-ipv4-arpa ( string -- string' )
 158     dotted> ipv4-arpa-suffix ?tail drop ;
 159
 160 : trim-ipv6-arpa ( string -- string' )
 161     dotted> ipv6-arpa-suffix ?tail drop ;
 162
 163 : arpa>ipv4 ( string -- ip ) trim-ipv4-arpa reverse-ipv4 ;
 164
 165 : arpa>ipv6 ( string -- ip )
 166     trim-ipv6-arpa "." split 2 group reverse
 167     [
 168         first2 swap [ hex> ] bi@ [ 4 shift ] [ ] bi* bitor
 169     ] B{ } map-as byte-array>ipv6 ;
 170
 171 : parse-length-bytes ( -- seq ) read1 read utf8 decode ;
 172
 173 : (parse-name) ( -- )
 174     peek1 [
 175         read1 drop
 176     ] [
 177         HEX: C0 mask? [
 178             2 read be> HEX: 3fff bitand
 179             seek-absolute [ parse-length-bytes , (parse-name) ] with-temporary-input-seek
 180         ] [
 181             parse-length-bytes , (parse-name)
 182         ] if
 183     ] if-zero ;
 184
 185 : parse-name ( -- seq )
 186     [ (parse-name) ] { } make "." join ;
 187
 188 : parse-query ( -- query )
 189     parse-name
 190     2 read be> <dns-type>
 191     2 read be> <dns-class> <query> ;
 192
 193 : parse-soa ( -- soa )
 194     soa new
 195         parse-name >>mname
 196         parse-name >>rname
 197         4 read be> >>serial
 198         4 read be> >>refresh
 199         4 read be> >>retry
 200         4 read be> >>expire
 201         4 read be> >>minimum ;
 202
 203 : parse-mx ( -- mx )
 204     mx new
 205         2 read be> >>preference
 206         parse-name >>exchange ;
 207
 208 GENERIC: parse-rdata ( n type -- obj )
 209
 210 M: object parse-rdata drop read ;
 211 M: A parse-rdata 2drop 4 read byte-array>ipv4 <a> ;
 212 M: AAAA parse-rdata 2drop 16 read byte-array>ipv6 <aaaa> ;
 213 M: CNAME parse-rdata 2drop parse-name <cname> ;
 214 M: MX parse-rdata 2drop parse-mx ;
 215 M: NS parse-rdata 2drop parse-name <ns> ;
 216 M: PTR parse-rdata 2drop parse-name <ptr> ;
 217 M: SOA parse-rdata 2drop parse-soa ;
 218
 219 : parse-rr ( -- rr )
 220     rr new
 221         parse-name >>name
 222         2 read be> <dns-type> >>type
 223         2 read be> <dns-class> >>class
 224         4 read be> >>ttl
 225         2 read be> over type>> parse-rdata >>rdata ;
 226
 227 : parse-message ( ba -- message )
 228     [ message new ] dip
 229     binary [
 230         2 read be> >>id
 231         2 read be> header>message-parts set-slots[ qr opcode aa tc rd ra z rcode ]
 232         2 read be> >>query
 233         2 read be> >>answer-section
 234         2 read be> >>authority-section
 235         2 read be> >>additional-section
 236         [ [ parse-query ] replicate ] change-query
 237         [ [ parse-rr ] replicate ] change-answer-section
 238         [ [ parse-rr ] replicate ] change-authority-section
 239         [ [ parse-rr ] replicate ] change-additional-section
 240     ] with-byte-reader ;
 241
 242 : >n/label ( string -- ba )
 243     [ length 1array ] [ utf8 encode ] bi B{ } append-as ;
 244
 245 : >name ( dn -- ba ) "." split [ >n/label ] map concat ;
 246
 247 : query>byte-array ( query -- ba )
 248     [
 249         {
 250             [ name>> >name ]
 251             [ type>> enum>number 2 >be ]
 252             [ class>> enum>number 2 >be ]
 253         } cleave
 254     ] B{ } append-outputs-as ;
 255
 256 GENERIC: rdata>byte-array ( rdata type -- obj )
 257
 258 M: A rdata>byte-array drop ipv4>byte-array ;
 259
 260 M: CNAME rdata>byte-array drop >name ;
 261
 262 M: HINFO rdata>byte-array
 263     drop
 264     [ cpu>> >name ]
 265     [ os>> >name ] bi append ;
 266
 267 M: MX rdata>byte-array
 268     drop
 269     [ preference>> 2 >be ]
 270     [ exchange>> >name ] bi append ;
 271
 272 M: NS rdata>byte-array drop >name ;
 273
 274 M: PTR rdata>byte-array drop >name ;
 275
 276 M: SOA rdata>byte-array
 277     drop
 278     [
 279         {
 280             [ mname>> >name ]
 281             [ rname>> >name ]
 282             [ serial>> 4 >be ]
 283             [ refresh>> 4 >be ]
 284             [ retry>> 4 >be ]
 285             [ expire>> 4 >be ]
 286             [ minimum>> 4 >be ]
 287         } cleave
 288     ] B{ } append-outputs-as ;
 289
 290 : rr>byte-array ( rr -- ba )
 291     [
 292         {
 293             [ name>> >name ]
 294             [ type>> enum>number 2 >be ]
 295             [ class>> enum>number 2 >be ]
 296             [ ttl>> 4 >be ]
 297             [
 298                 [ rdata>> ] [ type>> ] bi rdata>byte-array
 299                 [ length 2 >be ] [ ] bi append
 300             ]
 301         } cleave
 302     ] B{ } append-outputs-as ;
 303
 304 : message>byte-array ( message -- ba )
 305     [
 306         {
 307             [ id>> 2 >be ]
 308             [ message>header 2 >be ]
 309             [ query>> length 2 >be ]
 310             [ answer-section>> length 2 >be ]
 311             [ authority-section>> length 2 >be ]
 312             [ additional-section>> length 2 >be ]
 313             [ query>> [ query>byte-array ] map concat ]
 314             [ answer-section>> [ rr>byte-array ] map concat ]
 315             [ authority-section>> [ rr>byte-array ] map concat ]
 316             [ additional-section>> [ rr>byte-array ] map concat ]
 317         } cleave
 318     ] B{ } append-outputs-as ;
 319
 320 : udp-query ( bytes server -- bytes' )
 321     f 0 <inet4> <datagram>
 322     30 seconds over set-timeout [
 323         [ send ] [ receive drop ] bi
 324     ] with-disposal ;
 325
 326 : <dns-inet4> ( -- inet4 )
 327     dns-servers get random 53 <inet4> ;
 328
 329 : dns-query ( query -- message )
 330     <message> message>byte-array
 331     <dns-inet4> udp-query parse-message ;
 332
 333 : dns-A-query ( domain -- message ) A IN <query> dns-query ;
 334 : dns-AAAA-query ( domain -- message ) AAAA IN <query> dns-query ;
 335 : dns-MX-query ( domain -- message ) MX IN <query> dns-query ;
 336 : dns-NS-query ( domain -- message ) NS IN <query> dns-query ;
 337
 338 : reverse-lookup ( reversed-ip -- message )
 339     PTR IN <query> dns-query ;
 340
 341 : reverse-ipv4-lookup ( ip -- message )
 342     ipv4>arpa reverse-lookup ;
 343
 344 : reverse-ipv6-lookup ( ip -- message )
 345     ipv6>arpa reverse-lookup ;
 346
 347 : message>names ( message -- names )
 348     answer-section>> [ rdata>> name>> ] map ;
 349
 350 : message>a-names ( message -- names )
 351     answer-section>>
 352     [ rdata>> ] map [ a? ] filter [ name>> ] map ;
 353
 354 : message>mxs ( message -- assoc )
 355     answer-section>> [ rdata>> [ preference>> ] [ exchange>> ] bi 2array ] map ;
 356
 357 : messages>names ( messages -- names )
 358     [ message>names ] map concat ;
 359
 360 : forward-confirmed-reverse-dns-ipv4? ( ipv4-string -- ? )
 361     dup reverse-ipv4-lookup message>names
 362     [ dns-A-query ] map messages>names member? ;
 363
 364 : forward-confirmed-reverse-dns-ipv6? ( ipv6-string -- ? )
 365     expand-ipv6
 366     dup reverse-ipv6-lookup message>names
 367     [ dns-AAAA-query ] map messages>names member? ;
 368
 369 : message>query-name ( message -- string )
 370     query>> first name>> dotted> ;
 371
 372 USE: nested-comments
 373 (*
 374 M: string resolve-host
 375     dup >lower "localhost" = [
 376         drop resolve-localhost
 377     ] [
 378         dns-A-query message>a-names [ <ipv4> ] map
 379     ] if ;
 380 *)
 381
 382 HOOK: initial-dns-servers os ( -- seq )
 383
 384 {
 385     { [ os windows? ] [ "dns.windows" ] }
 386     { [ os unix? ] [ "dns.unix" ] }
 387 } cond require
 388
 389 dns-servers [ initial-dns-servers >vector ] initialize