extra/gopher/ui/ui.factor

   1 ! Copyright (C) 2014 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors arrays debugger fry gopher gopher.private
   5 kernel models present sequences ui ui.commands ui.gadgets
   6 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.editors
   7 ui.gadgets.panes ui.gadgets.scrollers ui.gadgets.status-bar
   8 ui.gadgets.toolbar ui.gadgets.tracks ui.gadgets.viewports
   9 ui.gestures ui.operations ui.tools.browser
  10 ui.tools.browser.history ui.tools.common urls ;
  11
  12 IN: gopher.ui
  13
  14 TUPLE: gopher-gadget < tool history scroller url-field ;
  15
  16 gopher-gadget { 600 600 } set-tool-dim
  17
  18 M: gopher-gadget history-value
  19     [ control-value ] [ scroller>> scroll-position ]
  20     bi 2array ;
  21
  22 M: gopher-gadget set-history-value
  23     [ first2 ] dip
  24     [ set-control-value ] [ scroller>> set-scroll-position ]
  25     bi-curry bi* ;
  26
  27 M: gopher-gadget model-changed
  28     [ value>> present ]
  29     [ url-field>> editor>> set-editor-string ] bi* ;
  30
  31 : show-gopher ( url gopher-gadget -- )
  32     [ [ >url ] [ f ] if* ] dip
  33     [
  34         2dup control-value =
  35         [ 2drop ] [ nip history>> add-history ] if
  36     ]
  37     [ set-control-value ]
  38     2bi ;
  39
  40 : <url-field> ( gopher-gadget -- field )
  41     '[ >url _ show-gopher ] <action-field>
  42         "Gopher URL" >>default-text
  43         white-interior ;
  44
  45 : <gopher-pane> ( gopher-gadget -- gadget )
  46     model>> [ '[ _ [ gopher. ] when* ] try ] <pane-control> ;
  47
  48 : <gopher-toolbar> ( browser -- toolbar )
  49     horizontal <track>
  50         0 >>fill
  51         1/2 >>align
  52         { 5 5 } >>gap
  53         over <toolbar> f track-add
  54         swap url-field>> 1 track-add ;
  55
  56 : add-gopher-toolbar ( track -- track )
  57     dup <gopher-toolbar> format-toolbar f track-add ;
  58
  59 : add-gopher-pane ( track -- track )
  60     dup dup <gopher-pane> margins
  61     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  62
  63 : <gopher-gadget> ( -- gadget )
  64     vertical gopher-gadget new-track with-lines
  65         f <model> >>model
  66         dup <history> >>history
  67         dup <url-field> >>url-field
  68         add-gopher-toolbar
  69         add-gopher-pane ;
  70
  71 : open-gopher-window ( url -- )
  72     <gopher-gadget>
  73     [ "Gopher" open-status-window ]
  74     [ show-gopher ] bi ;
  75
  76 : com-clear ( gopher -- )
  77     f swap set-control-value ;
  78
  79 : com-gopher ( url -- )
  80     [ gopher-gadget? ] find-window
  81     [ [ raise-window ] [ gadget-child show-gopher ] bi ]
  82     [ open-gopher-window ] if* ;
  83
  84 gopher-gadget "toolbar" f {
  85     { f com-back }
  86     { f com-forward }
  87     { f com-clear }
  88 } define-command-map
  89
  90 gopher-gadget "scrolling" f {
  91     { T{ key-down f f "UP" } com-scroll-up }
  92     { T{ key-down f f "DOWN" } com-scroll-down }
  93     { T{ key-down f f "PAGE_UP" } com-page-up }
  94     { T{ key-down f f "PAGE_DOWN" } com-page-down }
  95 } define-command-map
  96
  97 [ gopher-link? ] \ com-gopher H{ { +primary+ t } } define-operation