extra/gdbm/gdbm.factor

   1 ! Copyright (C) 2010 Dmitry Shubin.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types alien.data alien.destructors
   4 alien.enums alien.syntax classes.struct combinators continuations
   5 destructors fry gdbm.ffi io.backend kernel libc locals math namespaces
   6 sequences serialize strings ;
   7 IN: gdbm
   8
   9 ENUM: gdbm-role reader writer wrcreat newdb ;
  10
  11 TUPLE: gdbm
  12     { name string }
  13     { block-size integer }
  14     { role initial: wrcreat }
  15     { sync boolean }
  16     { nolock boolean }
  17     { mode integer initial: 0o644 } ;
  18
  19 : <gdbm> ( -- gdbm ) gdbm new ;
  20
  21 ENUM: gdbm-error
  22     gdbm-no-error
  23     gdbm-malloc-error
  24     gdbm-block-size-error
  25     gdbm-file-open-error
  26     gdbm-file-write-error
  27     gdbm-file-seek-error
  28     gdbm-file-read-error
  29     gdbm-bad-magic-number
  30     gdbm-empty-database
  31     gdbm-cant-be-reader
  32     gdbm-cant-be-writer
  33     gdbm-reader-cant-delete
  34     gdbm-reader-cant-store
  35     gdbm-reader-cant-reorganize
  36     gdbm-unknown-update
  37     gdbm-item-not-found
  38     gdbm-reorganize-failed
  39     gdbm-cannot-replace
  40     gdbm-illegal-data
  41     gdbm-option-already-set
  42     gdbm-illegal-option ;
  43
  44 <PRIVATE
  45
  46 : gdbm-errno ( -- n )
  47     [ gdbm_errno ] [ drop gdbm_errno_location int deref ] recover ;
  48
  49 : gdbm-throw ( -- * ) gdbm-errno gdbm-error number>enum throw ;
  50
  51 : check-error ( ret -- ) 0 = [ gdbm-throw ] unless ;
  52
  53 SYMBOL: current-dbf
  54
  55 : dbf ( -- dbf ) current-dbf get ;
  56
  57 : get-flag ( gdbm -- n )
  58     [ role>>   enum>number ]
  59     [ sync>>   GDBM_SYNC 0 ? ]
  60     [ nolock>> GDBM_NOLOCK 0 ? ]
  61     tri bitor bitor ;
  62
  63 : gdbm-open ( gdbm -- dbf )
  64     {
  65         [ name>> normalize-path ]
  66         [ block-size>> ] [ get-flag ] [ mode>> ]
  67     } cleave f gdbm_open [ gdbm-throw ] unless* ;
  68
  69 DESTRUCTOR: gdbm-close
  70
  71 : object>datum ( obj -- datum )
  72     object>bytes [ malloc-byte-array &free ] [ length ] bi
  73     datum <struct-boa> ;
  74
  75 : datum>object* ( datum -- obj ? )
  76     [ dptr>> ] [ dsize>> ] bi over
  77     [ memory>byte-array bytes>object t ] [ drop f ] if ;
  78
  79 : gdbm-store ( key content flag -- )
  80     [
  81         [ dbf ] 3dip
  82         [ object>datum ] [ object>datum ] [ ] tri*
  83         gdbm_store check-error
  84     ] with-destructors ;
  85
  86 :: (setopt) ( value option -- )
  87     [
  88         int heap-size dup malloc &free :> ( size ptr )
  89         value ptr 0 int set-alien-value
  90         dbf option ptr size gdbm_setopt check-error
  91     ] with-destructors ;
  92
  93 : setopt ( value option -- )
  94     [ GDBM_CACHESIZE = [ >c-bool ] unless ] keep (setopt) ;
  95
  96 PRIVATE>
  97
  98
  99 : gdbm-info ( -- str ) gdbm_version ;
 100
 101 : gdbm-error-message ( error -- msg )
 102     enum>number gdbm_strerror ;
 103
 104 : replace ( key content -- ) GDBM_REPLACE gdbm-store ;
 105 : insert ( key content -- ) GDBM_INSERT gdbm-store ;
 106
 107 : delete ( key -- )
 108     [ dbf swap object>datum gdbm_delete check-error ]
 109     with-destructors ;
 110
 111 : fetch* ( key -- content ? )
 112     [ dbf swap object>datum gdbm_fetch datum>object* ]
 113     with-destructors ;
 114
 115 : first-key* ( -- key ? )
 116     [ dbf gdbm_firstkey datum>object* ] with-destructors ;
 117
 118 : next-key* ( key -- next-key ? )
 119     [ dbf swap object>datum gdbm_nextkey datum>object* ]
 120     with-destructors ;
 121
 122 : fetch ( key -- content/f ) fetch* drop ;
 123 : first-key ( -- key/f ) first-key* drop ;
 124 : next-key ( key -- key/f ) next-key* drop ;
 125
 126 :: each-key ( ... quot: ( ... key -- ... ) -- ... )
 127     first-key*
 128     [ [ next-key* ] [ quot keep ] do while ] when drop ; inline
 129
 130 : each-value ( ... quot: ( ... value -- ... ) -- ... )
 131     [ fetch ] prepose each-key ; inline
 132
 133 : each-record ( ... quot: ( ... key value -- ... ) -- ... )
 134     [ dup fetch ] prepose each-key ; inline
 135
 136 : reorganize ( -- ) dbf gdbm_reorganize check-error ;
 137
 138 : synchronize ( -- ) dbf gdbm_sync ;
 139
 140 : file-exists? ( key -- ? )
 141     [ dbf swap object>datum gdbm_exists c-bool> ]
 142     with-destructors ;
 143
 144 : set-cache-size ( size -- ) GDBM_CACHESIZE setopt ;
 145 : set-sync-mode ( ? -- ) GDBM_SYNCMODE setopt ;
 146 : set-block-pool ( ? -- ) GDBM_CENTFREE setopt ;
 147 : set-block-merging ( ? -- ) GDBM_COALESCEBLKS setopt ;
 148
 149 : gdbm-file-descriptor ( -- desc ) dbf gdbm_fdesc ;
 150
 151 : with-gdbm ( gdbm quot -- )
 152     '[
 153         _ gdbm-open &gdbm-close current-dbf
 154         _ with-variable
 155     ] with-destructors ; inline
 156
 157 :: with-gdbm-role ( name role quot -- )
 158     <gdbm> name >>name role >>role quot with-gdbm ; inline
 159
 160 : with-gdbm-reader ( name quot -- )
 161     reader swap with-gdbm-role ; inline
 162
 163 : with-gdbm-writer ( name quot -- )
 164     writer swap with-gdbm-role ; inline