extra/gdbm/gdbm.factor

   1 ! Copyright (C) 2010 Dmitry Shubin.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types alien.data alien.destructors
   4 alien.enums alien.syntax classes.struct combinators destructors
   5 gdbm.ffi io.backend kernel libc locals math namespaces sequences
   6 serialize strings ;
   7 IN: gdbm
   8
   9 ENUM: gdbm-role reader writer wrcreat newdb ;
  10
  11 TUPLE: gdbm
  12     { name string }
  13     { block-size integer }
  14     { role initial: wrcreat }
  15     { sync boolean }
  16     { nolock boolean }
  17     { mode integer initial: 0o644 } ;
  18
  19 : <gdbm> ( -- gdbm ) gdbm new ;
  20
  21 ENUM: gdbm-error
  22     gdbm-no-error
  23     gdbm-malloc-error
  24     gdbm-block-size-error
  25     gdbm-file-open-error
  26     gdbm-file-write-error
  27     gdbm-file-seek-error
  28     gdbm-file-read-error
  29     gdbm-bad-magic-number
  30     gdbm-empty-database
  31     gdbm-cant-be-reader
  32     gdbm-cant-be-writer
  33     gdbm-reader-cant-delete
  34     gdbm-reader-cant-store
  35     gdbm-reader-cant-reorganize
  36     gdbm-unknown-update
  37     gdbm-item-not-found
  38     gdbm-reorganize-failed
  39     gdbm-cannot-replace
  40     gdbm-illegal-data
  41     gdbm-option-already-set
  42     gdbm-illegal-option ;
  43
  44
  45 <PRIVATE
  46
  47 : gdbm-throw ( -- * ) gdbm_errno gdbm-error number>enum throw ;
  48
  49 : check-error ( ret -- ) 0 = [ gdbm-throw ] unless ;
  50
  51 SYMBOL: current-dbf
  52
  53 : dbf ( -- dbf ) current-dbf get ;
  54
  55 : get-flag ( gdbm -- n )
  56     [ role>>   enum>number ]
  57     [ sync>>   GDBM_SYNC 0 ? ]
  58     [ nolock>> GDBM_NOLOCK 0 ? ]
  59     tri bitor bitor ;
  60
  61 : gdbm-open ( gdbm -- dbf )
  62     {
  63         [ name>> normalize-path ]
  64         [ block-size>> ] [ get-flag ] [ mode>> ]
  65     } cleave f gdbm_open [ gdbm-throw ] unless* ;
  66
  67 DESTRUCTOR: gdbm-close
  68
  69 : object>datum ( obj -- datum )
  70     object>bytes [ malloc-byte-array &free ] [ length ] bi
  71     datum <struct-boa> ;
  72
  73 : datum>object* ( datum -- obj ? )
  74     [ dptr>> ] [ dsize>> ] bi over
  75     [ memory>byte-array bytes>object t ] [ drop f ] if ;
  76
  77 : gdbm-store ( key content flag -- )
  78     [
  79         [ dbf ] 3dip
  80         [ object>datum ] [ object>datum ] [ ] tri*
  81         gdbm_store check-error
  82     ] with-destructors ;
  83
  84 :: (setopt) ( value option -- )
  85     [
  86         int heap-size dup malloc &free :> ( size ptr )
  87         value ptr 0 int set-alien-value
  88         dbf option ptr size gdbm_setopt check-error
  89     ] with-destructors ;
  90
  91 : setopt ( value option -- )
  92     [ GDBM_CACHESIZE = [ >c-bool ] unless ] keep (setopt) ;
  93
  94 PRIVATE>
  95
  96
  97 : gdbm-info ( -- str ) gdbm_version ;
  98
  99 : gdbm-error-message ( error -- msg )
 100     enum>number gdbm_strerror ;
 101
 102 : replace ( key content -- ) GDBM_REPLACE gdbm-store ;
 103 : insert ( key content -- ) GDBM_INSERT gdbm-store ;
 104
 105 : delete ( key -- )
 106     [ dbf swap object>datum gdbm_delete check-error ]
 107     with-destructors ;
 108
 109 : fetch* ( key -- content ? )
 110     [ dbf swap object>datum gdbm_fetch datum>object* ]
 111     with-destructors ;
 112
 113 : first-key* ( -- key ? )
 114     [ dbf gdbm_firstkey datum>object* ] with-destructors ;
 115
 116 : next-key* ( key -- next-key ? )
 117     [ dbf swap object>datum gdbm_nextkey datum>object* ]
 118     with-destructors ;
 119
 120 : fetch ( key -- content/f ) fetch* drop ;
 121 : first-key ( -- key/f ) first-key* drop ;
 122 : next-key ( key -- key/f ) next-key* drop ;
 123
 124 :: each-key ( ... quot: ( ... key -- ... ) -- ... )
 125     first-key*
 126     [ [ next-key* ] [ quot keep ] do while ] when drop ; inline
 127
 128 : each-value ( ... quot: ( ... value -- ... ) -- ... )
 129     [ fetch ] prepose each-key ; inline
 130
 131 : each-record ( ... quot: ( ... key value -- ... ) -- ... )
 132     [ dup fetch ] prepose each-key ; inline
 133
 134 : reorganize ( -- ) dbf gdbm_reorganize check-error ;
 135
 136 : synchronize ( -- ) dbf gdbm_sync ;
 137
 138 : exists? ( key -- ? )
 139     [ dbf swap object>datum gdbm_exists c-bool> ]
 140     with-destructors ;
 141
 142 : set-cache-size ( size -- ) GDBM_CACHESIZE setopt ;
 143 : set-sync-mode ( ? -- ) GDBM_SYNCMODE setopt ;
 144 : set-block-pool ( ? -- ) GDBM_CENTFREE setopt ;
 145 : set-block-merging ( ? -- ) GDBM_COALESCEBLKS setopt ;
 146
 147 : gdbm-file-descriptor ( -- desc ) dbf gdbm_fdesc ;
 148
 149 : with-gdbm ( gdbm quot -- )
 150     [ gdbm-open &gdbm-close current-dbf set ] prepose curry
 151     [ with-scope ] curry with-destructors ; inline
 152
 153 :: with-gdbm-role ( name role quot -- )
 154     <gdbm> name >>name role >>role quot with-gdbm ; inline
 155
 156 : with-gdbm-reader ( name quot -- )
 157     reader swap with-gdbm-role ; inline
 158
 159 : with-gdbm-writer ( name quot -- )
 160     writer swap with-gdbm-role ; inline
 161