extra/gpu/buffers/buffers.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien alien.c-types arrays byte-arrays
   3 combinators destructors gpu kernel locals math opengl opengl.gl
   4 ui.gadgets.worlds variants ;
   5 IN: gpu.buffers
   6
   7 VARIANT: buffer-upload-pattern
   8     stream-upload static-upload dynamic-upload ;
   9
  10 VARIANT: buffer-usage-pattern
  11     draw-usage read-usage copy-usage ;
  12
  13 VARIANT: buffer-access-mode
  14     read-access write-access read-write-access ;
  15
  16 VARIANT: buffer-kind
  17     vertex-buffer index-buffer
  18     pixel-unpack-buffer pixel-pack-buffer
  19     transform-feedback-buffer ;
  20
  21 TUPLE: buffer < gpu-object
  22     { upload-pattern buffer-upload-pattern }
  23     { usage-pattern buffer-usage-pattern }
  24     { kind buffer-kind } ;
  25
  26 <PRIVATE
  27
  28 : gl-buffer-usage ( buffer -- usage )
  29     [ upload-pattern>> ] [ usage-pattern>> ] bi 2array {
  30         { { stream-upload draw-usage } [ GL_STREAM_DRAW ] }
  31         { { stream-upload read-usage } [ GL_STREAM_READ ] }
  32         { { stream-upload copy-usage } [ GL_STREAM_COPY ] }
  33
  34         { { static-upload draw-usage } [ GL_STATIC_DRAW ] }
  35         { { static-upload read-usage } [ GL_STATIC_READ ] }
  36         { { static-upload copy-usage } [ GL_STATIC_COPY ] }
  37
  38         { { dynamic-upload draw-usage } [ GL_DYNAMIC_DRAW ] }
  39         { { dynamic-upload read-usage } [ GL_DYNAMIC_READ ] }
  40         { { dynamic-upload copy-usage } [ GL_DYNAMIC_COPY ] }
  41     } case ; inline
  42
  43 : gl-access ( access -- gl-access )
  44     {
  45         { read-access [ GL_READ_ONLY ] }
  46         { write-access [ GL_WRITE_ONLY ] }
  47         { read-write-access [ GL_READ_WRITE ] }
  48     } case ; inline
  49
  50 : gl-target ( kind -- target )
  51     {
  52         { vertex-buffer [ GL_ARRAY_BUFFER ] }
  53         { index-buffer [ GL_ELEMENT_ARRAY_BUFFER ] }
  54         { pixel-unpack-buffer [ GL_PIXEL_UNPACK_BUFFER ] }
  55         { pixel-pack-buffer [ GL_PIXEL_PACK_BUFFER ] }
  56         { transform-feedback-buffer [ GL_TRANSFORM_FEEDBACK_BUFFER ] }
  57     } case ; inline
  58
  59 : get-buffer-int ( target enum -- value )
  60     0 <int> [ glGetBufferParameteriv ] keep *int ;
  61
  62 : bind-buffer ( buffer -- target )
  63     [ kind>> gl-target dup ] [ handle>> glBindBuffer ] bi ;
  64
  65 PRIVATE>
  66
  67 M: buffer dispose
  68     [ [ delete-gl-buffer ] when* f ] change-handle drop ;
  69
  70 TUPLE: buffer-ptr
  71     { buffer buffer read-only }
  72     { offset integer read-only } ;
  73 C: <buffer-ptr> buffer-ptr
  74
  75 TUPLE: buffer-range < buffer-ptr
  76     { size integer read-only } ;
  77 C: <buffer-range> buffer-range
  78
  79 UNION: gpu-data-ptr buffer-ptr c-ptr ;
  80
  81 : buffer-size ( buffer -- size )
  82     bind-buffer GL_BUFFER_SIZE get-buffer-int ;
  83
  84 : buffer-ptr>range ( buffer-ptr -- buffer-range )
  85     [ buffer>> ] [ offset>> ] bi
  86     2dup [ buffer-size ] dip -
  87     buffer-range boa ; inline
  88
  89 :: allocate-buffer ( buffer size initial-data -- )
  90     buffer bind-buffer :> target
  91     target size initial-data buffer gl-buffer-usage glBufferData ;
  92
  93 : <buffer> ( upload usage kind size initial-data -- buffer )
  94     [ [ gen-gl-buffer ] 3dip buffer boa dup ] 2dip allocate-buffer
  95     window-resource ;
  96
  97 : byte-array>buffer ( byte-array upload usage kind -- buffer )
  98     [ ] 3curry dip
  99     [ byte-length ] [ ] bi <buffer> ;
 100
 101 :: update-buffer ( buffer-ptr size data -- )
 102     buffer-ptr buffer>> :> buffer
 103     buffer bind-buffer :> target
 104     target buffer-ptr offset>> size data glBufferSubData ;
 105
 106 :: read-buffer ( buffer-ptr size -- data )
 107     buffer-ptr buffer>> :> buffer
 108     buffer bind-buffer :> target
 109     size <byte-array> :> data
 110     target buffer-ptr offset>> size data glGetBufferSubData
 111     data ;
 112
 113 :: copy-buffer ( to-buffer-ptr from-buffer-ptr size -- )
 114     GL_COPY_WRITE_BUFFER to-buffer-ptr buffer>> glBindBuffer
 115     GL_COPY_READ_BUFFER from-buffer-ptr buffer>> glBindBuffer
 116
 117     GL_COPY_READ_BUFFER GL_COPY_WRITE_BUFFER
 118     from-buffer-ptr offset>> to-buffer-ptr offset>>
 119     size glCopyBufferSubData ;
 120
 121 :: with-mapped-buffer ( buffer access quot: ( alien -- ) -- )
 122     buffer bind-buffer :> target
 123     target access gl-access glMapBuffer
 124
 125     quot call
 126
 127     target glUnmapBuffer drop ; inline
 128
 129 :: with-bound-buffer ( buffer target quot: ( -- ) -- )
 130     target gl-target buffer glBindBuffer
 131     quot call ; inline
 132
 133 : with-buffer-ptr ( buffer-ptr target quot: ( c-ptr -- ) -- )
 134     [ [ offset>> <alien> ] [ buffer>> handle>> ] bi ] 2dip
 135     with-bound-buffer ; inline
 136
 137 : with-gpu-data-ptr ( gpu-data-ptr target quot: ( c-ptr -- ) -- )
 138     pick buffer-ptr?
 139     [ with-buffer-ptr ]
 140     [ [ gl-target 0 glBindBuffer ] dip call ] if ; inline
 141