extra/fuel/help/help.factor

   1 ! Copyright (C) 2009 Jose Antonio Ortega Ruiz.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3
   4 USING: accessors arrays assocs combinators help help.crossref
   5 help.markup help.topics io io.streams.string kernel make namespaces
   6 parser prettyprint sequences summary help.vocabs
   7 vocabs vocabs.loader vocabs.hierarchy vocabs.metadata words see
   8 listener ;
   9 FROM: vocabs.hierarchy => child-vocabs ;
  10 IN: fuel.help
  11
  12 <PRIVATE
  13
  14 : fuel-find-word ( name -- word/f )
  15     [ [ name>> ] dip = ] curry all-words swap filter
  16     dup empty? not [ first ] [ drop f ] if ;
  17
  18 : fuel-value-str ( word -- str )
  19     [ pprint-short ] with-string-writer ; inline
  20
  21 : fuel-definition-str ( word -- str )
  22     [ see ] with-string-writer ; inline
  23
  24 : fuel-methods-str ( word -- str )
  25     methods [ f ] [
  26         [ [ see nl ] each ] with-string-writer
  27     ] if-empty ; inline
  28
  29 : fuel-related-words ( word -- seq )
  30     dup "related" word-prop remove ; inline
  31
  32 : fuel-parent-topics ( word -- seq )
  33     help-path [ dup article-title swap 2array ] map ; inline
  34
  35 SYMBOL: $doc-path
  36
  37 : (fuel-word-element) ( word -- element )
  38     \ article swap dup article-title swap
  39     [
  40         {
  41             [ fuel-parent-topics [ \ $doc-path prefix , ] unless-empty ]
  42             [ \ $vocabulary swap vocabulary>> 2array , ]
  43             [ word-help % ]
  44             [ fuel-related-words [ \ $related swap 2array , ] unless-empty ]
  45             [ get-global [ \ $value swap fuel-value-str 2array , ] when* ]
  46             [ \ $definition swap fuel-definition-str 2array , ]
  47             [ fuel-methods-str [ \ $methods swap 2array , ] when* ]
  48         } cleave
  49     ] { } make 3array ;
  50
  51 : fuel-vocab-help-row ( vocab -- element )
  52     [ vocab-name ] [ summary ] bi 2array ;
  53
  54 : fuel-vocab-help-root-heading ( root -- element )
  55     [ "Children from " prepend ] [ "Other children" ] if* \ $heading swap 2array ;
  56
  57 SYMBOL: vocab-list
  58 SYMBOL: describe-words
  59
  60 : fuel-vocab-help-table ( vocabs -- element )
  61     [ fuel-vocab-help-row ] map vocab-list prefix ;
  62
  63 : fuel-vocab-list ( assoc -- seq )
  64     [
  65         [ drop f ] [
  66             [ fuel-vocab-help-root-heading ]
  67             [ fuel-vocab-help-table ] bi*
  68             [ 2array ] [ drop f ] if*
  69         ] if-empty
  70     ] { } assoc>map sift ;
  71
  72 : fuel-vocab-children-help ( name -- element )
  73     child-vocabs fuel-vocab-list ; inline
  74
  75 : fuel-vocab-describe-words ( name -- element )
  76     [ words. ] with-string-writer \ describe-words swap 2array ; inline
  77
  78 : (fuel-vocab-element) ( name -- element )
  79     dup require \ article swap dup >vocab-link
  80     [
  81         {
  82             [ vocab-authors [ \ $authors prefix , ] when* ]
  83             [ vocab-tags [ \ $tags prefix , ] when* ]
  84             [ summary [ { $heading "Summary" } swap 2array , ] when* ]
  85             [ drop \ $nl , ]
  86             [ vocab-help [ article content>> % ] when* ]
  87             [ name>> fuel-vocab-describe-words , ]
  88             [ name>> fuel-vocab-children-help % ]
  89         } cleave
  90     ] { } make 3array ;
  91
  92 PRIVATE>
  93
  94 : (fuel-word-help) ( name -- elem )
  95     fuel-find-word [ [ auto-use? on (fuel-word-element) ] with-scope ] [ f ] if* ;
  96
  97 : (fuel-word-synopsis) ( word usings -- str/f )
  98     [
  99         [ lookup-vocab ] filter interactive-vocabs [ append ] change
 100         fuel-find-word [ synopsis ] [ f ] if*
 101     ] with-scope ;
 102
 103 : (fuel-word-see) ( word -- elem )
 104     [ name>> \ article swap ]
 105     [ [ see ] with-string-writer \ $code swap 2array ] bi 3array ; inline
 106
 107 : (fuel-word-def) ( name -- str )
 108     fuel-find-word [ [ def>> pprint ] with-string-writer ] [ f ] if* ; inline
 109
 110 : (fuel-vocab-summary) ( name -- str ) >vocab-link summary ; inline
 111
 112 : (fuel-vocab-help) ( name -- str )
 113     dup empty? [ fuel-vocab-children-help ] [ (fuel-vocab-element) ] if ;
 114
 115 : (fuel-get-vocabs/author) ( author -- element )
 116     [ "Vocabularies by " prepend \ $heading swap 2array ]
 117     [ authored fuel-vocab-list ] bi 2array ;
 118
 119 : (fuel-get-vocabs/tag) ( tag -- element )
 120     [ "Vocabularies tagged " prepend \ $heading swap 2array ]
 121     [ tagged fuel-vocab-list ] bi 2array ;
 122
 123 : format-index ( seq -- seq )
 124     [ [ >link name>> ] [ article-title ] bi 2array \ $subsection prefix ] map ;