extra/gpu/buffers/buffers.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien alien.c-types arrays byte-arrays
   3 combinators destructors gpu kernel locals math opengl opengl.gl
   4 ui.gadgets.worlds variants ;
   5 IN: gpu.buffers
   6
   7 VARIANT: buffer-upload-pattern
   8     stream-upload static-upload dynamic-upload ;
   9
  10 VARIANT: buffer-usage-pattern
  11     draw-usage read-usage copy-usage ;
  12
  13 VARIANT: buffer-access-mode
  14     read-access write-access read-write-access ;
  15
  16 VARIANT: buffer-kind
  17     vertex-buffer index-buffer
  18     pixel-unpack-buffer pixel-pack-buffer ;
  19
  20 TUPLE: buffer < gpu-object
  21     { upload-pattern buffer-upload-pattern }
  22     { usage-pattern buffer-usage-pattern }
  23     { kind buffer-kind } ;
  24
  25 <PRIVATE
  26
  27 : gl-buffer-usage ( buffer -- usage )
  28     [ upload-pattern>> ] [ usage-pattern>> ] bi 2array {
  29         { { stream-upload draw-usage } [ GL_STREAM_DRAW ] }
  30         { { stream-upload read-usage } [ GL_STREAM_READ ] }
  31         { { stream-upload copy-usage } [ GL_STREAM_COPY ] }
  32
  33         { { static-upload draw-usage } [ GL_STATIC_DRAW ] }
  34         { { static-upload read-usage } [ GL_STATIC_READ ] }
  35         { { static-upload copy-usage } [ GL_STATIC_COPY ] }
  36
  37         { { dynamic-upload draw-usage } [ GL_DYNAMIC_DRAW ] }
  38         { { dynamic-upload read-usage } [ GL_DYNAMIC_READ ] }
  39         { { dynamic-upload copy-usage } [ GL_DYNAMIC_COPY ] }
  40     } case ; inline
  41
  42 : gl-access ( access -- gl-access )
  43     {
  44         { read-access [ GL_READ_ONLY ] }
  45         { write-access [ GL_WRITE_ONLY ] }
  46         { read-write-access [ GL_READ_WRITE ] }
  47     } case ; inline
  48
  49 : gl-target ( kind -- target )
  50     {
  51         { vertex-buffer [ GL_ARRAY_BUFFER ] }
  52         { index-buffer [ GL_ELEMENT_ARRAY_BUFFER ] }
  53         { pixel-unpack-buffer [ GL_PIXEL_UNPACK_BUFFER ] }
  54         { pixel-pack-buffer [ GL_PIXEL_PACK_BUFFER ] }
  55     } case ; inline
  56
  57 PRIVATE>
  58
  59 M: buffer dispose
  60     [ [ delete-gl-buffer ] when* f ] change-handle drop ;
  61
  62 TUPLE: buffer-ptr
  63     { buffer buffer read-only }
  64     { offset integer read-only } ;
  65 C: <buffer-ptr> buffer-ptr
  66
  67 UNION: gpu-data-ptr buffer-ptr c-ptr ;
  68
  69 :: allocate-buffer ( buffer size initial-data -- )
  70     buffer kind>> gl-target :> target
  71     target buffer handle>> glBindBuffer
  72     target size initial-data buffer gl-buffer-usage glBufferData ;
  73
  74 : <buffer> ( upload usage kind size initial-data -- buffer )
  75     [ [ gen-gl-buffer ] 3dip buffer boa dup ] 2dip allocate-buffer
  76     window-resource ;
  77
  78 : byte-array>buffer ( byte-array upload usage kind -- buffer )
  79     [ ] 3curry dip
  80     [ byte-length ] [ ] bi <buffer> ;
  81
  82 :: update-buffer ( buffer-ptr size data -- )
  83     buffer-ptr buffer>> :> buffer
  84     buffer kind>> gl-target :> target
  85     target buffer handle>> glBindBuffer
  86     target buffer-ptr offset>> size data glBufferSubData ;
  87
  88 :: read-buffer ( buffer-ptr size -- data )
  89     buffer-ptr buffer>> :> buffer
  90     buffer kind>> gl-target :> target
  91     size <byte-array> :> data
  92     target buffer handle>> glBindBuffer
  93     target buffer-ptr offset>> size data glGetBufferSubData
  94     data ;
  95
  96 :: copy-buffer ( to-buffer-ptr from-buffer-ptr size -- )
  97     GL_COPY_WRITE_BUFFER to-buffer-ptr buffer>> glBindBuffer
  98     GL_COPY_READ_BUFFER from-buffer-ptr buffer>> glBindBuffer
  99
 100     GL_COPY_READ_BUFFER GL_COPY_WRITE_BUFFER
 101     from-buffer-ptr offset>> to-buffer-ptr offset>>
 102     size glCopyBufferSubData ;
 103
 104 :: with-mapped-buffer ( buffer access quot: ( alien -- ) -- )
 105     buffer kind>> gl-target :> target
 106
 107     target buffer handle>> glBindBuffer
 108     target access gl-access glMapBuffer
 109
 110     quot call
 111
 112     target glUnmapBuffer ; inline
 113
 114 :: with-bound-buffer ( buffer target quot: ( -- ) -- )
 115     target gl-target buffer glBindBuffer
 116     quot call ; inline
 117
 118 : with-buffer-ptr ( buffer-ptr target quot: ( c-ptr -- ) -- )
 119     [ [ offset>> <alien> ] [ buffer>> handle>> ] bi ] 2dip
 120     with-bound-buffer ; inline
 121
 122 : with-gpu-data-ptr ( gpu-data-ptr target quot: ( c-ptr -- ) -- )
 123     pick buffer-ptr?
 124     [ with-buffer-ptr ]
 125     [ [ gl-target 0 glBindBuffer ] dip call ] if ; inline
 126