extra/furnace/auth/auth.factor

   1 ! Copyright (c) 2008 Slava Pestov\r
   2 ! See http://factorcode.org/license.txt for BSD license.\r
   3 USING: accessors assocs namespaces kernel sequences sets\r
   4 destructors combinators fry logging\r
   5 io.encodings.utf8 io.encodings.string io.binary random\r
   6 checksums checksums.sha2\r
   7 html.forms\r
   8 http.server\r
   9 http.server.filters\r
  10 http.server.dispatchers\r
  11 furnace\r
  12 furnace.actions\r
  13 furnace.redirection\r
  14 furnace.boilerplate\r
  15 furnace.auth.providers\r
  16 furnace.auth.providers.db ;\r
  17 IN: furnace.auth\r
  18 \r
  19 SYMBOL: logged-in-user\r
  20 \r
  21 : logged-in? ( -- ? )\r
  22     logged-in-user get >boolean ;\r
  23 \r
  24 : username ( -- string/f )\r
  25     logged-in-user get dup [ username>> ] when ;\r
  26 \r
  27 GENERIC: init-user-profile ( responder -- )\r
  28 \r
  29 M: object init-user-profile drop ;\r
  30 \r
  31 M: dispatcher init-user-profile\r
  32     default>> init-user-profile ;\r
  33 \r
  34 M: filter-responder init-user-profile\r
  35     responder>> init-user-profile ;\r
  36 \r
  37 : profile ( -- assoc ) logged-in-user get profile>> ;\r
  38 \r
  39 : user-changed ( -- )\r
  40     logged-in-user get t >>changed? drop ;\r
  41 \r
  42 : uget ( key -- value )\r
  43     profile at ;\r
  44 \r
  45 : uset ( value key -- )\r
  46     profile set-at\r
  47     user-changed ;\r
  48 \r
  49 : uchange ( quot key -- )\r
  50     profile swap change-at\r
  51     user-changed ; inline\r
  52 \r
  53 SYMBOL: capabilities\r
  54 \r
  55 V{ } clone capabilities set-global\r
  56 \r
  57 : define-capability ( word -- ) capabilities get adjoin ;\r
  58 \r
  59 TUPLE: realm < dispatcher name users checksum secure ;\r
  60 \r
  61 GENERIC: login-required* ( realm -- response )\r
  62 \r
  63 GENERIC: init-realm ( realm -- )\r
  64 \r
  65 GENERIC: logged-in-username ( realm -- username )\r
  66 \r
  67 : login-required ( -- * ) realm get login-required* exit-with ;\r
  68 \r
  69 : new-realm ( responder name class -- realm )\r
  70     new-dispatcher\r
  71         swap >>name\r
  72         swap >>default\r
  73         users-in-db >>users\r
  74         sha-256 >>checksum\r
  75         t >>secure ; inline\r
  76 \r
  77 : users ( -- provider )\r
  78     realm get users>> ;\r
  79 \r
  80 TUPLE: user-saver user ;\r
  81 \r
  82 C: <user-saver> user-saver\r
  83 \r
  84 M: user-saver dispose\r
  85     user>> dup changed?>> [ users update-user ] [ drop ] if ;\r
  86 \r
  87 : save-user-after ( user -- )\r
  88     <user-saver> &dispose drop ;\r
  89 \r
  90 : init-user ( user -- )\r
  91     [ [ logged-in-user set ] [ save-user-after ] bi ] when* ;\r
  92 \r
  93 \ init-user DEBUG add-input-logging\r
  94 \r
  95 M: realm call-responder* ( path responder -- response )\r
  96     dup realm set\r
  97     logged-in? [\r
  98         dup init-realm\r
  99         dup logged-in-username\r
 100         dup [ users get-user ] when\r
 101         init-user\r
 102     ] unless\r
 103     call-next-method ;\r
 104 \r
 105 : encode-password ( string salt -- bytes )\r
 106     [ utf8 encode ] [ 4 >be ] bi* append\r
 107     realm get checksum>> checksum-bytes ;\r
 108 \r
 109 : >>encoded-password ( user string -- user )\r
 110     32 random-bits [ encode-password ] keep\r
 111     [ >>password ] [ >>salt ] bi* ; inline\r
 112 \r
 113 : valid-login? ( password user -- ? )\r
 114     [ salt>> encode-password ] [ password>> ] bi = ;\r
 115 \r
 116 : check-login ( password username -- user/f )\r
 117     users get-user dup [ [ valid-login? ] keep and ] [ 2drop f ] if ;\r
 118 \r
 119 : if-secure-realm ( quot -- )\r
 120     realm get secure>> [ if-secure ] [ call ] if ; inline\r
 121 \r
 122 TUPLE: secure-realm-only < filter-responder ;\r
 123 \r
 124 C: <secure-realm-only> secure-realm-only\r
 125 \r
 126 M: secure-realm-only call-responder*\r
 127     '[ , , call-next-method ] if-secure-realm ;\r
 128 \r
 129 TUPLE: protected < filter-responder description capabilities ;\r
 130 \r
 131 : <protected> ( responder -- protected )\r
 132     protected new\r
 133         swap >>responder ;\r
 134 \r
 135 : have-capabilities? ( capabilities -- ? )\r
 136     logged-in-user get {\r
 137         { [ dup not ] [ 2drop f ] }\r
 138         { [ dup deleted>> 1 = ] [ 2drop f ] }\r
 139         [ capabilities>> subset? ]\r
 140     } cond ;\r
 141 \r
 142 M: protected call-responder* ( path responder -- response )\r
 143     '[\r
 144         , ,\r
 145         dup protected set\r
 146         dup capabilities>> have-capabilities?\r
 147         [ call-next-method ] [ 2drop realm get login-required* ] if\r
 148     ] if-secure-realm ;\r
 149 \r
 150 : <auth-boilerplate> ( responder -- responder' )\r
 151     <boilerplate> { realm "boilerplate" } >>template ;\r
 152 \r
 153 : password-mismatch ( -- * )\r
 154     "passwords do not match" validation-error\r
 155     validation-failed ;\r
 156 \r
 157 : same-password-twice ( -- )\r
 158     "new-password" value "verify-password" value =\r
 159     [ password-mismatch ] unless ;\r
 160 \r
 161 : user-exists ( -- * )\r
 162     "username taken" validation-error\r
 163     validation-failed ;\r