extra/gopher/ui/ui.factor

   1 ! Copyright (C) 2014 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors arrays debugger fonts fry gopher gopher.private
   5 kernel math.vectors models present sequences ui ui.commands ui.gadgets
   6 ui.gadgets.editors ui.gadgets.panes ui.gadgets.scrollers
   7 ui.gadgets.status-bar ui.gadgets.toolbar ui.gadgets.tracks
   8 ui.gadgets.viewports ui.gestures ui.operations ui.tools.browser
   9 ui.tools.browser.history ui.tools.common urls ;
  10
  11 IN: gopher.ui
  12
  13 TUPLE: gopher-gadget < tool history scroller url-field ;
  14
  15 gopher-gadget default-font-size { 50 50 } n*v set-tool-dim
  16
  17 M: gopher-gadget history-value
  18     [ control-value ] [ scroller>> scroll-position ]
  19     bi 2array ;
  20
  21 M: gopher-gadget set-history-value
  22     [ first2 ] dip
  23     [ set-control-value ] [ scroller>> set-scroll-position ]
  24     bi-curry bi* ;
  25
  26 M: gopher-gadget model-changed
  27     [ value>> present ]
  28     [ url-field>> editor>> set-editor-string ] bi* ;
  29
  30 : show-gopher ( url gopher-gadget -- )
  31     [ [ >url ] [ f ] if* ] dip
  32     [
  33         2dup control-value =
  34         [ 2drop ] [ nip history>> add-history ] if
  35     ]
  36     [ set-control-value ]
  37     2bi ;
  38
  39 : <url-field> ( gopher-gadget -- field )
  40     '[ >url _ show-gopher ] <action-field>
  41         "Gopher URL" >>default-text
  42         white-interior ;
  43
  44 : <gopher-pane> ( gopher-gadget -- gadget )
  45     model>> [ '[ _ [ gopher. ] when* ] try ] <pane-control> ;
  46
  47 : <gopher-toolbar> ( browser -- toolbar )
  48     horizontal <track>
  49         0 >>fill
  50         1/2 >>align
  51         { 5 5 } >>gap
  52         over <toolbar> f track-add
  53         swap url-field>> 1 track-add ;
  54
  55 : add-gopher-toolbar ( track -- track )
  56     dup <gopher-toolbar> format-toolbar f track-add ;
  57
  58 : add-gopher-pane ( track -- track )
  59     dup dup <gopher-pane> margins
  60     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  61
  62 : <gopher-gadget> ( -- gadget )
  63     vertical gopher-gadget new-track with-lines
  64         f <model> >>model
  65         dup <history> >>history
  66         dup <url-field> >>url-field
  67         add-gopher-toolbar
  68         add-gopher-pane ;
  69
  70 : open-gopher-window ( url -- )
  71     <gopher-gadget>
  72     [ "Gopher" open-status-window ]
  73     [ show-gopher ] bi ;
  74
  75 : com-clear ( gopher -- )
  76     f swap set-control-value ;
  77
  78 : com-gopher ( url -- )
  79     [ gopher-gadget? ] find-window
  80     [ [ raise-window ] [ gadget-child show-gopher ] bi ]
  81     [ open-gopher-window ] if* ;
  82
  83 gopher-gadget "toolbar" f {
  84     { f com-back }
  85     { f com-forward }
  86     { f com-clear }
  87 } define-command-map
  88
  89 gopher-gadget "scrolling" f {
  90     { T{ key-down f f "UP" } com-scroll-up }
  91     { T{ key-down f f "DOWN" } com-scroll-down }
  92     { T{ key-down f f "PAGE_UP" } com-page-up }
  93     { T{ key-down f f "PAGE_DOWN" } com-page-down }
  94 } define-command-map
  95
  96 [ gopher-link? ] \ com-gopher H{ { +primary+ t } } define-operation