extra/gml/viewer/viewer.factor

   1 USING: accessors alien.c-types alien.data alien.data.map arrays
   2 assocs byte-arrays colors combinators combinators.short-circuit
   3 destructors euler.b-rep euler.b-rep.triangulation game.input
   4 game.loop game.models.half-edge game.worlds gml.printer gpu
   5 gpu.buffers gpu.framebuffers gpu.render gpu.shaders gpu.state
   6 gpu.util.wasd growable images kernel literals math math.order
   7 math.vectors math.vectors.conversion math.vectors.simd
   8 math.vectors.simd.cords method-chains models namespaces ranges
   9 sequences sets specialized-vectors typed ui ui.gadgets
  10 ui.gadgets.worlds ui.gestures ui.pixel-formats vectors ;
  11 FROM: models => change-model ;
  12 SPECIALIZED-VECTORS: ushort float-4 ;
  13 IN: gml.viewer
  14
  15 CONSTANT: neutral-edge-color float-4{ 1 1 1 1 }
  16 CONSTANT: neutral-face-color float-4{ 1 1 1 1 }
  17 CONSTANT: selected-face-color float-4{ 1 0.9 0.8 1 }
  18
  19 : double-4>float-4 ( in: double-4 -- out: float-4 )
  20     [ head>> ] [ tail>> ] bi double-2 float-4 vconvert ; inline
  21 : rgba>float-4 ( in: rgba -- out: float-4 )
  22     >rgba-components float-4-boa ; inline
  23
  24 : face-color ( edge -- color )
  25     face-normal float-4{ 0 1 0.1 0 } vdot 0.3 * 0.4 + dup dup 1.0 float-4-boa ; inline
  26
  27 TUPLE: b-rep-vertices
  28     { array byte-array read-only }
  29     { face-vertex-count integer read-only }
  30     { edge-vertex-count integer read-only }
  31     { point-vertex-count integer read-only } ;
  32
  33 :: <b-rep-vertices> ( face-array  face-count
  34                       edge-array  edge-count
  35                       point-array point-count -- vxs )
  36     face-array edge-array point-array 3append
  37     face-count edge-count point-count \ b-rep-vertices boa ; inline
  38
  39 : face-selected? ( face selected -- ? )
  40     [ f ] 2dip [ edge>> ] dip '[ _ in? or ] each-face-edge ;
  41
  42 :: b-rep-face-vertices ( b-rep selected -- vertices count indices )
  43     float-4-vector{ } clone :> vertices
  44     ushort-vector{ } clone :> indices
  45
  46     0 b-rep faces>> [| count face |
  47         face selected face-selected? :> selected?
  48         face dup base-face>> eq? [
  49             face edge>> face-color
  50                 selected? selected-face-color neutral-face-color ? v* :> color
  51             face triangulate-face seq>> :> triangles
  52             triangles members :> tri-vertices
  53             tri-vertices >index-hash :> vx-indices
  54
  55             tri-vertices [
  56                 position>> double-4>float-4 vertices push
  57                 color vertices push
  58             ] each
  59             triangles [ vx-indices at count + indices push ] each
  60
  61             count tri-vertices length +
  62         ] [ count ] if
  63     ] each :> total
  64     vertices float-4 >c-array underlying>>
  65     total
  66     indices ushort-array{ } like ;
  67
  68 : b-rep-edge-vertices ( b-rep -- vertices count )
  69     vertices>> [
  70         [
  71             position>> [ double-4>float-4 ] keep
  72             [ drop neutral-edge-color ]
  73             [ vertex-color rgba>float-4 ] 2bi
  74         ] data-map( object -- float-4[4] )
  75     ] [ length 2 * ] bi ; inline
  76
  77 GENERIC: selected-vectors ( object -- vectors )
  78 M: object selected-vectors drop { } ;
  79 M: double-4 selected-vectors 1array ;
  80 M: sequence selected-vectors [ selected-vectors ] map concat ;
  81
  82 : selected-vertices ( selected -- vertices count )
  83     selected-vectors [
  84         [ [ double-4>float-4 ] [ vertex-color rgba>float-4 ] bi ]
  85         data-map( object -- float-4[2] )
  86     ] [ length ] bi ; inline
  87
  88 : edge-vertex-index ( e vertex-indices selected -- n selected? )
  89     [ dup vertex>> ] [ at 2 * ] [ swapd in? [ [ 1 + ] when ] keep ] tri* ;
  90
  91 :: b-rep-edge-index-array ( b-rep selected offset -- edge-indices )
  92     b-rep vertices>> >index-hash :> vertex-indices
  93     b-rep edges>> length <ushort-vector> :> edge-indices
  94
  95     b-rep edges>> [| e |
  96         e opposite-edge>> :> o
  97         e vertex-indices selected edge-vertex-index [ offset + ] dip :> ( from e-selected? )
  98         o vertex-indices selected edge-vertex-index [ offset + ] dip :> ( to   o-selected? )
  99
 100         from to < [ from edge-indices push to edge-indices push ] when
 101     ] each
 102
 103     edge-indices ushort-array{ } like ;
 104
 105 :: make-b-rep-vertices ( b-rep selected -- vertices face-indices edge-indices point-indices )
 106     b-rep selected b-rep-face-vertices :> ( face-vertices face-count face-indices )
 107     b-rep b-rep-edge-vertices :> ( edge-vertices edge-count )
 108     selected selected-vertices :> ( sel-vertices sel-count )
 109     face-vertices face-count edge-vertices edge-count sel-vertices sel-count
 110     <b-rep-vertices> :> vertices
 111
 112     vertices array>>
 113
 114     face-indices
 115
 116     b-rep selected vertices face-vertex-count>> b-rep-edge-index-array
 117     vertices
 118
 119     [ face-vertex-count>> ]
 120     [ edge-vertex-count>> + dup ]
 121     [ point-vertex-count>> + ] tri
 122     [a..b) ushort >c-array ;
 123
 124 VERTEX-FORMAT: wire-vertex-format
 125     { "vertex"  float-components 3 f }
 126     { f         float-components 1 f }
 127     { "color"   float-components 4 f } ;
 128
 129 GLSL-SHADER-FILE: gml-viewer-vertex-shader vertex-shader "viewer.v.glsl"
 130 GLSL-SHADER-FILE: gml-viewer-fragment-shader fragment-shader "viewer.f.glsl"
 131 GLSL-PROGRAM: gml-viewer-program
 132     gml-viewer-vertex-shader gml-viewer-fragment-shader
 133     wire-vertex-format ;
 134
 135 TUPLE: gml-viewer-world < wasd-world
 136     { b-rep b-rep }
 137     selected
 138     program
 139     vertex-array
 140     face-indices edge-indices point-indices
 141     view-faces? view-edges?
 142     drag? ;
 143
 144 TYPED: refresh-b-rep-view ( world: gml-viewer-world -- )
 145     dup control-value >>b-rep
 146     dup vertex-array>> [ vertex-array-buffer dispose ] when*
 147     dup [ b-rep>> ] [ selected>> value>> ] bi make-b-rep-vertices {
 148         [
 149             static-upload draw-usage vertex-buffer byte-array>buffer
 150             over program>> <vertex-array> >>vertex-array
 151         ]
 152         [ >>face-indices ]
 153         [ >>edge-indices ]
 154         [ >>point-indices ]
 155     } spread
 156     drop ;
 157
 158 : viewable? ( gml-viewer-world -- ? )
 159     { [ b-rep>> ] [ program>> ] } 1&& ;
 160
 161 M: gml-viewer-world model-changed
 162     nip
 163     [ control-value ]
 164     [ b-rep<< ]
 165     [ dup viewable? [ refresh-b-rep-view ] [ drop ] if ] tri ;
 166
 167 : init-viewer-model ( gml-viewer-world -- )
 168     [ dup model>> add-connection ]
 169     [ dup selected>> add-connection ] bi ;
 170
 171 : reset-view ( gml-viewer-world -- )
 172     { 0.0 0.0 5.0 } 0.0 0.0 set-wasd-view drop ;
 173
 174 M: gml-viewer-world begin-game-world
 175     init-gpu
 176     t >>view-faces?
 177     t >>view-edges?
 178     T{ point-state { size 5.0 } } set-gpu-state
 179     dup reset-view
 180     gml-viewer-program <program-instance> >>program
 181     dup init-viewer-model
 182     refresh-b-rep-view ;
 183
 184 M: gml-viewer-world end-game-world
 185     [ dup selected>> remove-connection ]
 186     [ dup model>> remove-connection ] bi ;
 187
 188 M: gml-viewer-world draw-world*
 189     system-framebuffer {
 190         { default-attachment { 0.0 0.0 0.0 1.0 } }
 191         { depth-attachment 1.0 }
 192     } clear-framebuffer
 193
 194     [
 195         dup view-faces?>> [
 196             T{ depth-state { comparison cmp-less } } set-gpu-state
 197             {
 198                 { "primitive-mode" [ drop triangles-mode ] }
 199                 { "indexes"        [ face-indices>> ] }
 200                 { "uniforms"       [ <mvp-uniforms> ] }
 201                 { "vertex-array"   [ vertex-array>> ] }
 202             } <render-set> render
 203             T{ depth-state { comparison f } } set-gpu-state
 204         ] [ drop ] if
 205     ] [
 206         dup view-edges?>> [
 207             {
 208                 { "primitive-mode" [ drop lines-mode ] }
 209                 { "indexes"        [ edge-indices>> ] }
 210                 { "uniforms"       [ <mvp-uniforms> ] }
 211                 { "vertex-array"   [ vertex-array>> ] }
 212             } <render-set> render
 213         ] [ drop ] if
 214     ] [
 215         {
 216             { "primitive-mode" [ drop points-mode ] }
 217             { "indexes"        [ point-indices>> ] }
 218             { "uniforms"       [ <mvp-uniforms> ] }
 219             { "vertex-array"   [ vertex-array>> ] }
 220         } <render-set> render
 221     ] tri ;
 222
 223 TYPED: rotate-view-mode ( world: gml-viewer-world -- )
 224     dup view-edges?>> [
 225         dup view-faces?>>
 226         [ f >>view-faces? ]
 227         [ f >>view-edges? t >>view-faces? ] if
 228     ] [ t >>view-edges? ] if drop ;
 229
 230 CONSTANT: edge-hitbox-radius 0.05
 231
 232 :: line-nearest-t ( p0 u q0 v -- tp tq )
 233     p0 q0 v- :> w0
 234
 235     u u vdot :> a
 236     u v vdot :> b
 237     v v vdot :> c
 238     u w0 vdot :> d
 239     v w0 vdot :> e
 240
 241     a c * b b * - :> denom
 242
 243     b e * c d * - denom /f
 244     a e * b d * - denom /f ;
 245
 246 :: intersects-edge-node? ( source direction edge -- ? )
 247     edge vertex>> position>> double-4>float-4 :> edge-source
 248     edge opposite-edge>> vertex>> position>> double-4>float-4 edge-source v- :> edge-direction
 249
 250     source direction edge-source edge-direction line-nearest-t :> ( ray-t edge-t )
 251
 252     ray-t 0.0 >= edge-t 0.0 0.5 between? and [
 253         source direction ray-t v*n v+
 254         edge-source edge-direction edge-t v*n v+ v- norm
 255         edge-hitbox-radius <
 256     ] [ f ] if ;
 257
 258 : intersecting-edge-node ( source direction b-rep -- edge/f )
 259     edges>> [ intersects-edge-node? ] 2with find nip ;
 260
 261 : select-edge ( world -- )
 262     [ [ location>> ] [ hand-loc get wasd-pixel-ray ] bi ]
 263     [ b-rep>> intersecting-edge-node ]
 264     [ '[ _ [ selected>> push-model ] [ refresh-b-rep-view ] bi ] when* ] tri ;
 265
 266 gml-viewer-world H{
 267     { T{ button-up f f 1 } [ dup drag?>> [ drop ] [ select-edge ] if ] }
 268     { T{ drag f 1 } [ t >>drag? drop ] }
 269     { T{ key-down f f "RET" } [ reset-view ] }
 270     { T{ key-down f f "TAB" } [ rotate-view-mode ] }
 271 } set-gestures
 272
 273 AFTER: gml-viewer-world tick-game-world
 274     dup drag?>> [
 275         read-mouse buttons>>
 276         ! FIXME: GTK Mouse buttons are an integer
 277         ! MacOSX mouse buttons are an array of bools
 278         dup integer? [ 0 bit? ] [ first ] if >>drag?
 279     ] when drop ;
 280
 281 M: gml-viewer-world wasd-mouse-scale drag?>> -1/600. 0.0 ? ;
 282
 283 : wrap-in-model ( object -- model )
 284     dup model? [ <model> ] unless ;
 285 : wrap-in-growable-model ( object -- model )
 286     dup model? [
 287         dup growable? [ >vector ] unless
 288         <model>
 289     ] unless ;
 290
 291 : gml-viewer ( b-rep selection -- )
 292     [ wrap-in-model ] [ wrap-in-growable-model ] bi*
 293     '[
 294         f T{ game-attributes
 295             { world-class gml-viewer-world }
 296             { title "GML wireframe viewer" }
 297             { pixel-format-attributes {
 298                 windowed
 299                 double-buffered
 300                 T{ depth-bits f 16 }
 301             } }
 302             { grab-input? f }
 303             { use-game-input? t }
 304             { use-audio-engine? f }
 305             { pref-dim { 1024 768 } }
 306             { tick-interval-nanos $[ 30 fps ] }
 307         } open-window*
 308         _ >>model
 309         _ >>selected
 310         drop
 311     ] with-ui ;